matita/components/ng_tactics/nTacStatus.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: nCic.ml 9058 2008-10-13 17:42:30Z tassi $ *)
  13
  14 let debug = ref false;;
  15 let pp x =
  16  if !debug then prerr_endline (Lazy.force x) else ()
  17 ;;
  18
  19 type automation_cache = NDiscriminationTree.DiscriminationTree.t
  20 type unit_eq_cache = NCicParamod.state
  21
  22 exception Error of string lazy_t * exn option
  23 let fail ?exn msg = raise (Error (msg,exn))
  24
  25 module NRef = NReference
  26
  27 let wrap fname f x =
  28   try f x
  29   with
  30   | MultiPassDisambiguator.DisambiguationError _
  31   | NCicRefiner.RefineFailure _
  32   | NCicUnification.UnificationFailure _
  33   | NCicTypeChecker.TypeCheckerFailure _
  34   | NCicMetaSubst.MetaSubstFailure _ as exn -> fail ~exn (lazy fname)
  35 ;;
  36
  37 class type g_eq_status =
  38  object
  39    method eq_cache : unit_eq_cache
  40  end
  41
  42 class eq_status =
  43  object(self)
  44   val eq_cache = NCicParamod.empty_state
  45   method eq_cache = eq_cache
  46   method set_eq_cache v = {< eq_cache = v >}
  47   method set_eq_status
  48    : 'status. #g_eq_status as 'status -> 'self
  49    = fun o -> self#set_eq_cache o#eq_cache
  50  end
  51
  52 class type g_auto_status =
  53  object
  54    method auto_cache : automation_cache
  55  end
  56
  57 class auto_status =
  58  object(self)
  59   val auto_cache = NDiscriminationTree.DiscriminationTree.empty
  60   method auto_cache = auto_cache
  61   method set_auto_cache v = {< auto_cache = v >}
  62   method set_auto_status
  63    : 'status. #g_auto_status as 'status -> 'self
  64    = fun o -> self#set_auto_cache o#auto_cache
  65  end
  66
  67 class type g_pstatus =
  68  object
  69   inherit GrafiteDisambiguate.g_status
  70   inherit g_auto_status
  71   inherit g_eq_status
  72   method obj: NCic.obj
  73  end
  74
  75 class pstatus =
  76  fun (o: NCic.obj) ->
  77  object (self)
  78    inherit GrafiteDisambiguate.status
  79    inherit auto_status
  80    inherit eq_status
  81    val obj = o
  82    method obj = obj
  83    method set_obj o = {< obj = o >}
  84    method set_pstatus : 'status. #g_pstatus as 'status -> 'self
  85    = fun o ->
  86     (((self#set_lexicon_engine_status o)#set_obj o#obj)#set_auto_status o)#set_eq_status o
  87   end
  88
  89 type tactic_term = NotationPt.term Disambiguate.disambiguator_input
  90 type tactic_pattern = GrafiteAst.npattern Disambiguate.disambiguator_input
  91
  92 let pp_tac_status status =
  93   prerr_endline (NCicPp.ppobj status#obj);
  94   prerr_endline ("STACK:\n" ^ Continuationals.Stack.pp status#stack)
  95 ;;
  96
  97 type cic_term = NCic.context * NCic.term
  98 let ctx_of (c,_) = c ;;
  99 let mk_cic_term c t = c,t ;;
 100
 101 let ppterm status t =
 102  let uri,height,metasenv,subst,obj = status#obj in
 103  let context,t = t in
 104   NCicPp.ppterm ~metasenv ~subst ~context t
 105 ;;
 106
 107 let ppcontext status c =
 108  let uri,height,metasenv,subst,obj = status#obj in
 109   NCicPp.ppcontext ~metasenv ~subst c
 110 ;;
 111
 112 let ppterm_and_context status t =
 113  let uri,height,metasenv,subst,obj = status#obj in
 114  let context,t = t in
 115   NCicPp.ppcontext ~metasenv ~subst context ^ "\n ⊢ "^
 116   NCicPp.ppterm ~metasenv ~subst ~context t
 117 ;;
 118
 119 let relocate status destination (source,t as orig) =
 120  pp(lazy("relocate:\n" ^ ppterm_and_context status orig));
 121  pp(lazy("relocate in:\n" ^ ppcontext status destination));
 122  let rc =
 123    if source == destination then status, orig else
 124     let _, _, metasenv, subst, _ = status#obj in
 125     let rec compute_ops ctx = function (* destination, source *)
 126       | (n1, NCic.Decl t1 as e)::cl1 as ex, (n2, NCic.Decl t2)::cl2 ->
 127           if n1 = n2 &&
 128              NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
 129             compute_ops (e::ctx) (cl1,cl2)
 130           else
 131             [ `Delift ctx; `Lift (List.rev ex) ]
 132       | (n1, NCic.Def (b1,t1) as e)::cl1 as ex, (n2, NCic.Def (b2,t2))::cl2 ->
 133           if n1 = n2 &&
 134              NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 &&
 135              NCicReduction.are_convertible ctx ~subst ~metasenv b1 b2 then
 136             compute_ops (e::ctx) (cl1,cl2)
 137           else
 138             [ `Delift ctx; `Lift (List.rev ex) ]
 139       | (n1, NCic.Def (b1,t1) as e)::cl1 as ex, (n2, NCic.Decl t2)::cl2 ->
 140           if n1 = n2 &&
 141              NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
 142             compute_ops (e::ctx) (cl1,cl2)
 143           else
 144             [ `Delift ctx; `Lift (List.rev ex) ]
 145       | (n1, NCic.Decl _)::cl1 as ex, (n2, NCic.Def _)::cl2 ->
 146             [ `Delift ctx; `Lift (List.rev ex) ]
 147       | _::_ as ex, [] -> [ `Lift (List.rev ex) ]
 148       | [], _::_ -> [ `Delift ctx ]
 149       | [],[] -> []
 150     in
 151     let ops = compute_ops [] (List.rev destination, List.rev source) in
 152     let rec mk_irl i j = if i > j then [] else NCic.Rel i :: mk_irl (i+1) j in
 153     List.fold_left
 154      (fun (status, (source,t)) -> function
 155       | `Lift extra_ctx ->
 156            let len = List.length extra_ctx in
 157            status, (extra_ctx@source, NCicSubstitution.lift len t)
 158       | `Delift ctx ->
 159             let len_ctx = List.length ctx in
 160             let irl = mk_irl 1 (List.length ctx) in
 161             let lc = List.length source - len_ctx, NCic.Ctx irl in
 162             let u, d, metasenv, subst, o = status#obj in
 163             pp(lazy("delifting as " ^
 164               NCicPp.ppterm ~metasenv ~subst ~context:source
 165                (NCic.Meta (0,lc))));
 166             let (metasenv, subst), t =
 167               NCicMetaSubst.delift
 168                  ~unify:(fun m s c t1 t2 ->
 169                    try Some (NCicUnification.unify status m s c t1 t2)
 170                    with
 171                     | NCicUnification.UnificationFailure _
 172                     | NCicUnification.Uncertain _ -> None)
 173                metasenv subst source 0 lc t
 174             in
 175             let status = status#set_obj (u, d, metasenv, subst, o) in
 176             status, (ctx,t))
 177        (status,orig) ops
 178  in
 179  pp(lazy("relocated: " ^ ppterm (fst rc) (snd rc)));
 180  rc
 181 ;;
 182 let relocate a b c = wrap "relocate" (relocate a b) c;;
 183
 184 let term_of_cic_term s t c =
 185   let s, (_,t) = relocate s c t in
 186   s, t
 187 ;;
 188
 189 let disambiguate status context t ty =
 190  let status, expty =
 191    match ty with
 192    | None -> status, None
 193    | Some ty ->
 194        let status, (_,x) = relocate status context ty in status, Some x
 195  in
 196  let uri,height,metasenv,subst,obj = status#obj in
 197  let metasenv, subst, status, t =
 198    GrafiteDisambiguate.disambiguate_nterm expty status context metasenv subst t
 199  in
 200  let new_pstatus = uri,height,metasenv,subst,obj in
 201   status#set_obj new_pstatus, (context, t)
 202 ;;
 203 let disambiguate a b c d = wrap "disambiguate" (disambiguate a b c) d;;
 204
 205 let typeof status ctx t =
 206   let status, (_,t) = relocate status ctx t in
 207   let _,_,metasenv,subst,_ = status#obj in
 208   let ty = NCicTypeChecker.typeof ~subst ~metasenv ctx t in
 209   status, (ctx, ty)
 210 ;;
 211 let typeof a b c = wrap "typeof" (typeof a b) c;;
 212
 213 let saturate status ?delta (ctx,t) =
 214   let n,h,metasenv,subst,k = status#obj in
 215   let t,metasenv,args = NCicMetaSubst.saturate ?delta metasenv subst ctx t 0 in
 216   let status = status#set_obj (n,h,metasenv,subst,k) in
 217   status, (ctx,t), List.map (fun x -> ctx,x) args
 218 ;;
 219 let saturate a ?delta b = wrap "saturate" (saturate a ?delta) b;;
 220
 221 let whd status ?delta ctx t =
 222   let status, (_,t) = relocate status ctx t in
 223   let _,_,_,subst,_ = status#obj in
 224   let t = NCicReduction.whd ~subst ?delta ctx t in
 225   status, (ctx, t)
 226 ;;
 227
 228 let normalize status ?delta ctx t =
 229   let status, (_,t) = relocate status ctx t in
 230   let _,_,_,subst,_ = status#obj in
 231   let t = NCicTacReduction.normalize ~subst ?delta ctx t in
 232   status, (ctx, t)
 233 ;;
 234
 235 let unify status ctx a b =
 236   let status, (_,a) = relocate status ctx a in
 237   let status, (_,b) = relocate status ctx b in
 238   let n,h,metasenv,subst,o = status#obj in
 239   let metasenv, subst = NCicUnification.unify status metasenv subst ctx a b in
 240    status#set_obj (n,h,metasenv,subst,o)
 241 ;;
 242 let unify a b c d = wrap "unify" (unify a b c) d;;
 243
 244 let fix_sorts status (ctx,t) =
 245  let f () =
 246   let name,height,metasenv,subst,obj = status#obj in
 247   let metasenv, t =
 248     NCicUnification.fix_sorts metasenv subst t in
 249   let status = status#set_obj (name,height,metasenv,subst,obj) in
 250    status, (ctx,t)
 251  in
 252   wrap "fix_sorts" f ()
 253 ;;
 254
 255 let refine status ctx term expty =
 256   let status, (_,term) = relocate status ctx term in
 257   let status, expty =
 258     match expty with
 259       None -> status, None
 260     | Some e ->
 261         let status, (_, e) = relocate status ctx e in status, Some e
 262   in
 263   let name,height,metasenv,subst,obj = status#obj in
 264   let metasenv,subst,t,ty =
 265    NCicRefiner.typeof status metasenv subst ctx term expty
 266   in
 267    status#set_obj (name,height,metasenv,subst,obj), (ctx,t), (ctx,ty)
 268 ;;
 269 let refine a b c d = wrap "refine" (refine a b c) d;;
 270
 271 let get_goalty status g =
 272  let _,_,metasenv,_,_ = status#obj in
 273  try
 274    let _, ctx, ty = NCicUtils.lookup_meta g metasenv in
 275    ctx, ty
 276  with NCicUtils.Meta_not_found _ as exn -> fail ~exn (lazy "get_goalty")
 277 ;;
 278
 279 let get_subst status =
 280   let _,_,_,subst,_ = status#obj in subst
 281 ;;
 282
 283 let to_subst status i entry =
 284  let name,height,metasenv,subst,obj = status#obj in
 285  let metasenv = List.filter (fun j,_ -> j <> i) metasenv in
 286  let subst = (i, entry) :: subst in
 287   status#set_obj (name,height,metasenv,subst,obj)
 288 ;;
 289
 290 let instantiate status i t =
 291  let _,_,metasenv,_,_ = status#obj in
 292  let gname, context, gty = List.assoc i metasenv in
 293  let status, (_,t), (_,ty) = refine status context t (Some (context,gty)) in
 294   to_subst status i (gname,context,t,ty)
 295 ;;
 296
 297 let instantiate_with_ast status i t =
 298  let _,_,metasenv,_,_ = status#obj in
 299  let gname, context, gty = List.assoc i metasenv in
 300  let ggty = mk_cic_term context gty in
 301  let status, (_,t) = disambiguate status context t (Some ggty) in
 302   to_subst status i (gname,context,t,gty)
 303 ;;
 304
 305 let mk_meta status ?(attrs=[]) ctx bo_or_ty kind =
 306   match bo_or_ty with
 307   | `Decl ty ->
 308       let status, (_,ty) = relocate status ctx ty in
 309       let n,h,metasenv,subst,o = status#obj in
 310       let metasenv, _, instance, _ =
 311         NCicMetaSubst.mk_meta ~attrs metasenv ctx ~with_type:ty kind
 312       in
 313       let status = status#set_obj (n,h,metasenv,subst,o) in
 314       status, (ctx,instance)
 315   | `Def bo ->
 316       let status, (_,bo_ as bo) = relocate status ctx bo in
 317       let status, (_,ty) = typeof status ctx bo in
 318       let n,h,metasenv,subst,o = status#obj in
 319       let metasenv, metano, instance, _ =
 320         NCicMetaSubst.mk_meta ~attrs metasenv ctx ~with_type:ty kind in
 321       let attrs,_,_ = NCicUtils.lookup_meta metano metasenv in
 322       let metasenv = List.filter (fun j,_ -> j <> metano) metasenv in
 323       let subst = (metano, (attrs, ctx, bo_, ty)) :: subst in
 324       let status = status#set_obj (n,h,metasenv,subst,o) in
 325       status, (ctx,instance)
 326 ;;
 327
 328 let mk_in_scope status t =
 329   mk_meta status ~attrs:[`InScope] (ctx_of t) (`Def t) `IsTerm
 330 ;;
 331
 332 let mk_out_scope n status t =
 333   mk_meta status ~attrs:[`OutScope n] (ctx_of t) (`Def t) `IsTerm
 334 ;;
 335
 336 (* the following unification problem will be driven by
 337  *   select s ~found:mk_in_scope ~postprocess:(mk_out_scope argsno) t pattern
 338  *
 339  *   ? args = t
 340  *
 341  *   where argsn = length args and the pattern matches t
 342  *
 343  *  found is called on every selected term to map them
 344  *  postprocess is called on the entire term after selection
 345  *)
 346 let select_term
 347   low_status ~found ~postprocess (context,term) (wanted,path)
 348 =
 349   let is_found status ctx t wanted =
 350     (* we could lift wanted step-by-step *)
 351     pp(lazy("is_found: "^ppterm status (ctx,t)));
 352     try true, unify status ctx (ctx, t) wanted
 353     with
 354     | Error (_, Some (NCicUnification.UnificationFailure _))
 355     | Error (_, Some (NCicUnification.Uncertain _)) -> false, status
 356   in
 357   let match_term status ctx (wanted : cic_term) t =
 358     let rec aux ctx (status,already_found) t =
 359       let b, status = is_found status ctx t wanted in
 360       if b then
 361          let status , (_,t) = found status (ctx, t) in
 362          (status,true),t
 363       else
 364         let _,_,_,subst,_ = status#obj in
 365         match t with
 366         | NCic.Meta (i,lc) when List.mem_assoc i subst ->
 367             let _,_,t,_ = NCicUtils.lookup_subst i subst in
 368             aux ctx (status,already_found) t
 369         | NCic.Meta _ -> (status,already_found),t
 370         | _ ->
 371           NCicUntrusted.map_term_fold_a (fun e c -> e::c) ctx aux
 372            (status,already_found) t
 373      in
 374        aux ctx (status,false) t
 375   in
 376   let _,_,_,subst,_ = low_status#obj in
 377   let rec select status ctx pat cic =
 378     match pat, cic with
 379     | _, NCic.Meta (i,lc) when List.mem_assoc i subst ->
 380         let cic =
 381           let _,_,t,_ = NCicUtils.lookup_subst i subst in
 382           NCicSubstitution.subst_meta lc t
 383         in
 384         select status ctx pat cic
 385     | NCic.LetIn (_,t1,s1,b1), NCic.LetIn (n,t2,s2,b2) ->
 386         let status, t = select status ctx t1 t2 in
 387         let status, s = select status ctx s1 s2 in
 388         let ctx = (n, NCic.Def (s2,t2)) :: ctx in
 389         let status, b = select status ctx b1 b2 in
 390         status, NCic.LetIn (n,t,s,b)
 391     | NCic.Lambda (_,s1,t1), NCic.Lambda (n,s2,t2) ->
 392         let status, s = select status ctx s1 s2 in
 393         let ctx = (n, NCic.Decl s2) :: ctx in
 394         let status, t = select status ctx t1 t2 in
 395         status, NCic.Lambda (n,s,t)
 396     | NCic.Prod (_,s1,t1), NCic.Prod (n,s2,t2) ->
 397         let status, s = select status ctx s1 s2 in
 398         let ctx = (n, NCic.Decl s2) :: ctx in
 399         let status, t = select status ctx t1 t2 in
 400         status, NCic.Prod (n,s,t)
 401     | NCic.Appl l1, NCic.Appl l2 ->
 402         let status, l =
 403            List.fold_left2
 404              (fun (status,l) x y ->
 405               let status, x = select status ctx x y in
 406               status, x::l)
 407              (status,[]) l1 l2
 408         in
 409         status, NCic.Appl (List.rev l)
 410     | NCic.Match (_,ot1,t1,pl1), NCic.Match (u,ot2,t2,pl2) ->
 411         let status, t = select status ctx t1 t2 in
 412         let status, ot = select status ctx ot1 ot2 in
 413         let status, pl =
 414            List.fold_left2
 415              (fun (status,l) x y ->
 416               let status, x = select status ctx x y in
 417               status, x::l)
 418              (status,[]) pl1 pl2
 419         in
 420         status, NCic.Match (u,ot,t,List.rev pl)
 421     | NCic.Implicit `Hole, t ->
 422         (match wanted with
 423         | Some wanted ->
 424              let status', wanted = disambiguate status ctx wanted None in
 425              pp(lazy("wanted: "^ppterm status' wanted));
 426              let (status',found), t' = match_term status' ctx wanted t in
 427               if found then status',t' else status,t
 428         | None ->
 429            let (status,_),t = match_term status ctx (ctx,t) t in
 430             status,t)
 431     | NCic.Implicit _, t -> status, t
 432     | _,t ->
 433         fail (lazy ("malformed pattern: " ^ NCicPp.ppterm ~metasenv:[]
 434           ~context:[] ~subst:[] pat ^ " against " ^
 435           NCicPp.ppterm ~metasenv:[] ~subst:[] ~context:[] t))
 436   in
 437   pp(lazy ("select in: "^ppterm low_status (context,term)));
 438   let status, term = select low_status context path term in
 439   let term = (context, term) in
 440   pp(lazy ("postprocess: "^ppterm low_status term));
 441   postprocess status term
 442 ;;
 443
 444 let analyse_indty status ty =
 445  let status, reduct = whd status (ctx_of ty) ty in
 446  let ref, args =
 447   match reduct with
 448    | _,NCic.Const ref -> ref, []
 449    | _,NCic.Appl (NCic.Const (NRef.Ref (_,(NRef.Ind _)) as ref) :: args) ->
 450          ref, args
 451    | _,_ -> fail (lazy ("not an inductive type: " ^ ppterm status ty)) in
 452  let _,lno,tl,_,i = NCicEnvironment.get_checked_indtys ref in
 453  let _,_,_,cl = List.nth tl i in
 454  let consno = List.length cl in
 455  let left, right = HExtlib.split_nth lno args in
 456  status, (ref, consno, left, right)
 457 ;;
 458
 459 let apply_subst status ctx t =
 460  let status, (_,t) = relocate status ctx t in
 461  let _,_,_,subst,_ = status#obj in
 462   status, (ctx, NCicUntrusted.apply_subst subst ctx t)
 463 ;;
 464
 465 let apply_subst_context status ~fix_projections ctx =
 466  let _,_,_,subst,_ = status#obj in
 467   NCicUntrusted.apply_subst_context ~fix_projections subst ctx
 468 ;;
 469
 470 let metas_of_term status (context,t) =
 471  let _,_,_,subst,_ = status#obj in
 472  NCicUntrusted.metas_of_term subst context t
 473 ;;
 474
 475 (* ============= move this elsewhere ====================*)
 476
 477 class type ['stack] g_status =
 478  object
 479   inherit g_pstatus
 480   method stack: 'stack
 481  end
 482
 483 class ['stack] status =
 484  fun (o: NCic.obj) (s: 'stack) ->
 485  object (self)
 486    inherit (pstatus o)
 487    val stack = s
 488    method stack = stack
 489    method set_stack s = {< stack = s >}
 490    method set_status : 'status. 'stack #g_status as 'status -> 'self
 491    = fun o -> (self#set_pstatus o)#set_stack o#stack
 492   end
 493
 494 class type lowtac_status = [unit] status
 495
 496 type 'status lowtactic = #lowtac_status as 'status -> int -> 'status
 497
 498 class type tac_status = [Continuationals.Stack.t] status
 499
 500 type 'status tactic = #tac_status as 'status -> 'status
 501
 502 module NCicInverseRelIndexable : Discrimination_tree.Indexable
 503 with type input = cic_term and type constant_name = NUri.uri = struct
 504
 505 open Discrimination_tree
 506
 507 type input = cic_term
 508 type constant_name = NUri.uri
 509
 510 let ppelem = function
 511   | Constant (uri,arity) ->
 512       "("^NUri.name_of_uri uri ^ "," ^ string_of_int arity^")"
 513   | Bound (i,arity) ->
 514       "("^string_of_int i ^ "," ^ string_of_int arity^")"
 515   | Variable -> "?"
 516   | Proposition -> "Prop"
 517   | Datatype -> "Type"
 518   | Dead -> "Dead"
 519 ;;
 520
 521 let string_of_path l = String.concat "." (List.map ppelem l) ;;
 522
 523 let path_string_of (ctx,t) =
 524   let len_ctx = List.length ctx in
 525   let rec aux arity = function
 526     | NCic.Appl ((NCic.Meta _|NCic.Implicit _)::_) -> [Variable]
 527     | NCic.Appl (NCic.Lambda _ :: _) -> [Variable] (* maybe we should b-reduce *)
 528     | NCic.Appl [] -> assert false
 529     | NCic.Appl (hd::tl) ->
 530         aux (List.length tl) hd @ List.flatten (List.map (aux 0) tl)
 531     | NCic.Lambda _ | NCic.Prod _ -> [Variable]
 532         (* I think we should CicSubstitution.subst Implicit t *)
 533     | NCic.LetIn _ -> [Variable] (* z-reduce? *)
 534     | NCic.Meta _ | NCic.Implicit _ -> assert (arity = 0); [Variable]
 535     | NCic.Rel i -> [Bound (len_ctx - i, arity)]
 536     | NCic.Sort (NCic.Prop) -> assert (arity=0); [Proposition]
 537     | NCic.Sort _ -> assert (arity=0); [Datatype]
 538     | NCic.Const (NReference.Ref (u,_)) -> [Constant (u, arity)]
 539     | NCic.Match _ -> [Dead]
 540   in
 541   let path = aux 0 t in
 542 (*   prerr_endline (string_of_path path); *)
 543   path
 544 ;;
 545
 546 let compare e1 e2 =
 547   match e1,e2 with
 548   | Constant (u1,a1),Constant (u2,a2) ->
 549        let x = NUri.compare u1 u2 in
 550        if x = 0 then Pervasives.compare a1 a2 else x
 551   | e1,e2 -> Pervasives.compare e1 e2
 552 ;;
 553
 554
 555 end
 556
 557 module Ncic_termOT : Set.OrderedType with type t = cic_term =
 558  struct
 559    type t = cic_term
 560    let compare = Pervasives.compare
 561  end
 562
 563 module Ncic_termSet : Set.S with type elt = cic_term = Set.Make(Ncic_termOT)
 564
 565 module InvRelDiscriminationTree =
 566    Discrimination_tree.Make(NCicInverseRelIndexable)(Ncic_termSet)
 567