matita/components/ng_tactics/nTactics.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: nCic.ml 9058 2008-10-13 17:42:30Z tassi $ *)
  13
  14 open Printf
  15
  16 let debug = false
  17 let debug_print s = if debug then prerr_endline (Lazy.force s) else ()
  18
  19 open Continuationals.Stack
  20 open NTacStatus
  21 module Ast = CicNotationPt
  22
  23 let id_tac status = status ;;
  24 let print_tac print_status message status =
  25   if print_status then pp_tac_status status;
  26   prerr_endline message;
  27   status
  28 ;;
  29
  30 let dot_tac status =
  31   let gstatus =
  32     match status#stack with
  33     | [] -> assert false
  34     | ([], _, [], _) :: _ as stack ->
  35         (* backward compatibility: do-nothing-dot *)
  36         stack
  37     | (g, t, k, tag) :: s ->
  38         match filter_open g, k with
  39         | loc :: loc_tl, _ ->
  40              (([ loc ], t, loc_tl @+ k, tag) :: s)
  41         | [], loc :: k ->
  42             assert (is_open loc);
  43             (([ loc ], t, k, tag) :: s)
  44         | _ -> fail (lazy "can't use \".\" here")
  45   in
  46    status#set_stack gstatus
  47 ;;
  48
  49 let branch_tac ?(force=false) status =
  50   let gstatus =
  51     match status#stack with
  52     | [] -> assert false
  53     | (g, t, k, tag) :: s ->
  54           match init_pos g with (* TODO *)
  55           | [] -> fail (lazy "empty goals")
  56           | [_] when (not force) -> fail (lazy "too few goals to branch")
  57           | loc :: loc_tl ->
  58                ([ loc ], [], [], `BranchTag) :: (loc_tl, t, k, tag) :: s
  59   in
  60    status#set_stack gstatus
  61 ;;
  62
  63 let shift_tac status =
  64   let gstatus =
  65     match status#stack with
  66     | (g, t, k, `BranchTag) :: (g', t', k', tag) :: s ->
  67           (match g' with
  68           | [] -> fail (lazy "no more goals to shift")
  69           | loc :: loc_tl ->
  70                 (([ loc ], t @+ filter_open g @+ k, [],`BranchTag)
  71                 :: (loc_tl, t', k', tag) :: s))
  72      | _ -> fail (lazy "can't shift goals here")
  73   in
  74    status#set_stack gstatus
  75 ;;
  76
  77 let pos_tac i_s status =
  78   let gstatus =
  79     match status#stack with
  80     | [] -> assert false
  81     | ([ loc ], t, [],`BranchTag) :: (g', t', k', tag) :: s
  82       when is_fresh loc ->
  83         let l_js = List.filter (fun (i, _) -> List.mem i i_s) ([loc] @+ g') in
  84           ((l_js, t , [],`BranchTag)
  85            :: (([ loc ] @+ g') @- l_js, t', k', tag) :: s)
  86     | _ -> fail (lazy "can't use relative positioning here")
  87   in
  88    status#set_stack gstatus
  89 ;;
  90
  91 let case_tac lab status =
  92   let gstatus =
  93     match status#stack with
  94     | [] -> assert false
  95     | ([ loc ], t, [],`BranchTag) :: (g', t', k', tag) :: s
  96       when is_fresh loc ->
  97         let l_js =
  98           List.filter
  99            (fun curloc ->
 100               let _,_,metasenv,_,_ = status#obj in
 101               match NCicUtils.lookup_meta (goal_of_loc curloc) metasenv with
 102                   attrs,_,_ when List.mem (`Name lab) attrs -> true
 103                 | _ -> false) ([loc] @+ g') in
 104           ((l_js, t , [],`BranchTag)
 105            :: (([ loc ] @+ g') @- l_js, t', k', tag) :: s)
 106     | _ -> fail (lazy "can't use relative positioning here")
 107   in
 108    status#set_stack gstatus
 109 ;;
 110
 111 let wildcard_tac status =
 112   let gstatus =
 113     match status#stack with
 114     | [] -> assert false
 115     | ([ loc ] , t, [], `BranchTag) :: (g', t', k', tag) :: s
 116        when is_fresh loc ->
 117             (([loc] @+ g', t, [], `BranchTag) :: ([], t', k', tag) :: s)
 118     | _ -> fail (lazy "can't use wildcard here")
 119   in
 120    status#set_stack gstatus
 121 ;;
 122
 123 let merge_tac status =
 124   let gstatus =
 125     match status#stack with
 126     | [] -> assert false
 127     | (g, t, k,`BranchTag) :: (g', t', k', tag) :: s ->
 128         ((t @+ filter_open g @+ g' @+ k, t', k', tag) :: s)
 129     | _ -> fail (lazy "can't merge goals here")
 130   in
 131    status#set_stack gstatus
 132 ;;
 133
 134 let focus_tac gs status =
 135   let gstatus =
 136     match status#stack with
 137     | [] -> assert false
 138     | s -> assert(gs <> []);
 139           let stack_locs =
 140             let add_l acc _ _ l = if is_open l then l :: acc else acc in
 141             fold ~env:add_l ~cont:add_l ~todo:add_l [] s
 142           in
 143           List.iter
 144             (fun g ->
 145               if not (List.exists (fun l -> goal_of_loc l = g) stack_locs) then
 146                 fail (lazy (sprintf "goal %d not found (or closed)" g)))
 147             gs;
 148           (zero_pos gs, [], [], `FocusTag) :: deep_close gs s
 149   in
 150    status#set_stack gstatus
 151 ;;
 152
 153 let unfocus_tac status =
 154   let gstatus =
 155     match status#stack with
 156     | [] -> assert false
 157     | (g, [], [], `FocusTag) :: s when filter_open g = [] -> s
 158     | _ as s -> fail (lazy ("can't unfocus, some goals are still open:\n"^
 159       Continuationals.Stack.pp s))
 160   in
 161    status#set_stack gstatus
 162 ;;
 163
 164 let skip_tac status =
 165   let gstatus =
 166     match status#stack with
 167     | [] -> assert false
 168     | (gl, t, k, tag) :: s ->
 169         let gl = List.map switch_of_loc gl in
 170         if List.exists (function Open _ -> true | Closed _ -> false) gl then
 171           fail (lazy "cannot skip an open goal")
 172         else
 173           ([],t,k,tag) :: s
 174   in
 175    status#set_stack gstatus
 176 ;;
 177
 178 let block_tac l status =
 179   List.fold_left (fun status tac -> tac status) status l
 180 ;;
 181
 182
 183 let compare_statuses ~past ~present =
 184  let _,_,past,_,_ = past#obj in
 185  let _,_,present,_,_ = present#obj in
 186  List.map fst (List.filter (fun (i,_) -> not(List.mem_assoc i past)) present),
 187  List.map fst (List.filter (fun (i,_) -> not (List.mem_assoc i present)) past)
 188 ;;
 189
 190
 191
 192 (* Exec and distribute_tac form a retraction pair:
 193     1) exec (distribute_tac low_tac) (s,i) = low_tac (s,i)
 194     2) tac [s]::G = G1::...::Gn::G' && G' is G with some goals closed =>
 195          distribute_tac (exec tac) [s]::G = (G1@...Gn)::G'
 196     3) tac G = distribute_tac (exec tac) G if
 197        tac = distribute_tac lowtac
 198     4) atomic_tac t === distribute_tac (exec t)
 199
 200    Note that executing an high tactic on a set of goals may be stronger
 201    than executing the same tactic on those goals, but once at a time
 202    (e.g. the tactic could perform a global analysis of the set of goals)
 203 *)
 204
 205 let exec tac (low_status : #lowtac_status) g =
 206   let stack = [ [0,Open g], [], [], `NoTag ] in
 207   let status =
 208    (new NTacStatus.status low_status#obj stack)#set_estatus low_status
 209   in
 210   let status = tac status in
 211    (low_status#set_estatus status)#set_obj status#obj
 212 ;;
 213
 214 let distribute_tac tac (status : #tac_status) =
 215   match status#stack with
 216   | [] -> assert false
 217   | (g, t, k, tag) :: s ->
 218       debug_print (lazy ("context length " ^string_of_int (List.length g)));
 219       let rec aux s go gc =
 220         function
 221         | [] ->
 222             debug_print (lazy "no selected goals");
 223             s, go, gc
 224         | loc :: loc_tl ->
 225             debug_print (lazy "inner eval tactical");
 226             let s, go, gc =
 227               if List.exists ((=) (goal_of_loc loc)) gc then
 228                 s, go, gc
 229               else
 230                 match switch_of_loc loc with
 231                 | Closed _ -> fail (lazy "cannot apply to a Closed goal")
 232                 | Open n ->
 233                    let sn = tac s n in
 234                    let go', gc' = compare_statuses ~past:s ~present:sn in
 235                    sn, ((go @+ [n]) @- gc') @+ go', gc @+ gc'
 236             in
 237             aux s go gc loc_tl
 238       in
 239       let s0 = (new NTacStatus.status status#obj ())#set_estatus status in
 240       let s0, go0, gc0 = s0, [], [] in
 241       let sn, gon, gcn = aux s0 go0 gc0 g in
 242       debug_print (lazy ("opened: "
 243         ^ String.concat " " (List.map string_of_int gon)));
 244       debug_print (lazy ("closed: "
 245         ^ String.concat " " (List.map string_of_int gcn)));
 246       let stack =
 247         (zero_pos gon, t @~- gcn, k @~- gcn, tag) :: deep_close gcn s
 248       in
 249        ((status#set_stack stack)#set_obj(sn:>lowtac_status)#obj)#set_estatus sn
 250 ;;
 251
 252 let atomic_tac htac : #tac_status as 'a -> 'a = distribute_tac (exec htac) ;;
 253
 254 let repeat_tac t s =
 255   let rec repeat t (status : #tac_status as 'a) : 'a =
 256     try repeat t (t status)
 257     with NTacStatus.Error _ -> status
 258   in
 259     atomic_tac (repeat t) s
 260 ;;
 261
 262
 263 let try_tac tac status =
 264   try
 265     tac status
 266   with NTacStatus.Error _ ->
 267     status
 268 ;;
 269
 270 let first_tac tacl status =
 271   let res =
 272    HExtlib.list_findopt
 273     (fun tac _ -> try Some (tac status) with NTacStatus.Error _ -> None) tacl
 274   in
 275     match res with
 276       | None -> fail (lazy "No tactics left")
 277       | Some x -> x
 278 ;;
 279
 280 let exact_tac t : 's tactic = distribute_tac (fun status goal ->
 281  instantiate_with_ast status goal t)
 282 ;;
 283
 284 let assumption_tac status = distribute_tac (fun status goal ->
 285   let gty = get_goalty status goal in
 286   let context = ctx_of gty in
 287   let htac =
 288    first_tac
 289     (List.map (fun (name,_) -> exact_tac ("",0,(Ast.Ident (name,None))))
 290       context)
 291   in
 292     exec htac status goal) status
 293 ;;
 294
 295 let find_in_context name context =
 296   let rec aux acc = function
 297     | [] -> raise Not_found
 298     | (hd,_) :: tl when hd = name -> acc
 299     | _ :: tl ->  aux (acc + 1) tl
 300   in
 301   aux 1 context
 302 ;;
 303
 304 let clear_tac names =
 305  if names = [] then id_tac
 306  else
 307   distribute_tac (fun status goal ->
 308    let goalty = get_goalty status goal in
 309    let js =
 310      List.map
 311      (fun name ->
 312         try find_in_context name (ctx_of goalty)
 313         with Not_found ->
 314           fail (lazy ("hypothesis '" ^ name ^ "' not found")))
 315      names
 316    in
 317    let n,h,metasenv,subst,o = status#obj in
 318    let metasenv,subst,_,_ = NCicMetaSubst.restrict metasenv subst goal js in
 319     status#set_obj (n,h,metasenv,subst,o))
 320 ;;
 321
 322 let generalize0_tac args =
 323  if args = [] then id_tac
 324  else exact_tac ("",0,Ast.Appl (Ast.Implicit `JustOne :: args))
 325 ;;
 326
 327 let select0_tac ~where:(wanted,hyps,where) ~job  =
 328  let found, postprocess =
 329    match job with
 330    | `Substexpand argsno -> mk_in_scope, mk_out_scope argsno
 331    | `Collect l -> (fun s t -> l := t::!l; mk_in_scope s t), mk_out_scope 1
 332    | `ChangeWith f -> f,(fun s t -> s, t)
 333  in
 334  distribute_tac (fun status goal ->
 335    let goalty = get_goalty status goal in
 336    let path =
 337      match where with None -> NCic.Implicit `Term | Some where -> where
 338    in
 339    let status, newgoalctx =
 340       List.fold_right
 341        (fun (name,d as entry) (status,ctx) ->
 342          try
 343           let path = List.assoc name hyps in
 344            match d with
 345               NCic.Decl ty ->
 346                let status,ty =
 347                 select_term status ~found ~postprocess (mk_cic_term ctx ty)
 348                  (wanted,path) in
 349                let status,ty = term_of_cic_term status ty ctx in
 350                 status,(name,NCic.Decl ty)::ctx
 351             | NCic.Def (bo,ty) ->
 352                let status,bo =
 353                 select_term status ~found ~postprocess (mk_cic_term ctx bo)
 354                  (wanted,path) in
 355                let status,bo = term_of_cic_term status bo ctx in
 356                 status,(name,NCic.Def (bo,ty))::ctx
 357          with
 358           Not_found -> status, entry::ctx
 359        ) (ctx_of goalty) (status,[])
 360    in
 361    let status, newgoalty =
 362      select_term status ~found ~postprocess goalty (wanted,path) in
 363    (* WARNING: the next two lines simply change the context of newgoalty
 364       from the old to the new one. Otherwise mk_meta will do that herself,
 365       calling relocate that calls delift. However, newgoalty is now
 366       ?[out_scope] and thus the delift would trigger the special unification
 367       case, which is wrong now :-( *)
 368    let status,newgoalty = term_of_cic_term status newgoalty (ctx_of goalty) in
 369    let newgoalty = mk_cic_term newgoalctx newgoalty in
 370
 371    let status, instance =
 372      mk_meta status newgoalctx (`Decl newgoalty) `IsTerm
 373    in
 374    instantiate status goal instance)
 375 ;;
 376
 377 let select_tac ~where ~job move_down_hyps =
 378  let (wanted,hyps,where) = GrafiteDisambiguate.disambiguate_npattern where in
 379  let path =
 380   match where with None -> NCic.Implicit `Term | Some where -> where in
 381  if not move_down_hyps then
 382   select0_tac ~where:(wanted,hyps,Some path) ~job
 383  else
 384   let path =
 385    List.fold_left
 386      (fun path (name,path_name) -> NCic.Prod ("_",path_name,path))
 387      path (List.rev hyps)
 388   in
 389    block_tac [
 390      generalize0_tac (List.map (fun (name,_) -> Ast.Ident (name,None)) hyps);
 391      select0_tac ~where:(wanted,[],Some path) ~job;
 392      clear_tac (List.map fst hyps) ]
 393 ;;
 394
 395 let generalize_tac ~where =
 396  let l = ref [] in
 397  block_tac [
 398    select_tac ~where ~job:(`Collect l) true;
 399    (fun s -> distribute_tac (fun status goal ->
 400       let goalty = get_goalty status goal in
 401       let status,canon,rest =
 402        match !l with
 403           [] ->
 404            (match where with
 405                _,_,(None,_,_)  -> fail (lazy "No term to generalize")
 406              | txt,txtlen,(Some what,_,_) ->
 407                 let status, what =
 408                  disambiguate status (ctx_of goalty) (txt,txtlen,what) None
 409                 in
 410                  status,what,[]
 411            )
 412         | he::tl -> status,he,tl in
 413       let status =
 414        List.fold_left
 415          (fun s t -> unify s (ctx_of goalty) canon t) status rest in
 416       let status, canon = term_of_cic_term status canon (ctx_of goalty) in
 417       instantiate status goal
 418        (mk_cic_term (ctx_of goalty) (NCic.Appl [NCic.Implicit `Term ; canon ]))
 419    ) s) ]
 420 ;;
 421
 422 let cut_tac t =
 423  atomic_tac (block_tac [
 424   exact_tac ("",0, Ast.Appl [Ast.Implicit `JustOne; Ast.Implicit `JustOne]);
 425   branch_tac;
 426    pos_tac [3]; exact_tac t;
 427    shift_tac; pos_tac [2]; skip_tac;
 428   merge_tac ])
 429 ;;
 430
 431 let lapply_tac (s,n,t) =
 432  exact_tac (s,n, Ast.Appl [Ast.Implicit `JustOne; t])
 433 ;;
 434
 435 let reduce_tac ~reduction ~where =
 436   let change status t =
 437     match reduction with
 438     | `Normalize perform_delta ->
 439         normalize status
 440          ?delta:(if perform_delta then None else Some max_int) (ctx_of t) t
 441     | `Whd perform_delta ->
 442         whd status
 443          ?delta:(if perform_delta then None else Some max_int) (ctx_of t) t
 444   in
 445   let where = GrafiteDisambiguate.disambiguate_npattern where in
 446   select0_tac ~where ~job:(`ChangeWith change)
 447 ;;
 448
 449 let change_tac ~where ~with_what =
 450   let change status t =
 451     let status, ww = disambiguate status (ctx_of t) with_what  None in
 452     let status = unify status (ctx_of t) t ww in
 453     status, ww
 454   in
 455   let where = GrafiteDisambiguate.disambiguate_npattern where in
 456   select0_tac ~where ~job:(`ChangeWith change)
 457 ;;
 458
 459 let letin_tac ~where ~what:(_,_,w) name =
 460  block_tac [
 461   select_tac ~where ~job:(`Substexpand 1) true;
 462   exact_tac
 463    ("",0,Ast.LetIn((Ast.Ident (name,None),None),w,Ast.Implicit `JustOne));
 464  ]
 465 ;;
 466
 467 let apply_tac (s,n,t) =
 468   let t = Ast.Appl [t; Ast.Implicit `Vector] in
 469   exact_tac (s,n,t)
 470 ;;
 471
 472 type indtyinfo = {
 473         rightno: int;
 474         leftno: int;
 475         consno: int;
 476         lefts: NCic.term list;
 477         rights: NCic.term list;
 478         reference: NReference.reference;
 479  }
 480 ;;
 481
 482 let ref_of_indtyinfo iti = iti.reference;;
 483
 484 let analyze_indty_tac ~what indtyref =
 485  distribute_tac (fun status goal ->
 486   let goalty = get_goalty status goal in
 487   let status, what = disambiguate status (ctx_of goalty) what None in
 488   let status, ty_what = typeof status (ctx_of what) what in
 489   let status, (r,consno,lefts,rights) = analyse_indty status ty_what in
 490   let leftno = List.length lefts in
 491   let rightno = List.length rights in
 492   indtyref := Some {
 493     rightno = rightno; leftno = leftno; consno = consno;
 494     lefts = lefts; rights = rights; reference = r;
 495   };
 496   exec id_tac status goal)
 497 ;;
 498
 499 let sort_of_goal_tac sortref = distribute_tac (fun status goal ->
 500   let goalty = get_goalty status goal in
 501   let status,sort = typeof status (ctx_of goalty) goalty in
 502   let status, sort = fix_sorts status sort in
 503   let status, sort = term_of_cic_term status sort (ctx_of goalty) in
 504    sortref := sort;
 505    status)
 506 ;;
 507
 508 let elim_tac ~what:(txt,len,what) ~where =
 509   let what = txt, len, Ast.Appl [what; Ast.Implicit `Vector] in
 510   let indtyinfo = ref None in
 511   let sort = ref (NCic.Rel 1) in
 512   atomic_tac (block_tac [
 513     analyze_indty_tac ~what indtyinfo;
 514     (fun s -> select_tac
 515       ~where ~job:(`Substexpand ((HExtlib.unopt !indtyinfo).rightno+1)) true s);
 516     sort_of_goal_tac sort;
 517     (fun status ->
 518      let ity = HExtlib.unopt !indtyinfo in
 519      let NReference.Ref (uri, _) = ity.reference in
 520      let name =
 521        NUri.name_of_uri uri ^ "_" ^
 522         snd (NCicElim.ast_of_sort
 523           (match !sort with NCic.Sort x -> x | _ -> assert false))
 524      in
 525      let eliminator =
 526        let _,_,w = what in
 527        Ast.Appl [ Ast.Ident (name,None) ; Ast.Implicit `Vector ; w ]
 528      in
 529      exact_tac ("",0,eliminator) status) ])
 530 ;;
 531
 532 let rewrite_tac ~dir ~what:(_,_,what) ~where status =
 533  let sortref = ref (NCic.Rel 1) in
 534  let status = sort_of_goal_tac sortref status in
 535  let suffix = "_" ^ snd (NCicElim.ast_of_sort
 536    (match !sortref with NCic.Sort x -> x | _ -> assert false))
 537  in
 538  let name =
 539   match dir with
 540      `LeftToRight -> "eq" ^ suffix ^ "_r"
 541    | `RightToLeft -> "eq" ^ suffix
 542  in
 543   block_tac
 544    [ select_tac ~where ~job:(`Substexpand 2) true;
 545      exact_tac
 546       ("",0,
 547        Ast.Appl(Ast.Ident(name,None)::HExtlib.mk_list (Ast.Implicit `JustOne) 5@
 548         [what]))] status
 549 ;;
 550
 551 let intro_tac name =
 552  block_tac
 553   [ exact_tac
 554      ("",0,(Ast.Binder (`Lambda,
 555       (Ast.Ident (name,None),None),Ast.Implicit `JustOne)));
 556     if name = "_" then clear_tac [name] else id_tac ]
 557 ;;
 558
 559 let name_counter = ref 0;;
 560 let intros_tac ?names_ref names s =
 561   let names_ref, prefix =
 562     match names_ref with | None -> ref [], "__" | Some r -> r, "H"
 563   in
 564   if names = [] then
 565    repeat_tac
 566      (fun s ->
 567         incr name_counter;
 568         (* TODO: generate better names *)
 569         let name = prefix ^ string_of_int !name_counter in
 570         let s = intro_tac name s in
 571         names_ref := !names_ref @ [name];
 572         s)
 573      s
 574    else
 575      block_tac (List.map intro_tac names) s
 576 ;;
 577
 578 let cases ~what status goal =
 579  let gty = get_goalty status goal in
 580  let status, what = disambiguate status (ctx_of gty) what None in
 581  let status, ty = typeof status (ctx_of what) what in
 582  let status, (ref, consno, _, _) = analyse_indty status ty in
 583  let status, what = term_of_cic_term status what (ctx_of gty) in
 584  let t =
 585   NCic.Match (ref,NCic.Implicit `Term, what,
 586     HExtlib.mk_list (NCic.Implicit `Term) consno)
 587  in
 588  instantiate status goal (mk_cic_term (ctx_of gty) t)
 589 ;;
 590
 591 let cases_tac ~what:(txt,len,what) ~where =
 592   let what = txt, len, Ast.Appl [what; Ast.Implicit `Vector] in
 593   let indtyinfo = ref None in
 594   atomic_tac
 595    (block_tac [
 596       analyze_indty_tac ~what indtyinfo;
 597       (fun s -> select_tac
 598        ~where ~job:(`Substexpand ((HExtlib.unopt !indtyinfo).rightno+1))true s);
 599       distribute_tac (cases ~what) ])
 600 ;;
 601
 602 let case1_tac name =
 603  let name = if name = "_" then "_clearme" else name in
 604  block_tac [ intro_tac name;
 605              cases_tac
 606               ~where:("",0,(None,[],None))
 607               ~what:("",0,Ast.Ident (name,None));
 608              if name = "_clearme" then clear_tac ["_clearme"] else id_tac ]
 609 ;;
 610
 611 let constructor_tac ?(num=1) ~args = distribute_tac (fun status goal ->
 612   if num < 1 then fail (lazy "constructor numbers begin with 1");
 613   let gty = get_goalty status goal in
 614   let status, (r,_,_,_) = analyse_indty status gty in
 615   let ref = NReference.mk_constructor num r in
 616   let t =
 617     if args = [] then Ast.NRef ref else
 618     Ast.Appl (HExtlib.list_concat ~sep:[Ast.Implicit `Vector]
 619       ([Ast.NRef ref] :: List.map (fun _,_,x -> [x]) args))
 620   in
 621   exec (apply_tac ("",0,t)) status goal)
 622 ;;
 623
 624 let assert0_tac (hyps,concl) = distribute_tac (fun status goal ->
 625  let gty = get_goalty status goal in
 626  let eq status ctx t1 t2 =
 627   let status,t1 = disambiguate status ctx t1 None in
 628   let status,t1 = apply_subst status ctx t1 in
 629   let status,t1 = term_of_cic_term status t1 ctx in
 630   let t2 = mk_cic_term ctx t2 in
 631   let status,t2 = apply_subst status ctx t2 in
 632   let status,t2 = term_of_cic_term status t2 ctx in
 633   prerr_endline ("COMPARING: " ^ NCicPp.ppterm ~subst:[] ~metasenv:[] ~context:ctx t1 ^ " vs " ^ NCicPp.ppterm ~subst:[] ~metasenv:[] ~context:ctx t2);
 634   assert (t1=t2);
 635   status
 636  in
 637  let status,gty' = term_of_cic_term status gty (ctx_of gty) in
 638  let status = eq status (ctx_of gty) concl gty' in
 639  let status,_ =
 640   List.fold_right2
 641    (fun (id1,e1) ((id2,e2) as item) (status,ctx) ->
 642      assert (id1=id2 || (prerr_endline (id1 ^ " vs " ^ id2); false));
 643      match e1,e2 with
 644         `Decl t1, NCic.Decl t2 ->
 645           let status = eq status ctx t1 t2 in
 646           status,item::ctx
 647       | `Def (b1,t1), NCic.Def (b2,t2) ->
 648           let status = eq status ctx t1 t2 in
 649           let status = eq status ctx b1 b2 in
 650           status,item::ctx
 651       | _ -> assert false
 652    ) hyps (ctx_of gty) (status,[])
 653  in
 654   exec id_tac status goal)
 655 ;;
 656
 657 let assert_tac seqs status =
 658  match status#stack with
 659   | [] -> assert false
 660   | (g,_,_,_) :: s ->
 661      assert (List.length g = List.length seqs);
 662      (match seqs with
 663          [] -> id_tac
 664        | [seq] -> assert0_tac seq
 665        | _ ->
 666          block_tac
 667           ((branch_tac ~force:false)::
 668           HExtlib.list_concat ~sep:[shift_tac]
 669             (List.map (fun seq -> [assert0_tac seq]) seqs)@
 670           [merge_tac])
 671      ) status
 672 ;;
 673
 674 let inversion_tac ~what:(txt,len,what) ~where =
 675   let what = txt, len, Ast.Appl [what; Ast.Implicit `Vector] in
 676   let indtyinfo = ref None in
 677   let sort = ref (NCic.Rel 1) in
 678   atomic_tac (block_tac [
 679     analyze_indty_tac ~what indtyinfo;
 680     (fun s -> select_tac
 681       ~where ~job:(`Substexpand ((HExtlib.unopt !indtyinfo).rightno+1)) true s);
 682     sort_of_goal_tac sort;
 683     (fun status ->
 684      let ity = HExtlib.unopt !indtyinfo in
 685      let NReference.Ref (uri, _) = ity.reference in
 686      let name =
 687        NUri.name_of_uri uri ^ "_inv_" ^
 688         snd (NCicElim.ast_of_sort
 689           (match !sort with NCic.Sort x -> x | _ -> assert false))
 690      in
 691      let eliminator =
 692        let _,_,w = what in
 693        Ast.Appl [ Ast.Ident (name,None) ; Ast.Implicit `Vector ; w ]
 694      in
 695      exact_tac ("",0,eliminator) status) ])
 696 ;;