matita/components/registry/helm_registry.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 let debug = false
  31 let debug_print s =
  32   if debug then prerr_endline ("Helm_registry debugging: " ^ (Lazy.force s))
  33
  34   (** <helpers> *)
  35
  36 let list_uniq l =
  37   let rec aux last_element = function
  38     | [] -> []
  39     | hd :: tl ->
  40         (match last_element with
  41         | Some elt when elt = hd -> aux last_element tl
  42         | _ -> hd :: aux (Some hd) tl)
  43   in
  44   aux None l
  45
  46 let starts_with prefix =
  47 (*
  48   let rex = Str.regexp (Str.quote prefix) in
  49   fun s -> Str.string_match rex s 0
  50 *)
  51   let prefix_len = String.length prefix in
  52   fun s ->
  53     try
  54       String.sub s 0 prefix_len = prefix
  55     with Invalid_argument _ -> false
  56
  57 (*let hashtbl_keys tbl = Hashtbl.fold (fun k _ acc -> k :: acc) tbl []*)
  58 let hashtbl_pairs tbl = Hashtbl.fold (fun k v acc -> (k,v) :: acc) tbl []
  59
  60   (** </helpers> *)
  61
  62 exception Malformed_key of string
  63 exception Key_not_found of string
  64 exception Cyclic_definition of string
  65 exception Type_error of string (* expected type, value, msg *)
  66 exception Parse_error of string * int * int * string  (* file, line, col, msg *)
  67
  68   (* root XML tag: used by save_to, ignored by load_from *)
  69 let root_tag = "helm_registry"
  70
  71 let magic_size = 127
  72
  73 let backup_registry registry = Hashtbl.copy registry
  74 let restore_registry backup registry =
  75   Hashtbl.clear registry;
  76   Hashtbl.iter (fun key value -> Hashtbl.add registry key value) backup
  77
  78   (* as \\w but:
  79    * - no sequences of '_' longer than 1 are permitted
  80    *)
  81 let valid_step_rex_raw = "[a-zA-Z0-9]+\\(_[a-z0A-Z-9]+\\)*"
  82 let valid_key_rex_raw =
  83   sprintf "%s\\(\\.%s\\)*" valid_step_rex_raw valid_step_rex_raw
  84 let valid_key_rex = Str.regexp ("^" ^ valid_key_rex_raw ^ "$")
  85 let interpolated_key_rex = Str.regexp ("\\$(" ^ valid_key_rex_raw ^ ")")
  86 let dot_rex = Str.regexp "\\."
  87 let spaces_rex = Str.regexp "[ \t\n\r]+"
  88 (*let heading_spaces_rex = Str.regexp "^[ \t\n\r]+"*)
  89 let margin_blanks_rex =
  90   Str.regexp "^\\([ \t\n\r]*\\)\\([^ \t\n\r]*\\)\\([ \t\n\r]*\\)$"
  91
  92 let strip_blanks s = Str.global_replace margin_blanks_rex "\\2" s
  93
  94 (*let split s =
  95   (* trailing blanks are removed per default by split *)
  96   Str.split spaces_rex (Str.global_replace heading_spaces_rex "" s)*)
  97 (*let merge l = String.concat " " l*)
  98
  99 let handle_type_error f x =
 100   try f x with exn -> raise (Type_error (Printexc.to_string exn))
 101
 102   (** marshallers/unmarshallers *)
 103 let string x = x
 104 let int = handle_type_error int_of_string
 105 let float = handle_type_error float_of_string
 106 let bool = handle_type_error bool_of_string
 107 let of_string x = x
 108 let of_int = handle_type_error string_of_int
 109 let of_float = handle_type_error string_of_float
 110 let of_bool = handle_type_error string_of_bool
 111
 112 (* FG *)
 113 let pair fst_unmarshaller snd_unmarshaller v =
 114   match Str.split spaces_rex v with
 115   | [fst; snd] -> fst_unmarshaller fst, snd_unmarshaller snd
 116   | _ -> raise (Type_error "not a pair")
 117
 118 (* FG *)
 119 let triple fst_unmarshaller snd_unmarshaller trd_unmarshaller v =
 120   match Str.split spaces_rex v with
 121   | [fst; snd; trd] -> fst_unmarshaller fst, snd_unmarshaller snd, trd_unmarshaller trd
 122   | _ -> raise (Type_error "not a triple")
 123
 124 (* FG *)
 125 let quad fst_unmarshaller snd_unmarshaller trd_unmarshaller fth_unmarshaller v =
 126   match Str.split spaces_rex v with
 127   | [fst; snd; trd; fth] -> fst_unmarshaller fst, snd_unmarshaller snd, trd_unmarshaller trd, fth_unmarshaller fth
 128   | _ -> raise (Type_error "not a quad")
 129
 130   (* escapes for xml configuration file *)
 131 (*let (escape, unescape) =
 132   let (in_enc, out_enc) = (`Enc_utf8, `Enc_utf8) in
 133   (Netencoding.Html.encode ~in_enc ~out_enc (),
 134    Netencoding.Html.decode ~in_enc ~out_enc ~entity_base:`Xml ())*)
 135
 136 let key_is_valid key =
 137   if not (Str.string_match valid_key_rex key 0) then
 138     raise (Malformed_key key)
 139
 140 let set' ?(replace=false) registry ~key ~value =
 141   debug_print (lazy(sprintf "Setting (replace: %b) %s = %s" replace key value));
 142   key_is_valid key;
 143   let add_fun = if replace then Hashtbl.replace else Hashtbl.add in
 144   add_fun registry key value
 145
 146 let unset registry = Hashtbl.remove registry
 147
 148 let env_var_of_key s = String.uppercase_ascii (Str.global_replace dot_rex "_" s)
 149
 150 let singleton = function
 151   | [] ->
 152       raise (Type_error ("empty list value found where singleton was expected"))
 153   | hd :: _ -> hd
 154
 155 let get registry key =
 156   let rec aux stack key =
 157     key_is_valid key;
 158     if List.mem key stack then begin
 159       let msg = (String.concat " -> " (List.rev stack)) ^ " -> " ^ key in
 160       raise (Cyclic_definition msg)
 161     end;
 162       (* internal value *)
 163     let registry_values = List.rev (Hashtbl.find_all registry key) in
 164     let env_value = (* environment value *)
 165       try
 166         Some (Sys.getenv (env_var_of_key key))
 167       with Not_found -> None
 168     in
 169     let values = (* resulting value *)
 170       match registry_values, env_value with
 171       | _, Some env -> [env]
 172       | [], None ->
 173           (try
 174             [ Sys.getenv key ]
 175           with Not_found -> raise (Key_not_found key))
 176       | values, None -> values
 177     in
 178     List.map (interpolate (key :: stack)) values
 179   and interpolate stack value =
 180     Str.global_substitute interpolated_key_rex
 181       (fun s ->
 182         let matched = Str.matched_string s in
 183           (* "$(var)" -> "var" *)
 184         let key = String.sub matched 2 (String.length matched - 3) in
 185         singleton (aux stack key))
 186       value
 187   in
 188   List.map strip_blanks (aux [] key)
 189
 190 let has registry key = Hashtbl.mem registry key
 191
 192 let get_typed registry unmarshaller key =
 193   let value = singleton (get registry key) in
 194   unmarshaller value
 195
 196 let set_typed registry marshaller ~key ~value =
 197   set' ~replace:true registry ~key ~value:(marshaller value)
 198
 199 let get_opt registry unmarshaller key =
 200   try
 201     Some (unmarshaller (singleton (get registry key)))
 202   with Key_not_found _ -> None
 203
 204 let get_opt_default registry unmarshaller ~default key =
 205   match get_opt registry unmarshaller key with
 206   | None -> default
 207   | Some v -> v
 208
 209 let set_opt registry marshaller ~key ~value =
 210   match value with
 211   | None -> unset registry key
 212   | Some value -> set' ~replace:true registry ~key ~value:(marshaller value)
 213
 214 let get_list registry unmarshaller key =
 215   try
 216     let tmp = get registry key in
 217     let rc = List.map unmarshaller tmp in
 218     rc
 219   with Key_not_found _ -> []
 220
 221 (* FG *)
 222 let get_pair registry fst_unmarshaller snd_unmarshaller =
 223   get_typed registry (pair fst_unmarshaller snd_unmarshaller)
 224
 225 (* FG *)
 226 let get_triple registry fst_unmarshaller snd_unmarshaller trd_unmarshaller =
 227   get_typed registry (triple fst_unmarshaller snd_unmarshaller trd_unmarshaller)
 228
 229 (* FG *)
 230 let get_quad registry fst_unmarshaller snd_unmarshaller trd_unmarshaller fth_unmarshaller =
 231   get_typed registry (quad fst_unmarshaller snd_unmarshaller trd_unmarshaller fth_unmarshaller)
 232
 233 let set_list registry marshaller ~key ~value =
 234   (* since ocaml hash table are crazy... *)
 235   while Hashtbl.mem registry key do
 236     Hashtbl.remove registry key
 237   done;
 238   List.iter (fun v -> set' registry ~key ~value:(marshaller v)) value
 239
 240 type xml_tree =
 241   | Cdata of string
 242   | Element of string * (string * string) list * xml_tree list
 243
 244 let dot_RE = Str.regexp "\\."
 245
 246 let xml_tree_of_registry registry =
 247   let has_child name elements =
 248     List.exists
 249       (function
 250         | Element (_, ["name", name'], _) when name = name' -> true
 251         | _ -> false)
 252       elements
 253   in
 254   let rec get_child name = function
 255     | [] -> assert false
 256     | (Element (_, ["name", name'], _) as child) :: tl when name = name' ->
 257         child, tl
 258     | hd :: tl ->
 259         let child, rest = get_child name tl in
 260         child, hd :: rest
 261   in
 262   let rec add_key path value tree =
 263     match path, tree with
 264     | [key], Element (name, attrs, children) ->
 265         Element (name, attrs,
 266           Element ("key", ["name", key],
 267             [Cdata (strip_blanks value)]) :: children)
 268     | dir :: path, Element (name, attrs, children) ->
 269         if has_child dir children then
 270           let child, rest = get_child dir children in
 271           Element (name, attrs, add_key path value child :: rest)
 272         else
 273           Element (name, attrs,
 274             ((add_key path value (Element ("section", ["name", dir], [])))
 275               :: children))
 276     | _ -> assert false
 277   in
 278   Hashtbl.fold
 279     (fun k v tree -> add_key ((Str.split dot_RE k)) v tree)
 280     registry
 281     (Element (root_tag, [], []))
 282
 283 let rec stream_of_xml_tree = function
 284   | Cdata s -> Xml.xml_cdata s
 285   | Element (name, attrs, children) ->
 286       Xml.xml_nempty name
 287         (List.map (fun (n, v) -> (None, n, v)) attrs)
 288         (stream_of_xml_trees children)
 289 and stream_of_xml_trees = function
 290   | [] -> [< >]
 291   | hd :: tl -> [< stream_of_xml_tree hd; stream_of_xml_trees tl >]
 292
 293 let save_to registry fname =
 294   let token_stream = stream_of_xml_tree (xml_tree_of_registry registry) in
 295   let oc = open_out fname in
 296   Xml.pp_to_outchan token_stream oc;
 297   close_out oc
 298
 299 let rec load_from_absolute ?path registry fname =
 300   let _path = ref (match path with None -> [] | Some p -> p)in
 301     (* <section> elements entered so far *)
 302   let in_key = ref false in (* have we entered a <key> element? *)
 303   let cdata = ref "" in     (* collected cdata (inside <key> *)
 304   let push_path name = _path := name :: !_path in
 305   let pop_path () = _path := List.tl !_path in
 306   let start_element tag attrs =
 307     match tag, attrs with
 308     | "section", ["name", name] -> push_path name
 309     | "key", ["name", name] -> in_key := true; push_path name
 310     | "helm_registry", _ -> ()
 311     | "include", ["href", fname] ->
 312         debug_print (lazy ("including file " ^ fname));
 313         load_from_absolute ~path:!_path registry fname
 314     | tag, _ ->
 315         raise (Parse_error (fname, ~-1, ~-1,
 316           (sprintf "unexpected element <%s> or wrong attribute set" tag)))
 317   in
 318   let end_element tag =
 319     match tag with
 320     | "section" -> pop_path ()
 321     | "key" ->
 322         let key = String.concat "." (List.rev !_path) in
 323         set' registry ~key ~value:!cdata;
 324         cdata := "";
 325         in_key := false;
 326         pop_path ()
 327     | "include" | "helm_registry" -> ()
 328     | _ -> assert false
 329   in
 330   let character_data text =
 331     if !in_key then cdata := !cdata ^ text
 332   in
 333   let callbacks = {
 334     XmlPushParser.default_callbacks with
 335       XmlPushParser.start_element = Some start_element;
 336       XmlPushParser.end_element = Some end_element;
 337       XmlPushParser.character_data = Some character_data;
 338   } in
 339   let xml_parser = XmlPushParser.create_parser callbacks in
 340   let backup = backup_registry registry in
 341 (*   if path = None then Hashtbl.clear registry; *)
 342   try
 343     XmlPushParser.parse xml_parser (`File fname)
 344   with exn ->
 345     restore_registry backup registry;
 346     raise exn
 347
 348 let load_from registry ?path fname =
 349   if Filename.is_relative fname then begin
 350     let no_file_found = ref true in
 351     let path =
 352       match path with
 353       | Some path -> path (* path given as argument *)
 354       | None -> [ Sys.getcwd () ] (* no path given, try with cwd *)
 355     in
 356     List.iter
 357       (fun dir ->
 358         let conffile = dir ^ "/" ^ fname in
 359         if Sys.file_exists conffile then begin
 360           no_file_found := false;
 361           load_from_absolute registry conffile
 362         end)
 363        path;
 364     if !no_file_found then
 365       failwith (sprintf
 366         "Helm_registry.init: no configuration file named %s in [ %s ]"
 367         fname (String.concat "; " path))
 368   end else
 369     load_from_absolute registry fname
 370
 371 let fold registry ?prefix ?(interpolate = true) f init =
 372   let value_of k v =
 373     if interpolate then singleton (get registry k) else strip_blanks v
 374   in
 375   match prefix with
 376   | None -> Hashtbl.fold (fun k v acc -> f acc k (value_of k v)) registry init
 377   | Some s ->
 378       let key_matches = starts_with (s ^ ".") in
 379       let rec fold_filter acc = function
 380         | [] -> acc
 381         | (k,v) :: tl when key_matches k ->
 382             fold_filter (f acc k (value_of k v)) tl
 383         | _ :: tl -> fold_filter acc tl
 384       in
 385       fold_filter init (hashtbl_pairs registry)
 386
 387 let iter registry ?prefix ?interpolate f =
 388   fold registry ?prefix ?interpolate (fun _ k v -> f k v) ()
 389 let to_list registry ?prefix ?interpolate () =
 390   fold registry ?prefix ?interpolate (fun acc k v -> (k, v) :: acc) []
 391
 392 let ls registry prefix =
 393   let prefix = prefix ^ "." in
 394   let prefix_len = String.length prefix in
 395   let key_matches = starts_with prefix in
 396   let matching_keys = (* collect matching keys' _postfixes_ *)
 397     fold registry
 398       (fun acc key _ ->
 399         if key_matches key then
 400           String.sub key prefix_len (String.length key - prefix_len) :: acc
 401         else
 402           acc)
 403       []
 404   in
 405   let (sections, keys) =
 406     List.fold_left
 407       (fun (sections, keys) postfix ->
 408         match Str.split dot_rex postfix with
 409         | [key] -> (sections, key :: keys)
 410         | hd_key :: _ ->  (* length > 1 => nested section found *)
 411             (hd_key :: sections, keys)
 412         | _ -> assert false)
 413       ([], []) matching_keys
 414   in
 415   (list_uniq (List.sort Pervasives.compare sections), keys)
 416
 417 (** {2 API implementation}
 418  * functional methods above are wrapped so that they work on a default
 419  * (imperative) registry*)
 420
 421 let default_registry = Hashtbl.create magic_size
 422
 423 let get key = singleton (get default_registry key)
 424 let set = set' ~replace:true default_registry
 425 let has = has default_registry
 426 let fold ?prefix ?interpolate f init =
 427   fold default_registry ?prefix ?interpolate f init
 428 let iter = iter default_registry
 429 let to_list = to_list default_registry
 430 let ls = ls default_registry
 431 let get_typed unmarshaller = get_typed default_registry unmarshaller
 432 let get_opt unmarshaller = get_opt default_registry unmarshaller
 433 let get_opt_default unmarshaller = get_opt_default default_registry unmarshaller
 434 let get_list unmarshaller = get_list default_registry unmarshaller
 435 let get_pair unmarshaller = get_pair default_registry unmarshaller
 436 let get_triple unmarshaller = get_triple default_registry unmarshaller
 437 let get_quad unmarshaller = get_quad default_registry unmarshaller
 438 let set_typed marshaller = set_typed default_registry marshaller
 439 let set_opt unmarshaller = set_opt default_registry unmarshaller
 440 let set_list marshaller = set_list default_registry marshaller
 441 let unset = unset default_registry
 442 let save_to = save_to default_registry
 443 let load_from = load_from default_registry
 444 let clear () = Hashtbl.clear default_registry
 445
 446 let get_string = get_typed string
 447 let get_int = get_typed int
 448 let get_float = get_typed float
 449 let get_bool = get_typed bool
 450 let set_string = set_typed of_string
 451 let set_int = set_typed of_int
 452 let set_float = set_typed of_float
 453 let set_bool = set_typed of_bool
 454