matita/matita/contribs/lambda_delta/basic_2/substitution/lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/term_weight.ma".
  16 include "basic_2/grammar/term_simple.ma".
  17
  18 (* BASIC TERM RELOCATION ****************************************************)
  19
  20 (* Basic_1: includes:
  21             lift_sort lift_lref_lt lift_lref_ge lift_bind lift_flat
  22 *)
  23 inductive lift: nat → nat → relation term ≝
  24 | lift_sort   : ∀k,d,e. lift d e (⋆k) (⋆k)
  25 | lift_lref_lt: ∀i,d,e. i < d → lift d e (#i) (#i)
  26 | lift_lref_ge: ∀i,d,e. d ≤ i → lift d e (#i) (#(i + e))
  27 | lift_gref   : ∀p,d,e. lift d e (§p) (§p)
  28 | lift_bind   : ∀a,I,V1,V2,T1,T2,d,e.
  29                 lift d e V1 V2 → lift (d + 1) e T1 T2 →
  30                 lift d e (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  31 | lift_flat   : ∀I,V1,V2,T1,T2,d,e.
  32                 lift d e V1 V2 → lift d e T1 T2 →
  33                 lift d e (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  34 .
  35
  36 interpretation "relocation" 'RLift d e T1 T2 = (lift d e T1 T2).
  37
  38 definition t_liftable: relation term → Prop ≝
  39                        λR. ∀T1,T2. R T1 T2 → ∀U1,d,e. ⇧[d, e] T1 ≡ U1 →
  40                        ∀U2. ⇧[d, e] T2 ≡ U2 → R U1 U2.
  41
  42 definition t_deliftable_sn: relation term → Prop ≝
  43                             λR. ∀U1,U2. R U1 U2 → ∀T1,d,e. ⇧[d, e] T1 ≡ U1 →
  44                             ∃∃T2. ⇧[d, e] T2 ≡ U2 & R T1 T2.
  45
  46 (* Basic inversion lemmas ***************************************************)
  47
  48 fact lift_inv_refl_O2_aux: ∀d,e,T1,T2. ⇧[d, e] T1 ≡ T2 → e = 0 → T1 = T2.
  49 #d #e #T1 #T2 #H elim H -d -e -T1 -T2 // /3 width=1/
  50 qed.
  51
  52 lemma lift_inv_refl_O2: ∀d,T1,T2. ⇧[d, 0] T1 ≡ T2 → T1 = T2.
  53 /2 width=4/ qed-.
  54
  55 fact lift_inv_sort1_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀k. T1 = ⋆k → T2 = ⋆k.
  56 #d #e #T1 #T2 * -d -e -T1 -T2 //
  57 [ #i #d #e #_ #k #H destruct
  58 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  59 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  60 ]
  61 qed.
  62
  63 lemma lift_inv_sort1: ∀d,e,T2,k. ⇧[d,e] ⋆k ≡ T2 → T2 = ⋆k.
  64 /2 width=5/ qed-.
  65
  66 fact lift_inv_lref1_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀i. T1 = #i →
  67                          (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
  68 #d #e #T1 #T2 * -d -e -T1 -T2
  69 [ #k #d #e #i #H destruct
  70 | #j #d #e #Hj #i #Hi destruct /3 width=1/
  71 | #j #d #e #Hj #i #Hi destruct /3 width=1/
  72 | #p #d #e #i #H destruct
  73 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
  74 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
  75 ]
  76 qed.
  77
  78 lemma lift_inv_lref1: ∀d,e,T2,i. ⇧[d,e] #i ≡ T2 →
  79                       (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
  80 /2 width=3/ qed-.
  81
  82 lemma lift_inv_lref1_lt: ∀d,e,T2,i. ⇧[d,e] #i ≡ T2 → i < d → T2 = #i.
  83 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  84 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
  85 elim (lt_refl_false … Hdd)
  86 qed-.
  87
  88 lemma lift_inv_lref1_ge: ∀d,e,T2,i. ⇧[d,e] #i ≡ T2 → d ≤ i → T2 = #(i + e).
  89 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  90 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
  91 elim (lt_refl_false … Hdd)
  92 qed-.
  93
  94 fact lift_inv_gref1_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀p. T1 = §p → T2 = §p.
  95 #d #e #T1 #T2 * -d -e -T1 -T2 //
  96 [ #i #d #e #_ #k #H destruct
  97 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  98 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  99 ]
 100 qed.
 101
 102 lemma lift_inv_gref1: ∀d,e,T2,p. ⇧[d,e] §p ≡ T2 → T2 = §p.
 103 /2 width=5/ qed-.
 104
 105 fact lift_inv_bind1_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 →
 106                          ∀a,I,V1,U1. T1 = ⓑ{a,I} V1.U1 →
 107                          ∃∃V2,U2. ⇧[d,e] V1 ≡ V2 & ⇧[d+1,e] U1 ≡ U2 &
 108                                   T2 = ⓑ{a,I} V2. U2.
 109 #d #e #T1 #T2 * -d -e -T1 -T2
 110 [ #k #d #e #a #I #V1 #U1 #H destruct
 111 | #i #d #e #_ #a #I #V1 #U1 #H destruct
 112 | #i #d #e #_ #a #I #V1 #U1 #H destruct
 113 | #p #d #e #a #I #V1 #U1 #H destruct
 114 | #b #J #W1 #W2 #T1 #T2 #d #e #HW #HT #a #I #V1 #U1 #H destruct /2 width=5/
 115 | #J #W1 #W2 #T1 #T2 #d #e #_ #HT #a #I #V1 #U1 #H destruct
 116 ]
 117 qed.
 118
 119 lemma lift_inv_bind1: ∀d,e,T2,a,I,V1,U1. ⇧[d,e] ⓑ{a,I} V1. U1 ≡ T2 →
 120                       ∃∃V2,U2. ⇧[d,e] V1 ≡ V2 & ⇧[d+1,e] U1 ≡ U2 &
 121                                T2 = ⓑ{a,I} V2. U2.
 122 /2 width=3/ qed-.
 123
 124 fact lift_inv_flat1_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 →
 125                          ∀I,V1,U1. T1 = ⓕ{I} V1.U1 →
 126                          ∃∃V2,U2. ⇧[d,e] V1 ≡ V2 & ⇧[d,e] U1 ≡ U2 &
 127                                   T2 = ⓕ{I} V2. U2.
 128 #d #e #T1 #T2 * -d -e -T1 -T2
 129 [ #k #d #e #I #V1 #U1 #H destruct
 130 | #i #d #e #_ #I #V1 #U1 #H destruct
 131 | #i #d #e #_ #I #V1 #U1 #H destruct
 132 | #p #d #e #I #V1 #U1 #H destruct
 133 | #a #J #W1 #W2 #T1 #T2 #d #e #_ #_ #I #V1 #U1 #H destruct
 134 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 135 ]
 136 qed.
 137
 138 lemma lift_inv_flat1: ∀d,e,T2,I,V1,U1. ⇧[d,e] ⓕ{I} V1. U1 ≡ T2 →
 139                       ∃∃V2,U2. ⇧[d,e] V1 ≡ V2 & ⇧[d,e] U1 ≡ U2 &
 140                                T2 = ⓕ{I} V2. U2.
 141 /2 width=3/ qed-.
 142
 143 fact lift_inv_sort2_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
 144 #d #e #T1 #T2 * -d -e -T1 -T2 //
 145 [ #i #d #e #_ #k #H destruct
 146 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 147 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 148 ]
 149 qed.
 150
 151 (* Basic_1: was: lift_gen_sort *)
 152 lemma lift_inv_sort2: ∀d,e,T1,k. ⇧[d,e] T1 ≡ ⋆k → T1 = ⋆k.
 153 /2 width=5/ qed-.
 154
 155 fact lift_inv_lref2_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀i. T2 = #i →
 156                          (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 157 #d #e #T1 #T2 * -d -e -T1 -T2
 158 [ #k #d #e #i #H destruct
 159 | #j #d #e #Hj #i #Hi destruct /3 width=1/
 160 | #j #d #e #Hj #i #Hi destruct <minus_plus_m_m /4 width=1/
 161 | #p #d #e #i #H destruct
 162 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 163 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 164 ]
 165 qed.
 166
 167 (* Basic_1: was: lift_gen_lref *)
 168 lemma lift_inv_lref2: ∀d,e,T1,i. ⇧[d,e] T1 ≡ #i →
 169                       (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 170 /2 width=3/ qed-.
 171
 172 (* Basic_1: was: lift_gen_lref_lt *)
 173 lemma lift_inv_lref2_lt: ∀d,e,T1,i. ⇧[d,e] T1 ≡ #i → i < d → T1 = #i.
 174 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 175 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
 176 elim (lt_inv_plus_l … Hdd) -Hdd #Hdd
 177 elim (lt_refl_false … Hdd)
 178 qed-.
 179
 180 (* Basic_1: was: lift_gen_lref_false *)
 181 lemma lift_inv_lref2_be: ∀d,e,T1,i. ⇧[d,e] T1 ≡ #i →
 182                          d ≤ i → i < d + e → ⊥.
 183 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H *
 184 [ #H1 #_ #H2 #_ | #H2 #_ #_ #H1 ]
 185 lapply (le_to_lt_to_lt … H2 H1) -H2 -H1 #H
 186 elim (lt_refl_false … H)
 187 qed-.
 188
 189 (* Basic_1: was: lift_gen_lref_ge *)
 190 lemma lift_inv_lref2_ge: ∀d,e,T1,i. ⇧[d,e] T1 ≡ #i → d + e ≤ i → T1 = #(i - e).
 191 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 192 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
 193 elim (lt_inv_plus_l … Hdd) -Hdd #Hdd
 194 elim (lt_refl_false … Hdd)
 195 qed-.
 196
 197 fact lift_inv_gref2_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀p. T2 = §p → T1 = §p.
 198 #d #e #T1 #T2 * -d -e -T1 -T2 //
 199 [ #i #d #e #_ #k #H destruct
 200 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 201 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 202 ]
 203 qed.
 204
 205 lemma lift_inv_gref2: ∀d,e,T1,p. ⇧[d,e] T1 ≡ §p → T1 = §p.
 206 /2 width=5/ qed-.
 207
 208 fact lift_inv_bind2_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 →
 209                          ∀a,I,V2,U2. T2 = ⓑ{a,I} V2.U2 →
 210                          ∃∃V1,U1. ⇧[d,e] V1 ≡ V2 & ⇧[d+1,e] U1 ≡ U2 &
 211                                   T1 = ⓑ{a,I} V1. U1.
 212 #d #e #T1 #T2 * -d -e -T1 -T2
 213 [ #k #d #e #a #I #V2 #U2 #H destruct
 214 | #i #d #e #_ #a #I #V2 #U2 #H destruct
 215 | #i #d #e #_ #a #I #V2 #U2 #H destruct
 216 | #p #d #e #a #I #V2 #U2 #H destruct
 217 | #b #J #W1 #W2 #T1 #T2 #d #e #HW #HT #a #I #V2 #U2 #H destruct /2 width=5/
 218 | #J #W1 #W2 #T1 #T2 #d #e #_ #_ #a #I #V2 #U2 #H destruct
 219 ]
 220 qed.
 221
 222 (* Basic_1: was: lift_gen_bind *)
 223 lemma lift_inv_bind2: ∀d,e,T1,a,I,V2,U2. ⇧[d,e] T1 ≡ ⓑ{a,I} V2. U2 →
 224                       ∃∃V1,U1. ⇧[d,e] V1 ≡ V2 & ⇧[d+1,e] U1 ≡ U2 &
 225                                T1 = ⓑ{a,I} V1. U1.
 226 /2 width=3/ qed-.
 227
 228 fact lift_inv_flat2_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 →
 229                          ∀I,V2,U2. T2 = ⓕ{I} V2.U2 →
 230                          ∃∃V1,U1. ⇧[d,e] V1 ≡ V2 & ⇧[d,e] U1 ≡ U2 &
 231                                   T1 = ⓕ{I} V1. U1.
 232 #d #e #T1 #T2 * -d -e -T1 -T2
 233 [ #k #d #e #I #V2 #U2 #H destruct
 234 | #i #d #e #_ #I #V2 #U2 #H destruct
 235 | #i #d #e #_ #I #V2 #U2 #H destruct
 236 | #p #d #e #I #V2 #U2 #H destruct
 237 | #a #J #W1 #W2 #T1 #T2 #d #e #_ #_ #I #V2 #U2 #H destruct
 238 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width=5/
 239 ]
 240 qed.
 241
 242 (* Basic_1: was: lift_gen_flat *)
 243 lemma lift_inv_flat2: ∀d,e,T1,I,V2,U2. ⇧[d,e] T1 ≡  ⓕ{I} V2. U2 →
 244                       ∃∃V1,U1. ⇧[d,e] V1 ≡ V2 & ⇧[d,e] U1 ≡ U2 &
 245                                T1 = ⓕ{I} V1. U1.
 246 /2 width=3/ qed-.
 247
 248 lemma lift_inv_pair_xy_x: ∀d,e,I,V,T. ⇧[d, e] ②{I} V. T ≡ V → ⊥.
 249 #d #e #J #V elim V -V
 250 [ * #i #T #H
 251   [ lapply (lift_inv_sort2 … H) -H #H destruct
 252   | elim (lift_inv_lref2 … H) -H * #_ #H destruct
 253   | lapply (lift_inv_gref2 … H) -H #H destruct
 254   ]
 255 | * [ #a ] #I #W2 #U2 #IHW2 #_ #T #H
 256   [ elim (lift_inv_bind2 … H) -H #W1 #U1 #HW12 #_ #H destruct /2 width=2/
 257   | elim (lift_inv_flat2 … H) -H #W1 #U1 #HW12 #_ #H destruct /2 width=2/
 258   ]
 259 ]
 260 qed-.
 261
 262 lemma lift_inv_pair_xy_y: ∀I,T,V,d,e. ⇧[d, e] ②{I} V. T ≡ T → ⊥.
 263 #J #T elim T -T
 264 [ * #i #V #d #e #H
 265   [ lapply (lift_inv_sort2 … H) -H #H destruct
 266   | elim (lift_inv_lref2 … H) -H * #_ #H destruct
 267   | lapply (lift_inv_gref2 … H) -H #H destruct
 268   ]
 269 | * [ #a ] #I #W2 #U2 #_ #IHU2 #V #d #e #H
 270   [ elim (lift_inv_bind2 … H) -H #W1 #U1 #_ #HU12 #H destruct /2 width=4/
 271   | elim (lift_inv_flat2 … H) -H #W1 #U1 #_ #HU12 #H destruct /2 width=4/
 272   ]
 273 ]
 274 qed-.
 275
 276 (* Basic forward lemmas *****************************************************)
 277
 278 lemma tw_lift: ∀d,e,T1,T2. ⇧[d, e] T1 ≡ T2 → #{T1} = #{T2}.
 279 #d #e #T1 #T2 #H elim H -d -e -T1 -T2 normalize //
 280 qed-.
 281
 282 lemma lift_simple_dx: ∀d,e,T1,T2. ⇧[d, e] T1 ≡ T2 → 𝐒⦃T1⦄ → 𝐒⦃T2⦄.
 283 #d #e #T1 #T2 #H elim H -d -e -T1 -T2 //
 284 #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #H
 285 elim (simple_inv_bind … H)
 286 qed-.
 287
 288 lemma lift_simple_sn: ∀d,e,T1,T2. ⇧[d, e] T1 ≡ T2 → 𝐒⦃T2⦄ → 𝐒⦃T1⦄.
 289 #d #e #T1 #T2 #H elim H -d -e -T1 -T2 //
 290 #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #H
 291 elim (simple_inv_bind … H)
 292 qed-.
 293
 294 (* Basic properties *********************************************************)
 295
 296 (* Basic_1: was: lift_lref_gt *)
 297 lemma lift_lref_ge_minus: ∀d,e,i. d + e ≤ i → ⇧[d, e] #(i - e) ≡ #i.
 298 #d #e #i #H >(plus_minus_m_m i e) in ⊢ (? ? ? ? %); /2 width=2/ /3 width=2/
 299 qed.
 300
 301 lemma lift_lref_ge_minus_eq: ∀d,e,i,j. d + e ≤ i → j = i - e → ⇧[d, e] #j ≡ #i.
 302 /2 width=1/ qed-.
 303
 304 (* Basic_1: was: lift_r *)
 305 lemma lift_refl: ∀T,d. ⇧[d, 0] T ≡ T.
 306 #T elim T -T
 307 [ * #i // #d elim (lt_or_ge i d) /2 width=1/
 308 | * /2 width=1/
 309 ]
 310 qed.
 311
 312 lemma lift_total: ∀T1,d,e. ∃T2. ⇧[d,e] T1 ≡ T2.
 313 #T1 elim T1 -T1
 314 [ * #i /2 width=2/ #d #e elim (lt_or_ge i d) /3 width=2/
 315 | * [ #a ] #I #V1 #T1 #IHV1 #IHT1 #d #e
 316   elim (IHV1 d e) -IHV1 #V2 #HV12
 317   [ elim (IHT1 (d+1) e) -IHT1 /3 width=2/
 318   | elim (IHT1 d e) -IHT1 /3 width=2/
 319   ]
 320 ]
 321 qed.
 322
 323 (* Basic_1: was: lift_free (right to left) *)
 324 lemma lift_split: ∀d1,e2,T1,T2. ⇧[d1, e2] T1 ≡ T2 →
 325                   ∀d2,e1. d1 ≤ d2 → d2 ≤ d1 + e1 → e1 ≤ e2 →
 326                   ∃∃T. ⇧[d1, e1] T1 ≡ T & ⇧[d2, e2 - e1] T ≡ T2.
 327 #d1 #e2 #T1 #T2 #H elim H -d1 -e2 -T1 -T2
 328 [ /3 width=3/
 329 | #i #d1 #e2 #Hid1 #d2 #e1 #Hd12 #_ #_
 330   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2 /4 width=3/
 331 | #i #d1 #e2 #Hid1 #d2 #e1 #_ #Hd21 #He12
 332   lapply (transitive_le … (i+e1) Hd21 ?) /2 width=1/ -Hd21 #Hd21
 333   >(plus_minus_m_m e2 e1 ?) // /3 width=3/
 334 | /3 width=3/
 335 | #a #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
 336   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
 337   elim (IHT (d2+1) … ? ? He12) /2 width=1/ /3 width=5/
 338 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
 339   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
 340   elim (IHT d2 … ? ? He12) // /3 width=5/
 341 ]
 342 qed.
 343
 344 (* Basic_1: was only: dnf_dec2 dnf_dec *)
 345 lemma is_lift_dec: ∀T2,d,e. Decidable (∃T1. ⇧[d,e] T1 ≡ T2).
 346 #T1 elim T1 -T1
 347 [ * [1,3: /3 width=2/ ] #i #d #e
 348   elim (lt_dec i d) #Hid
 349   [ /4 width=2/
 350   | lapply (false_lt_to_le … Hid) -Hid #Hid
 351     elim (lt_dec i (d + e)) #Hide
 352     [ @or_intror * #T1 #H
 353       elim (lift_inv_lref2_be … H Hid Hide)
 354     | lapply (false_lt_to_le … Hide) -Hide /4 width=2/
 355     ]
 356   ]
 357 | * [ #a ] #I #V2 #T2 #IHV2 #IHT2 #d #e
 358   [ elim (IHV2 d e) -IHV2
 359     [ * #V1 #HV12 elim (IHT2 (d+1) e) -IHT2
 360       [ * #T1 #HT12 @or_introl /3 width=2/
 361       | -V1 #HT2 @or_intror * #X #H
 362         elim (lift_inv_bind2 … H) -H /3 width=2/
 363       ]
 364     | -IHT2 #HV2 @or_intror * #X #H
 365       elim (lift_inv_bind2 … H) -H /3 width=2/
 366     ]
 367   | elim (IHV2 d e) -IHV2
 368     [ * #V1 #HV12 elim (IHT2 d e) -IHT2
 369       [ * #T1 #HT12 /4 width=2/
 370       | -V1 #HT2 @or_intror * #X #H
 371         elim (lift_inv_flat2 … H) -H /3 width=2/
 372       ]
 373     | -IHT2 #HV2 @or_intror * #X #H
 374       elim (lift_inv_flat2 … H) -H /3 width=2/
 375     ]
 376   ]
 377 ]
 378 qed.
 379
 380 lemma t_liftable_TC: ∀R. t_liftable R → t_liftable (TC … R).
 381 #R #HR #T1 #T2 #H elim H -T2
 382 [ /3 width=7/
 383 | #T #T2 #_ #HT2 #IHT1 #U1 #d #e #HTU1 #U2 #HTU2
 384   elim (lift_total T d e) /3 width=9/
 385 ]
 386 qed.
 387
 388 lemma t_deliftable_sn_TC: ∀R. t_deliftable_sn R → t_deliftable_sn (TC … R).
 389 #R #HR #U1 #U2 #H elim H -U2
 390 [ #U2 #HU12 #T1 #d #e #HTU1
 391   elim (HR … HU12 … HTU1) -U1 /3 width=3/
 392 | #U #U2 #_ #HU2 #IHU1 #T1 #d #e #HTU1
 393   elim (IHU1 … HTU1) -U1 #T #HTU #HT1
 394   elim (HR … HU2 … HTU) -U /3 width=5/
 395 ]
 396 qed-.
 397
 398 (* Basic_1: removed theorems 7:
 399             lift_head lift_gen_head
 400             lift_weight_map lift_weight lift_weight_add lift_weight_add_O
 401             lift_tlt_dx
 402 *)