matita/matita/contribs/lambda_delta/basic_2/substitution/lift_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/lift.ma".
  16
  17 (* BASIC TERM RELOCATION ****************************************************)
  18
  19 (* Main properies ***********************************************************)
  20
  21 (* Basic_1: was: lift_inj *)
  22 theorem lift_inj: ∀d,e,T1,U. ⇧[d,e] T1 ≡ U → ∀T2. ⇧[d,e] T2 ≡ U → T1 = T2.
  23 #d #e #T1 #U #H elim H -d -e -T1 -U
  24 [ #k #d #e #X #HX
  25   lapply (lift_inv_sort2 … HX) -HX //
  26 | #i #d #e #Hid #X #HX
  27   lapply (lift_inv_lref2_lt … HX ?) -HX //
  28 | #i #d #e #Hdi #X #HX
  29   lapply (lift_inv_lref2_ge … HX ?) -HX // /2 width=1/
  30 | #p #d #e #X #HX
  31   lapply (lift_inv_gref2 … HX) -HX //
  32 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  33   elim (lift_inv_bind2 … HX) -HX #V #T #HV1 #HT1 #HX destruct /3 width=1/
  34 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  35   elim (lift_inv_flat2 … HX) -HX #V #T #HV1 #HT1 #HX destruct /3 width=1/
  36 ]
  37 qed-.
  38
  39 (* Basic_1: was: lift_gen_lift *)
  40 theorem lift_div_le: ∀d1,e1,T1,T. ⇧[d1, e1] T1 ≡ T →
  41                      ∀d2,e2,T2. ⇧[d2 + e1, e2] T2 ≡ T →
  42                      d1 ≤ d2 →
  43                      ∃∃T0. ⇧[d1, e1] T0 ≡ T2 & ⇧[d2, e2] T0 ≡ T1.
  44 #d1 #e1 #T1 #T #H elim H -d1 -e1 -T1 -T
  45 [ #k #d1 #e1 #d2 #e2 #T2 #Hk #Hd12
  46   lapply (lift_inv_sort2 … Hk) -Hk #Hk destruct /3 width=3/
  47 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
  48   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2
  49   lapply (lift_inv_lref2_lt … Hi ?) -Hi /2 width=3/ /3 width=3/
  50 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
  51   elim (lift_inv_lref2 … Hi) -Hi * #Hid2 #H destruct
  52   [ -Hd12 lapply (lt_plus_to_lt_l … Hid2) -Hid2 #Hid2 /3 width=3/
  53   | -Hid1 >plus_plus_comm_23 in Hid2; #H lapply (le_plus_to_le_r … H) -H #H
  54     elim (le_inv_plus_l … H) -H #Hide2 #He2i
  55     lapply (transitive_le … Hd12 Hide2) -Hd12 #Hd12
  56     >le_plus_minus_comm // >(plus_minus_m_m i e2) in ⊢ (? ? ? %); // -He2i
  57     /4 width=3/
  58   ]
  59 | #p #d1 #e1 #d2 #e2 #T2 #Hk #Hd12
  60   lapply (lift_inv_gref2 … Hk) -Hk #Hk destruct /3 width=3/
  61 | #a #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
  62   lapply (lift_inv_bind2 … H) -H * #W2 #U2 #HW2 #HU2 #H destruct
  63   elim (IHW … HW2 ?) // -IHW -HW2 #W0 #HW2 #HW1
  64   >plus_plus_comm_23 in HU2; #HU2 elim (IHU … HU2 ?) /2 width=1/ /3 width=5/
  65 | #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
  66   lapply (lift_inv_flat2 … H) -H * #W2 #U2 #HW2 #HU2 #H destruct
  67   elim (IHW … HW2 ?) // -IHW -HW2 #W0 #HW2 #HW1
  68   elim (IHU … HU2 ?) // /3 width=5/
  69 ]
  70 qed.
  71
  72 (* Note: apparently this was missing in basic_1 *)
  73 theorem lift_div_be: ∀d1,e1,T1,T. ⇧[d1, e1] T1 ≡ T →
  74                      ∀e,e2,T2. ⇧[d1 + e, e2] T2 ≡ T →
  75                      e ≤ e1 → e1 ≤ e + e2 →
  76                      ∃∃T0. ⇧[d1, e] T0 ≡ T2 & ⇧[d1, e + e2 - e1] T0 ≡ T1.
  77 #d1 #e1 #T1 #T #H elim H -d1 -e1 -T1 -T
  78 [ #k #d1 #e1 #e #e2 #T2 #H >(lift_inv_sort2 … H) -H /2 width=3/
  79 | #i #d1 #e1 #Hid1 #e #e2 #T2 #H #He1 #He1e2
  80   >(lift_inv_lref2_lt … H) -H [ /3 width=3/ | /2 width=3/ ]
  81 | #i #d1 #e1 #Hid1 #e #e2 #T2 #H #He1 #He1e2
  82   elim (lt_or_ge (i+e1) (d1+e+e2)) #Hie1d1e2
  83   [ elim (lift_inv_lref2_be … H ? ?) -H // /2 width=1/
  84   | >(lift_inv_lref2_ge … H ?) -H //
  85     lapply (le_plus_to_minus … Hie1d1e2) #Hd1e21i
  86     elim (le_inv_plus_l … Hie1d1e2) -Hie1d1e2 #Hd1e12 #He2ie1
  87     @ex2_1_intro [2: /2 width=1/ | skip ] -Hd1e12
  88     @lift_lref_ge_minus_eq [ >plus_minus_commutative // | /2 width=1/ ]
  89   ]
  90 | #p #d1 #e1 #e #e2 #T2 #H >(lift_inv_gref2 … H) -H /2 width=3/
  91 | #a #I #V1 #V #T1 #T #d1 #e1 #_ #_ #IHV1 #IHT1 #e #e2 #X #H #He1 #He1e2
  92   elim (lift_inv_bind2 … H) -H #V2 #T2 #HV2 #HT2 #H destruct
  93   elim (IHV1 … HV2 ? ?) -V // >plus_plus_comm_23 in HT2; #HT2
  94   elim (IHT1 … HT2 ? ?) -T // -He1 -He1e2 /3 width=5/
  95 | #I #V1 #V #T1 #T #d1 #e1 #_ #_ #IHV1 #IHT1 #e #e2 #X #H #He1 #He1e2
  96   elim (lift_inv_flat2 … H) -H #V2 #T2 #HV2 #HT2 #H destruct
  97   elim (IHV1 … HV2 ? ?) -V //
  98   elim (IHT1 … HT2 ? ?) -T // -He1 -He1e2 /3 width=5/
  99 ]
 100 qed.
 101
 102 theorem lift_mono: ∀d,e,T,U1. ⇧[d,e] T ≡ U1 → ∀U2. ⇧[d,e] T ≡ U2 → U1 = U2.
 103 #d #e #T #U1 #H elim H -d -e -T -U1
 104 [ #k #d #e #X #HX
 105   lapply (lift_inv_sort1 … HX) -HX //
 106 | #i #d #e #Hid #X #HX
 107   lapply (lift_inv_lref1_lt … HX ?) -HX //
 108 | #i #d #e #Hdi #X #HX
 109   lapply (lift_inv_lref1_ge … HX ?) -HX //
 110 | #p #d #e #X #HX
 111   lapply (lift_inv_gref1 … HX) -HX //
 112 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
 113   elim (lift_inv_bind1 … HX) -HX #V #T #HV1 #HT1 #HX destruct /3 width=1/
 114 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
 115   elim (lift_inv_flat1 … HX) -HX #V #T #HV1 #HT1 #HX destruct /3 width=1/
 116 ]
 117 qed-.
 118
 119 (* Basic_1: was: lift_free (left to right) *)
 120 theorem lift_trans_be: ∀d1,e1,T1,T. ⇧[d1, e1] T1 ≡ T →
 121                        ∀d2,e2,T2. ⇧[d2, e2] T ≡ T2 →
 122                        d1 ≤ d2 → d2 ≤ d1 + e1 → ⇧[d1, e1 + e2] T1 ≡ T2.
 123 #d1 #e1 #T1 #T #H elim H -d1 -e1 -T1 -T
 124 [ #k #d1 #e1 #d2 #e2 #T2 #HT2 #_ #_
 125   >(lift_inv_sort1 … HT2) -HT2 //
 126 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #HT2 #Hd12 #_
 127   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2
 128   lapply (lift_inv_lref1_lt … HT2 Hid2) /2 width=1/
 129 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #HT2 #_ #Hd21
 130   lapply (lift_inv_lref1_ge … HT2 ?) -HT2
 131   [ @(transitive_le … Hd21 ?) -Hd21 /2 width=1/
 132   | -Hd21 /2 width=1/
 133   ]
 134 | #p #d1 #e1 #d2 #e2 #T2 #HT2 #_ #_
 135   >(lift_inv_gref1 … HT2) -HT2 //
 136 | #a #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd12 #Hd21
 137   elim (lift_inv_bind1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct
 138   lapply (IHV12 … HV20 ? ?) // -IHV12 -HV20 #HV10
 139   lapply (IHT12 … HT20 ? ?) /2 width=1/
 140 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd12 #Hd21
 141   elim (lift_inv_flat1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct
 142   lapply (IHV12 … HV20 ? ?) // -IHV12 -HV20 #HV10
 143   lapply (IHT12 … HT20 ? ?) // /2 width=1/
 144 ]
 145 qed.
 146
 147 (* Basic_1: was: lift_d (right to left) *)
 148 theorem lift_trans_le: ∀d1,e1,T1,T. ⇧[d1, e1] T1 ≡ T →
 149                        ∀d2,e2,T2. ⇧[d2, e2] T ≡ T2 → d2 ≤ d1 →
 150                        ∃∃T0. ⇧[d2, e2] T1 ≡ T0 & ⇧[d1 + e2, e1] T0 ≡ T2.
 151 #d1 #e1 #T1 #T #H elim H -d1 -e1 -T1 -T
 152 [ #k #d1 #e1 #d2 #e2 #X #HX #_
 153   >(lift_inv_sort1 … HX) -HX /2 width=3/
 154 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #_
 155   lapply (lt_to_le_to_lt … (d1+e2) Hid1 ?) // #Hie2
 156   elim (lift_inv_lref1 … HX) -HX * #Hid2 #HX destruct /3 width=3/ /4 width=3/
 157 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #Hd21
 158   lapply (transitive_le … Hd21 Hid1) -Hd21 #Hid2
 159   lapply (lift_inv_lref1_ge … HX ?) -HX /2 width=3/ #HX destruct
 160   >plus_plus_comm_23 /4 width=3/
 161 | #p #d1 #e1 #d2 #e2 #X #HX #_
 162   >(lift_inv_gref1 … HX) -HX /2 width=3/
 163 | #a #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd21
 164   elim (lift_inv_bind1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct
 165   elim (IHV12 … HV20 ?) -IHV12 -HV20 //
 166   elim (IHT12 … HT20 ?) -IHT12 -HT20 /2 width=1/ /3 width=5/
 167 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd21
 168   elim (lift_inv_flat1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct
 169   elim (IHV12 … HV20 ?) -IHV12 -HV20 //
 170   elim (IHT12 … HT20 ?) -IHT12 -HT20 // /3 width=5/
 171 ]
 172 qed.
 173
 174 (* Basic_1: was: lift_d (left to right) *)
 175 theorem lift_trans_ge: ∀d1,e1,T1,T. ⇧[d1, e1] T1 ≡ T →
 176                        ∀d2,e2,T2. ⇧[d2, e2] T ≡ T2 → d1 + e1 ≤ d2 →
 177                        ∃∃T0. ⇧[d2 - e1, e2] T1 ≡ T0 & ⇧[d1, e1] T0 ≡ T2.
 178 #d1 #e1 #T1 #T #H elim H -d1 -e1 -T1 -T
 179 [ #k #d1 #e1 #d2 #e2 #X #HX #_
 180   >(lift_inv_sort1 … HX) -HX /2 width=3/
 181 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #Hded
 182   lapply (lt_to_le_to_lt … (d1+e1) Hid1 ?) // #Hid1e
 183   lapply (lt_to_le_to_lt … (d2-e1) Hid1 ?) /2 width=1/ #Hid2e
 184   lapply (lt_to_le_to_lt … Hid1e Hded) -Hid1e -Hded #Hid2
 185   lapply (lift_inv_lref1_lt … HX ?) -HX // #HX destruct /3 width=3/
 186 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #_
 187   elim (lift_inv_lref1 … HX) -HX * #Hied #HX destruct /4 width=3/
 188 | #p #d1 #e1 #d2 #e2 #X #HX #_
 189   >(lift_inv_gref1 … HX) -HX /2 width=3/
 190 | #a #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hded
 191   elim (lift_inv_bind1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct
 192   elim (IHV12 … HV20 ?) -IHV12 -HV20 //
 193   elim (IHT12 … HT20 ?) -IHT12 -HT20 /2 width=1/ #T
 194   <plus_minus /2 width=2/ /3 width=5/
 195 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hded
 196   elim (lift_inv_flat1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct
 197   elim (IHV12 … HV20 ?) -IHV12 -HV20 //
 198   elim (IHT12 … HT20 ?) -IHT12 -HT20 // /3 width=5/
 199 ]
 200 qed.
 201
 202 (* Advanced properties ******************************************************)
 203
 204 lemma lift_conf_O1: ∀T,T1,d1,e1. ⇧[d1, e1] T ≡ T1 → ∀T2,e2. ⇧[0, e2] T ≡ T2 →
 205                     ∃∃T0. ⇧[0, e2] T1 ≡ T0 & ⇧[d1 + e2, e1] T2 ≡ T0.
 206 #T #T1 #d1 #e1 #HT1 #T2 #e2 #HT2
 207 elim (lift_total T1 0 e2) #T0 #HT10
 208 elim (lift_trans_le … HT1 … HT10 ?) -HT1 // #X #HTX #HT20
 209 lapply (lift_mono … HTX … HT2) -T #H destruct /2 width=3/
 210 qed.
 211
 212 lemma lift_conf_be: ∀T,T1,d,e1. ⇧[d, e1] T ≡ T1 → ∀T2,e2. ⇧[d, e2] T ≡ T2 →
 213                     e1 ≤ e2 → ⇧[d + e1, e2 - e1] T1 ≡ T2.
 214 #T #T1 #d #e1 #HT1 #T2 #e2 #HT2 #He12
 215 elim (lift_split … HT2 (d+e1) e1 ? ? ?) -HT2 // #X #H
 216 >(lift_mono … H … HT1) -T //
 217 qed.