matita/matita/contribs/lambda_delta/basic_2/substitution/tps.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/ldrop_append.ma".
  16
  17 (* PARALLEL SUBSTITUTION ON TERMS *******************************************)
  18
  19 inductive tps: nat → nat → lenv → relation term ≝
  20 | tps_atom : ∀L,I,d,e. tps d e L (⓪{I}) (⓪{I})
  21 | tps_subst: ∀L,K,V,W,i,d,e. d ≤ i → i < d + e →
  22              ⇩[0, i] L ≡ K. ⓓV → ⇧[0, i + 1] V ≡ W → tps d e L (#i) W
  23 | tps_bind : ∀L,a,I,V1,V2,T1,T2,d,e.
  24              tps d e L V1 V2 → tps (d + 1) e (L. ⓑ{I} V2) T1 T2 →
  25              tps d e L (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  26 | tps_flat : ∀L,I,V1,V2,T1,T2,d,e.
  27              tps d e L V1 V2 → tps d e L T1 T2 →
  28              tps d e L (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  29 .
  30
  31 interpretation "parallel substritution (term)"
  32    'PSubst L T1 d e T2 = (tps d e L T1 T2).
  33
  34 (* Basic properties *********************************************************)
  35
  36 lemma tps_lsubs_trans: ∀L1,T1,T2,d,e. L1 ⊢ T1 ▶ [d, e] T2 →
  37                        ∀L2. L2 ≼ [d, e] L1 → L2 ⊢ T1 ▶ [d, e] T2.
  38 #L1 #T1 #T2 #d #e #H elim H -L1 -T1 -T2 -d -e
  39 [ //
  40 | #L1 #K1 #V #W #i #d #e #Hdi #Hide #HLK1 #HVW #L2 #HL12
  41   elim (ldrop_lsubs_ldrop2_abbr … HL12 … HLK1 ? ?) -HL12 -HLK1 // /2 width=4/
  42 | /4 width=1/
  43 | /3 width=1/
  44 ]
  45 qed.
  46
  47 lemma tps_refl: ∀T,L,d,e. L ⊢ T ▶ [d, e] T.
  48 #T elim T -T //
  49 #I elim I -I /2 width=1/
  50 qed.
  51
  52 (* Basic_1: was: subst1_ex *)
  53 lemma tps_full: ∀K,V,T1,L,d. ⇩[0, d] L ≡ (K. ⓓV) →
  54                 ∃∃T2,T. L ⊢ T1 ▶ [d, 1] T2 & ⇧[d, 1] T ≡ T2.
  55 #K #V #T1 elim T1 -T1
  56 [ * #i #L #d #HLK /2 width=4/
  57   elim (lt_or_eq_or_gt i d) #Hid /3 width=4/
  58   destruct
  59   elim (lift_total V 0 (i+1)) #W #HVW
  60   elim (lift_split … HVW i i ? ? ?) // /3 width=4/
  61 | * [ #a ] #I #W1 #U1 #IHW1 #IHU1 #L #d #HLK
  62   elim (IHW1 … HLK) -IHW1 #W2 #W #HW12 #HW2
  63   [ elim (IHU1 (L. ⓑ{I} W2) (d+1) ?) -IHU1 /2 width=1/ -HLK /3 width=9/
  64   | elim (IHU1 … HLK) -IHU1 -HLK /3 width=8/
  65   ]
  66 ]
  67 qed.
  68
  69 lemma tps_weak: ∀L,T1,T2,d1,e1. L ⊢ T1 ▶ [d1, e1] T2 →
  70                 ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 →
  71                 L ⊢ T1 ▶ [d2, e2] T2.
  72 #L #T1 #T2 #d1 #e1 #H elim H -L -T1 -T2 -d1 -e1
  73 [ //
  74 | #L #K #V #W #i #d1 #e1 #Hid1 #Hide1 #HLK #HVW #d2 #e2 #Hd12 #Hde12
  75   lapply (transitive_le … Hd12 … Hid1) -Hd12 -Hid1 #Hid2
  76   lapply (lt_to_le_to_lt … Hide1 … Hde12) -Hide1 /2 width=4/
  77 | /4 width=3/
  78 | /4 width=1/
  79 ]
  80 qed.
  81
  82 lemma tps_weak_top: ∀L,T1,T2,d,e.
  83                     L ⊢ T1 ▶ [d, e] T2 → L ⊢ T1 ▶ [d, |L| - d] T2.
  84 #L #T1 #T2 #d #e #H elim H -L -T1 -T2 -d -e
  85 [ //
  86 | #L #K #V #W #i #d #e #Hdi #_ #HLK #HVW
  87   lapply (ldrop_fwd_ldrop2_length … HLK) #Hi
  88   lapply (le_to_lt_to_lt … Hdi Hi) /3 width=4/
  89 | normalize /2 width=1/
  90 | /2 width=1/
  91 ]
  92 qed.
  93
  94 lemma tps_weak_all: ∀L,T1,T2,d,e.
  95                     L ⊢ T1 ▶ [d, e] T2 → L ⊢ T1 ▶ [0, |L|] T2.
  96 #L #T1 #T2 #d #e #HT12
  97 lapply (tps_weak … HT12 0 (d + e) ? ?) -HT12 // #HT12
  98 lapply (tps_weak_top … HT12) //
  99 qed.
 100
 101 lemma tps_split_up: ∀L,T1,T2,d,e. L ⊢ T1 ▶ [d, e] T2 → ∀i. d ≤ i → i ≤ d + e →
 102                     ∃∃T. L ⊢ T1 ▶ [d, i - d] T & L ⊢ T ▶ [i, d + e - i] T2.
 103 #L #T1 #T2 #d #e #H elim H -L -T1 -T2 -d -e
 104 [ /2 width=3/
 105 | #L #K #V #W #i #d #e #Hdi #Hide #HLK #HVW #j #Hdj #Hjde
 106   elim (lt_or_ge i j)
 107   [ -Hide -Hjde
 108     >(plus_minus_m_m j d) in ⊢ (% → ?); // -Hdj /3 width=4/
 109   | -Hdi -Hdj #Hid
 110     generalize in match Hide; -Hide (**) (* rewriting in the premises, rewrites in the goal too *)
 111     >(plus_minus_m_m … Hjde) in ⊢ (% → ?); -Hjde /4 width=4/
 112   ]
 113 | #L #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
 114   elim (IHV12 i ? ?) -IHV12 // #V #HV1 #HV2
 115   elim (IHT12 (i + 1) ? ?) -IHT12 /2 width=1/
 116   -Hdi -Hide >arith_c1x #T #HT1 #HT2
 117   lapply (tps_lsubs_trans … HT1 (L. ⓑ{I} V) ?) -HT1 /3 width=5/
 118 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
 119   elim (IHV12 i ? ?) -IHV12 // elim (IHT12 i ? ?) -IHT12 //
 120   -Hdi -Hide /3 width=5/
 121 ]
 122 qed.
 123
 124 lemma tps_split_down: ∀L,T1,T2,d,e. L ⊢ T1 ▶ [d, e] T2 →
 125                       ∀i. d ≤ i → i ≤ d + e →
 126                       ∃∃T. L ⊢ T1 ▶ [i, d + e - i] T &
 127                            L ⊢ T ▶ [d, i - d] T2.
 128 #L #T1 #T2 #d #e #H elim H -L -T1 -T2 -d -e
 129 [ /2 width=3/
 130 | #L #K #V #W #i #d #e #Hdi #Hide #HLK #HVW #j #Hdj #Hjde
 131   elim (lt_or_ge i j)
 132   [ -Hide -Hjde >(plus_minus_m_m j d) in ⊢ (% → ?); // -Hdj /4 width=4/
 133   | -Hdi -Hdj
 134     >(plus_minus_m_m (d+e) j) in Hide; // -Hjde /3 width=4/
 135   ]
 136 | #L #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
 137   elim (IHV12 i ? ?) -IHV12 // #V #HV1 #HV2
 138   elim (IHT12 (i + 1) ? ?) -IHT12 /2 width=1/
 139   -Hdi -Hide >arith_c1x #T #HT1 #HT2
 140   lapply (tps_lsubs_trans … HT1 (L. ⓑ{I} V) ?) -HT1 /3 width=5/
 141 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
 142   elim (IHV12 i ? ?) -IHV12 // elim (IHT12 i ? ?) -IHT12 //
 143   -Hdi -Hide /3 width=5/
 144 ]
 145 qed.
 146
 147 lemma tps_append: ∀K,T1,T2,d,e. K ⊢ T1 ▶ [d, e] T2 →
 148                   ∀L. L @@ K ⊢ T1 ▶ [d, e] T2.
 149 #K #T1 #T2 #d #e #H elim H -K -T1 -T2 -d -e // /2 width=1/
 150 #K #K0 #V #W #i #d #e #Hdi #Hide #HK0 #HVW #L
 151 lapply (ldrop_fwd_ldrop2_length … HK0) #H
 152 @(tps_subst … (L@@K0) … HVW) // (**) (* /3/ does not work *)
 153 @(ldrop_O1_append_sn_le … HK0) /2 width=2/
 154 qed.
 155
 156 (* Basic inversion lemmas ***************************************************)
 157
 158 fact tps_inv_atom1_aux: ∀L,T1,T2,d,e. L ⊢ T1 ▶ [d, e] T2 → ∀I. T1 = ⓪{I} →
 159                         T2 = ⓪{I} ∨
 160                         ∃∃K,V,i. d ≤ i & i < d + e &
 161                                  ⇩[O, i] L ≡ K. ⓓV &
 162                                  ⇧[O, i + 1] V ≡ T2 &
 163                                  I = LRef i.
 164 #L #T1 #T2 #d #e * -L -T1 -T2 -d -e
 165 [ #L #I #d #e #J #H destruct /2 width=1/
 166 | #L #K #V #T2 #i #d #e #Hdi #Hide #HLK #HVT2 #I #H destruct /3 width=8/
 167 | #L #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #J #H destruct
 168 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #J #H destruct
 169 ]
 170 qed.
 171
 172 lemma tps_inv_atom1: ∀L,T2,I,d,e. L ⊢ ⓪{I} ▶ [d, e] T2 →
 173                      T2 = ⓪{I} ∨
 174                      ∃∃K,V,i. d ≤ i & i < d + e &
 175                               ⇩[O, i] L ≡ K. ⓓV &
 176                               ⇧[O, i + 1] V ≡ T2 &
 177                               I = LRef i.
 178 /2 width=3/ qed-.
 179
 180
 181 (* Basic_1: was: subst1_gen_sort *)
 182 lemma tps_inv_sort1: ∀L,T2,k,d,e. L ⊢ ⋆k ▶ [d, e] T2 → T2 = ⋆k.
 183 #L #T2 #k #d #e #H
 184 elim (tps_inv_atom1 … H) -H //
 185 * #K #V #i #_ #_ #_ #_ #H destruct
 186 qed-.
 187
 188 (* Basic_1: was: subst1_gen_lref *)
 189 lemma tps_inv_lref1: ∀L,T2,i,d,e. L ⊢ #i ▶ [d, e] T2 →
 190                      T2 = #i ∨
 191                      ∃∃K,V. d ≤ i & i < d + e &
 192                             ⇩[O, i] L ≡ K. ⓓV &
 193                             ⇧[O, i + 1] V ≡ T2.
 194 #L #T2 #i #d #e #H
 195 elim (tps_inv_atom1 … H) -H /2 width=1/
 196 * #K #V #j #Hdj #Hjde #HLK #HVT2 #H destruct /3 width=4/
 197 qed-.
 198
 199 lemma tps_inv_gref1: ∀L,T2,p,d,e. L ⊢ §p ▶ [d, e] T2 → T2 = §p.
 200 #L #T2 #p #d #e #H
 201 elim (tps_inv_atom1 … H) -H //
 202 * #K #V #i #_ #_ #_ #_ #H destruct
 203 qed-.
 204
 205 fact tps_inv_bind1_aux: ∀d,e,L,U1,U2. L ⊢ U1 ▶ [d, e] U2 →
 206                         ∀a,I,V1,T1. U1 = ⓑ{a,I} V1. T1 →
 207                         ∃∃V2,T2. L ⊢ V1 ▶ [d, e] V2 &
 208                                  L. ⓑ{I} V2 ⊢ T1 ▶ [d + 1, e] T2 &
 209                                  U2 = ⓑ{a,I} V2. T2.
 210 #d #e #L #U1 #U2 * -d -e -L -U1 -U2
 211 [ #L #k #d #e #a #I #V1 #T1 #H destruct
 212 | #L #K #V #W #i #d #e #_ #_ #_ #_ #a #I #V1 #T1 #H destruct
 213 | #L #b #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #a #I #V #T #H destruct /2 width=5/
 214 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #a #I #V #T #H destruct
 215 ]
 216 qed.
 217
 218 lemma tps_inv_bind1: ∀d,e,L,a,I,V1,T1,U2. L ⊢ ⓑ{a,I} V1. T1 ▶ [d, e] U2 →
 219                      ∃∃V2,T2. L ⊢ V1 ▶ [d, e] V2 &
 220                               L. ⓑ{I} V2 ⊢ T1 ▶ [d + 1, e] T2 &
 221                               U2 = ⓑ{a,I} V2. T2.
 222 /2 width=3/ qed-.
 223
 224 fact tps_inv_flat1_aux: ∀d,e,L,U1,U2. L ⊢ U1 ▶ [d, e] U2 →
 225                         ∀I,V1,T1. U1 = ⓕ{I} V1. T1 →
 226                         ∃∃V2,T2. L ⊢ V1 ▶ [d, e] V2 & L ⊢ T1 ▶ [d, e] T2 &
 227                                  U2 =  ⓕ{I} V2. T2.
 228 #d #e #L #U1 #U2 * -d -e -L -U1 -U2
 229 [ #L #k #d #e #I #V1 #T1 #H destruct
 230 | #L #K #V #W #i #d #e #_ #_ #_ #_ #I #V1 #T1 #H destruct
 231 | #L #a #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 232 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 233 ]
 234 qed.
 235
 236 lemma tps_inv_flat1: ∀d,e,L,I,V1,T1,U2. L ⊢ ⓕ{I} V1. T1 ▶ [d, e] U2 →
 237                      ∃∃V2,T2. L ⊢ V1 ▶ [d, e] V2 & L ⊢ T1 ▶ [d, e] T2 &
 238                               U2 =  ⓕ{I} V2. T2.
 239 /2 width=3/ qed-.
 240
 241 fact tps_inv_refl_O2_aux: ∀L,T1,T2,d,e. L ⊢ T1 ▶ [d, e] T2 → e = 0 → T1 = T2.
 242 #L #T1 #T2 #d #e #H elim H -L -T1 -T2 -d -e
 243 [ //
 244 | #L #K #V #W #i #d #e #Hdi #Hide #_ #_ #H destruct
 245   lapply (le_to_lt_to_lt … Hdi … Hide) -Hdi -Hide <plus_n_O #Hdd
 246   elim (lt_refl_false … Hdd)
 247 | /3 width=1/
 248 | /3 width=1/
 249 ]
 250 qed.
 251
 252 lemma tps_inv_refl_O2: ∀L,T1,T2,d. L ⊢ T1 ▶ [d, 0] T2 → T1 = T2.
 253 /2 width=6/ qed-.
 254
 255 (* Basic forward lemmas *****************************************************)
 256
 257 lemma tps_fwd_tw: ∀L,T1,T2,d,e. L ⊢ T1 ▶ [d, e] T2 → #{T1} ≤ #{T2}.
 258 #L #T1 #T2 #d #e #H elim H -L -T1 -T2 -d -e normalize
 259 /3 by monotonic_le_plus_l, le_plus/ (**) (* just /3 width=1/ is too slow *)
 260 qed-.
 261
 262 lemma tps_fwd_shift1: ∀L1,L,T1,T,d,e. L ⊢ L1 @@ T1 ▶[d, e] T →
 263                       ∃∃L2,T2. |L1| = |L2| & T = L2 @@ T2.
 264 #L1 @(lenv_ind_dx … L1) -L1 normalize
 265 [ #L #T1 #T #d #e #HT1
 266   @(ex2_2_intro … (⋆)) // (**) (* explicit constructor *)
 267 | #I #L1 #V1 #IH #L #T1 #X #d #e
 268   >shift_append_assoc normalize #H
 269   elim (tps_inv_bind1 … H) -H
 270   #V0 #T0 #_ #HT10 #H destruct
 271   elim (IH … HT10) -IH -HT10 #L2 #T2 #HL12 #H destruct
 272   >append_length >HL12 -HL12
 273   @(ex2_2_intro … (⋆.ⓑ{I}V0@@L2) T2) [ >append_length ] // /2 width=3/ (**) (* explicit constructor *)
 274 ]
 275 qed-.
 276
 277 (* Basic_1: removed theorems 25:
 278             subst0_gen_sort subst0_gen_lref subst0_gen_head subst0_gen_lift_lt
 279             subst0_gen_lift_false subst0_gen_lift_ge subst0_refl subst0_trans
 280             subst0_lift_lt subst0_lift_ge subst0_lift_ge_S subst0_lift_ge_s
 281             subst0_subst0 subst0_subst0_back subst0_weight_le subst0_weight_lt
 282             subst0_confluence_neq subst0_confluence_eq subst0_tlt_head
 283             subst0_confluence_lift subst0_tlt
 284             subst1_head subst1_gen_head subst1_lift_S subst1_confluence_lift
 285 *)