matita/matita/contribs/lambda_delta/basic_2/unfold/ltpss_sn.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/tpss.ma".
  16
  17 (* SN PARALLEL UNFOLD ON LOCAL ENVIRONMENTS *********************************)
  18
  19 inductive ltpss_sn: nat → nat → relation lenv ≝
  20 | ltpss_sn_atom : ∀d,e. ltpss_sn d e (⋆) (⋆)
  21 | ltpss_sn_pair : ∀L,I,V. ltpss_sn 0 0 (L. ⓑ{I} V) (L. ⓑ{I} V)
  22 | ltpss_sn_tpss2: ∀L1,L2,I,V1,V2,e.
  23                   ltpss_sn 0 e L1 L2 → L1 ⊢ V1 ▶* [0, e] V2 →
  24                   ltpss_sn 0 (e + 1) (L1. ⓑ{I} V1) (L2. ⓑ{I} V2)
  25 | ltpss_sn_tpss1: ∀L1,L2,I,V1,V2,d,e.
  26                   ltpss_sn d e L1 L2 → L1 ⊢ V1 ▶* [d, e] V2 →
  27                   ltpss_sn (d + 1) e (L1. ⓑ{I} V1) (L2. ⓑ{I} V2)
  28 .
  29
  30 interpretation "parallel unfold (local environment, sn variant)"
  31    'PSubstStarSn L1 d e L2 = (ltpss_sn d e L1 L2).
  32
  33 (* Basic inversion lemmas ***************************************************)
  34
  35 fact ltpss_sn_inv_refl_O2_aux: ∀d,e,L1,L2. L1 ⊢ ▶* [d, e] L2 → e = 0 → L1 = L2.
  36 #d #e #L1 #L2 #H elim H -d -e -L1 -L2 //
  37 [ #L1 #L2 #I #V1 #V2 #e #_ #_ #_ >commutative_plus normalize #H destruct
  38 | #L1 #L2 #I #V1 #V2 #d #e #_ #HV12 #IHL12 #He destruct
  39   >(IHL12 ?) -IHL12 // >(tpss_inv_refl_O2 … HV12) //
  40 ]
  41 qed.
  42
  43 lemma ltpss_sn_inv_refl_O2: ∀d,L1,L2. L1 ⊢ ▶* [d, 0] L2 → L1 = L2.
  44 /2 width=4/ qed-.
  45
  46 fact ltpss_sn_inv_atom1_aux: ∀d,e,L1,L2.
  47                              L1 ⊢ ▶* [d, e] L2 → L1 = ⋆ → L2 = ⋆.
  48 #d #e #L1 #L2 * -d -e -L1 -L2
  49 [ //
  50 | #L #I #V #H destruct
  51 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H destruct
  52 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
  53 ]
  54 qed.
  55
  56 lemma ltpss_sn_inv_atom1: ∀d,e,L2. ⋆ ⊢ ▶* [d, e] L2 → L2 = ⋆.
  57 /2 width=5/ qed-.
  58
  59 fact ltpss_sn_inv_tpss21_aux: ∀d,e,L1,L2. L1 ⊢ ▶* [d, e] L2 → d = 0 → 0 < e →
  60                               ∀K1,I,V1. L1 = K1. ⓑ{I} V1 →
  61                               ∃∃K2,V2. K1 ⊢ ▶* [0, e - 1] K2 &
  62                                        K1 ⊢ V1 ▶* [0, e - 1] V2 &
  63                                        L2 = K2. ⓑ{I} V2.
  64 #d #e #L1 #L2 * -d -e -L1 -L2
  65 [ #d #e #_ #_ #K1 #I #V1 #H destruct
  66 | #L1 #I #V #_ #H elim (lt_refl_false … H)
  67 | #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #_ #_ #K1 #J #W1 #H destruct /2 width=5/
  68 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ >commutative_plus normalize #H destruct
  69 ]
  70 qed.
  71
  72 lemma ltpss_sn_inv_tpss21: ∀e,K1,I,V1,L2. K1. ⓑ{I} V1 ⊢ ▶* [0, e] L2 → 0 < e →
  73                            ∃∃K2,V2. K1 ⊢ ▶* [0, e - 1] K2 &
  74                                     K1 ⊢ V1 ▶* [0, e - 1] V2 &
  75                                     L2 = K2. ⓑ{I} V2.
  76 /2 width=5/ qed-.
  77
  78 fact ltpss_sn_inv_tpss11_aux: ∀d,e,L1,L2. L1 ⊢ ▶* [d, e] L2 → 0 < d →
  79                               ∀I,K1,V1. L1 = K1. ⓑ{I} V1 →
  80                               ∃∃K2,V2. K1 ⊢ ▶* [d - 1, e] K2 &
  81                                        K1 ⊢ V1 ▶* [d - 1, e] V2 &
  82                                        L2 = K2. ⓑ{I} V2.
  83 #d #e #L1 #L2 * -d -e -L1 -L2
  84 [ #d #e #_ #I #K1 #V1 #H destruct
  85 | #L #I #V #H elim (lt_refl_false … H)
  86 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H elim (lt_refl_false … H)
  87 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #_ #J #K1 #W1 #H destruct /2 width=5/
  88 ]
  89 qed.
  90
  91 lemma ltpss_sn_inv_tpss11: ∀d,e,I,K1,V1,L2. K1. ⓑ{I} V1 ⊢ ▶* [d, e] L2 → 0 < d →
  92                            ∃∃K2,V2. K1 ⊢ ▶* [d - 1, e] K2 &
  93                                     K1 ⊢ V1 ▶* [d - 1, e] V2 &
  94                                     L2 = K2. ⓑ{I} V2.
  95 /2 width=3/ qed-.
  96
  97 fact ltpss_sn_inv_atom2_aux: ∀d,e,L1,L2.
  98                              L1 ⊢ ▶* [d, e] L2 → L2 = ⋆ → L1 = ⋆.
  99 #d #e #L1 #L2 * -d -e -L1 -L2
 100 [ //
 101 | #L #I #V #H destruct
 102 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H destruct
 103 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
 104 ]
 105 qed.
 106
 107 lemma ltpss_sn_inv_atom2: ∀d,e,L1. L1 ⊢ ▶* [d, e] ⋆ → L1 = ⋆.
 108 /2 width=5/ qed-.
 109
 110 fact ltpss_sn_inv_tpss22_aux: ∀d,e,L1,L2. L1 ⊢ ▶* [d, e] L2 → d = 0 → 0 < e →
 111                               ∀K2,I,V2. L2 = K2. ⓑ{I} V2 →
 112                               ∃∃K1,V1. K1 ⊢ ▶* [0, e - 1] K2 &
 113                                        K1 ⊢ V1 ▶* [0, e - 1] V2 &
 114                                        L1 = K1. ⓑ{I} V1.
 115 #d #e #L1 #L2 * -d -e -L1 -L2
 116 [ #d #e #_ #_ #K1 #I #V1 #H destruct
 117 | #L1 #I #V #_ #H elim (lt_refl_false … H)
 118 | #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #_ #_ #K2 #J #W2 #H destruct /2 width=5/
 119 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ >commutative_plus normalize #H destruct
 120 ]
 121 qed.
 122
 123 lemma ltpss_sn_inv_tpss22: ∀e,L1,K2,I,V2. L1 ⊢ ▶* [0, e] K2. ⓑ{I} V2 → 0 < e →
 124                            ∃∃K1,V1. K1 ⊢ ▶* [0, e - 1] K2 &
 125                                     K1 ⊢ V1 ▶* [0, e - 1] V2 &
 126                                     L1 = K1. ⓑ{I} V1.
 127 /2 width=5/ qed-.
 128
 129 fact ltpss_sn_inv_tpss12_aux: ∀d,e,L1,L2. L1 ⊢ ▶* [d, e] L2 → 0 < d →
 130                               ∀I,K2,V2. L2 = K2. ⓑ{I} V2 →
 131                               ∃∃K1,V1. K1 ⊢ ▶* [d - 1, e] K2 &
 132                                        K1 ⊢ V1 ▶* [d - 1, e] V2 &
 133                                        L1 = K1. ⓑ{I} V1.
 134 #d #e #L1 #L2 * -d -e -L1 -L2
 135 [ #d #e #_ #I #K2 #V2 #H destruct
 136 | #L #I #V #H elim (lt_refl_false … H)
 137 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H elim (lt_refl_false … H)
 138 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #_ #J #K2 #W2 #H destruct /2 width=5/
 139 ]
 140 qed.
 141
 142 lemma ltpss_sn_inv_tpss12: ∀L1,K2,I,V2,d,e. L1 ⊢ ▶* [d, e] K2. ⓑ{I} V2 → 0 < d →
 143                            ∃∃K1,V1. K1 ⊢ ▶* [d - 1, e] K2 &
 144                                     K1 ⊢ V1 ▶* [d - 1, e] V2 &
 145                                     L1 = K1. ⓑ{I} V1.
 146 /2 width=3/ qed-.
 147
 148 (* Basic properties *********************************************************)
 149
 150 lemma ltpss_sn_tps2: ∀L1,L2,I,V1,V2,e.
 151                      L1 ⊢ ▶* [0, e] L2 → L1 ⊢ V1 ▶ [0, e] V2 →
 152                      L1. ⓑ{I} V1 ⊢ ▶* [0, e + 1] L2. ⓑ{I} V2.
 153 /3 width=1/ qed.
 154
 155 lemma ltpss_sn_tps1: ∀L1,L2,I,V1,V2,d,e.
 156                      L1 ⊢ ▶* [d, e] L2 → L1 ⊢ V1 ▶ [d, e] V2 →
 157                      L1. ⓑ{I} V1 ⊢ ▶* [d + 1, e] L2. ⓑ{I} V2.
 158 /3 width=1/ qed.
 159
 160 lemma ltpss_sn_tpss2_lt: ∀L1,L2,I,V1,V2,e.
 161                          L1 ⊢ ▶* [0, e - 1] L2 → L1 ⊢ V1 ▶* [0, e - 1] V2 →
 162                          0 < e → L1. ⓑ{I} V1 ⊢ ▶* [0, e] L2. ⓑ{I} V2.
 163 #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #He
 164 >(plus_minus_m_m e 1) /2 width=1/
 165 qed.
 166
 167 lemma ltpss_sn_tpss1_lt: ∀L1,L2,I,V1,V2,d,e.
 168                          L1 ⊢ ▶* [d - 1, e] L2 → L1 ⊢ V1 ▶* [d - 1, e] V2 →
 169                          0 < d → L1. ⓑ{I} V1 ⊢ ▶* [d, e] L2. ⓑ{I} V2.
 170 #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #Hd
 171 >(plus_minus_m_m d 1) /2 width=1/
 172 qed.
 173
 174 lemma ltpss_sn_tps2_lt: ∀L1,L2,I,V1,V2,e.
 175                         L1 ⊢ ▶* [0, e - 1] L2 → L1 ⊢ V1 ▶ [0, e - 1] V2 →
 176                         0 < e → L1. ⓑ{I} V1 ⊢ ▶* [0, e] L2. ⓑ{I} V2.
 177 /3 width=1/ qed.
 178
 179 lemma ltpss_sn_tps1_lt: ∀L1,L2,I,V1,V2,d,e.
 180                         L1 ⊢ ▶* [d - 1, e] L2 → L1 ⊢ V1 ▶ [d - 1, e] V2 →
 181                         0 < d → L1. ⓑ{I} V1 ⊢ ▶* [d, e] L2. ⓑ{I} V2.
 182 /3 width=1/ qed.
 183
 184 lemma ltpss_sn_refl: ∀L,d,e. L ⊢ ▶* [d, e] L.
 185 #L elim L -L //
 186 #L #I #V #IHL * /2 width=1/ * /2 width=1/
 187 qed.
 188
 189 lemma ltpss_sn_weak: ∀L1,L2,d1,e1. L1 ⊢ ▶* [d1, e1] L2 →
 190                      ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 → L1 ⊢ ▶* [d2, e2] L2.
 191 #L1 #L2 #d1 #e1 #H elim H -L1 -L2 -d1 -e1 //
 192 [ #L1 #L2 #I #V1 #V2 #e1 #_ #HV12 #IHL12 #d2 #e2 #Hd2 #Hde2
 193   lapply (le_n_O_to_eq … Hd2) #H destruct normalize in Hde2;
 194   lapply (lt_to_le_to_lt 0 … Hde2) // #He2
 195   lapply (le_plus_to_minus_r … Hde2) -Hde2 /3 width=5/
 196 | #L1 #L2 #I #V1 #V2 #d1 #e1 #_ #HV12 #IHL12 #d2 #e2 #Hd21 #Hde12
 197   >plus_plus_comm_23 in Hde12; #Hde12
 198   elim (le_to_or_lt_eq 0 d2 ?) // #H destruct
 199   [ lapply (le_plus_to_minus_r … Hde12) -Hde12 <plus_minus // #Hde12
 200     lapply (le_plus_to_minus … Hd21) -Hd21 #Hd21 /3 width=5/
 201   | -Hd21 normalize in Hde12;
 202     lapply (lt_to_le_to_lt 0 … Hde12) // #He2
 203     lapply (le_plus_to_minus_r … Hde12) -Hde12
 204     /3 width=5 by ltpss_sn_tpss2_lt, tpss_weak/ (**) (* /3 width=5/ used to work *)
 205   ]
 206 ]
 207 qed.
 208
 209 lemma ltpss_sn_weak_all: ∀L1,L2,d,e. L1 ⊢ ▶* [d, e] L2 → L1 ⊢ ▶* [0, |L1|] L2.
 210 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e
 211 // /3 width=2/ /3 width=3/
 212 qed.
 213
 214 fact ltpss_sn_append_le_aux: ∀K1,K2,d,x. K1 ⊢ ▶* [d, x] K2 → x = |K1| - d →
 215                              ∀L1,L2,e. L1 ⊢ ▶* [0, e] L2 → d ≤ |K1| →
 216                              L1 @@ K1 ⊢ ▶* [d, x + e] L2 @@ K2.
 217 #K1 #K2 #d #x #H elim H -K1 -K2 -d -x
 218 [ #d #x #H1 #L1 #L2 #e #HL12 #H2 destruct
 219   lapply (le_n_O_to_eq … H2) -H2 #H destruct //
 220 | #K #I #V <minus_n_O normalize <plus_n_Sm #H destruct
 221 | #K1 #K2 #I #V1 #V2 #x #_ #HV12 <minus_n_O #IHK12 <minus_n_O #H #L1 #L2 #e #HL12 #_
 222   lapply (injective_plus_l … H) -H #H destruct >plus_plus_comm_23
 223   /4 width=5 by ltpss_sn_tpss2, tpss_append, tpss_weak, monotonic_le_plus_r/ (**) (* too slow without trace *)
 224 | #K1 #K2 #I #V1 #V2 #d #x #_ #HV12 #IHK12 normalize <minus_le_minus_minus_comm // <minus_plus_m_m #H1 #L1 #L2 #e #HL12 #H2 destruct
 225   lapply (le_plus_to_le_r … H2) -H2 #Hd
 226   /4 width=5 by ltpss_sn_tpss1, tpss_append, tpss_weak, monotonic_le_plus_r/ (**) (* too slow without trace *)
 227 ]
 228 qed-.
 229
 230 lemma ltpss_sn_append_le: ∀K1,K2,d. K1 ⊢ ▶* [d, |K1| - d] K2 →
 231                           ∀L1,L2,e. L1 ⊢ ▶* [0, e] L2 → d ≤ |K1| →
 232                           L1 @@ K1 ⊢ ▶* [d, |K1| - d + e] L2 @@ K2.
 233 /2 width=1 by ltpss_sn_append_le_aux/ qed.
 234
 235 lemma ltpss_sn_append_ge: ∀K1,K2,d,e. K1 ⊢ ▶* [d, e] K2 →
 236                           ∀L1,L2. L1 ⊢ ▶* [d - |K1|, e] L2 → |K1| ≤ d →
 237                           L1 @@ K1 ⊢ ▶* [d, e] L2 @@ K2.
 238 #K1 #K2 #d #e #H elim H -K1 -K2 -d -e
 239 [ #d #e #L1 #L2 <minus_n_O //
 240 | #K #I #V #L1 #L2 #_ #H
 241   lapply (le_n_O_to_eq … H) -H normalize <plus_n_Sm #H destruct
 242 | #K1 #K2 #I #V1 #V2 #e #_ #_ #_ #L1 #L2 #_ #H
 243   lapply (le_n_O_to_eq … H) -H normalize <plus_n_Sm #H destruct
 244 | #K1 #K2 #I #V1 #V2 #d #e #_ #HV12 #IHK12 #L1 #L2
 245   normalize <minus_le_minus_minus_comm // <minus_plus_m_m #HL12 #H
 246   lapply (le_plus_to_le_r … H) -H /3 width=1/
 247 ]
 248 qed.
 249
 250 (* Basic forward lemmas *****************************************************)
 251
 252 lemma ltpss_sn_fwd_length: ∀L1,L2,d,e. L1 ⊢ ▶* [d, e] L2 → |L1| = |L2|.
 253 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e
 254 normalize //
 255 qed-.