matita/matita/contribs/lambda_delta/ground_2/star.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basics/star.ma".
  16 include "ground_2/xoa_props.ma".
  17 include "ground_2/notation.ma".
  18
  19 (* PROPERTIES OF RELATIONS **************************************************)
  20
  21 definition Decidable: Prop → Prop ≝ λR. R ∨ (R → ⊥).
  22
  23 definition Confluent: ∀A. ∀R: relation A. Prop ≝ λA,R.
  24                       ∀a0,a1. R a0 a1 → ∀a2. R a0 a2 →
  25                       ∃∃a. R a1 a & R a2 a.
  26
  27 definition Transitive: ∀A. ∀R: relation A. Prop ≝ λA,R.
  28                        ∀a1,a0. R a1 a0 → ∀a2. R a0 a2 → R a1 a2.
  29
  30 definition confluent2: ∀A. ∀R1,R2: relation A. Prop ≝ λA,R1,R2.
  31                        ∀a0,a1. R1 a0 a1 → ∀a2. R2 a0 a2 →
  32                        ∃∃a. R2 a1 a & R1 a2 a.
  33
  34 definition transitive2: ∀A. ∀R1,R2: relation A. Prop ≝ λA,R1,R2.
  35                         ∀a1,a0. R1 a1 a0 → ∀a2. R2 a0 a2 →
  36                         ∃∃a. R2 a1 a & R1 a a2.
  37
  38 definition bi_confluent:  ∀A,B. ∀R: bi_relation A B. Prop ≝ λA,B,R.
  39                           ∀a0,a1,b0,b1. R a0 b0 a1 b1 → ∀a2,b2. R a0 b0 a2 b2 →
  40                           ∃∃a,b. R a1 b1 a b & R a2 b2 a b.
  41
  42 lemma TC_strip1: ∀A,R1,R2. confluent2 A R1 R2 →
  43                  ∀a0,a1. TC … R1 a0 a1 → ∀a2. R2 a0 a2 →
  44                  ∃∃a. R2 a1 a & TC … R1 a2 a.
  45 #A #R1 #R2 #HR12 #a0 #a1 #H elim H -a1
  46 [ #a1 #Ha01 #a2 #Ha02
  47   elim (HR12 … Ha01 … Ha02) -HR12 -a0 /3 width=3/
  48 | #a #a1 #_ #Ha1 #IHa0 #a2 #Ha02
  49   elim (IHa0 … Ha02) -a0 #a0 #Ha0 #Ha20
  50   elim (HR12 … Ha1 … Ha0) -HR12 -a /4 width=3/
  51 ]
  52 qed.
  53
  54 lemma TC_strip2: ∀A,R1,R2. confluent2 A R1 R2 →
  55                  ∀a0,a2. TC … R2 a0 a2 → ∀a1. R1 a0 a1 →
  56                  ∃∃a. TC … R2 a1 a & R1 a2 a.
  57 #A #R1 #R2 #HR12 #a0 #a2 #H elim H -a2
  58 [ #a2 #Ha02 #a1 #Ha01
  59   elim (HR12 … Ha01 … Ha02) -HR12 -a0 /3 width=3/
  60 | #a #a2 #_ #Ha2 #IHa0 #a1 #Ha01
  61   elim (IHa0 … Ha01) -a0 #a0 #Ha10 #Ha0
  62   elim (HR12 … Ha0 … Ha2) -HR12 -a /4 width=3/
  63 ]
  64 qed.
  65
  66 lemma TC_confluent2: ∀A,R1,R2.
  67                      confluent2 A R1 R2 → confluent2 A (TC … R1) (TC … R2).
  68 #A #R1 #R2 #HR12 #a0 #a1 #H elim H -a1
  69 [ #a1 #Ha01 #a2 #Ha02
  70   elim (TC_strip2 … HR12 … Ha02 … Ha01) -HR12 -a0 /3 width=3/
  71 | #a #a1 #_ #Ha1 #IHa0 #a2 #Ha02
  72   elim (IHa0 … Ha02) -a0 #a0 #Ha0 #Ha20
  73   elim (TC_strip2 … HR12 … Ha0 … Ha1) -HR12 -a /4 width=3/
  74 ]
  75 qed.
  76
  77 lemma TC_strap1: ∀A,R1,R2. transitive2 A R1 R2 →
  78                  ∀a1,a0. TC … R1 a1 a0 → ∀a2. R2 a0 a2 →
  79                  ∃∃a. R2 a1 a & TC … R1 a a2.
  80 #A #R1 #R2 #HR12 #a1 #a0 #H elim H -a0
  81 [ #a0 #Ha10 #a2 #Ha02
  82   elim (HR12 … Ha10 … Ha02) -HR12 -a0 /3 width=3/
  83 | #a #a0 #_ #Ha0 #IHa #a2 #Ha02
  84   elim (HR12 … Ha0 … Ha02) -HR12 -a0 #a0 #Ha0 #Ha02
  85   elim (IHa … Ha0) -a /4 width=3/
  86 ]
  87 qed.
  88
  89 lemma TC_strap2: ∀A,R1,R2. transitive2 A R1 R2 →
  90                  ∀a0,a2. TC … R2 a0 a2 → ∀a1. R1 a1 a0 →
  91                  ∃∃a. TC … R2 a1 a & R1 a a2.
  92 #A #R1 #R2 #HR12 #a0 #a2 #H elim H -a2
  93 [ #a2 #Ha02 #a1 #Ha10
  94   elim (HR12 … Ha10 … Ha02) -HR12 -a0 /3 width=3/
  95 | #a #a2 #_ #Ha02 #IHa #a1 #Ha10
  96   elim (IHa … Ha10) -a0 #a0 #Ha10 #Ha0
  97   elim (HR12 … Ha0 … Ha02) -HR12 -a /4 width=3/
  98 ]
  99 qed.
 100
 101 lemma TC_transitive2: ∀A,R1,R2.
 102                       transitive2 A R1 R2 → transitive2 A (TC … R1) (TC … R2).
 103 #A #R1 #R2 #HR12 #a1 #a0 #H elim H -a0
 104 [ #a0 #Ha10 #a2 #Ha02
 105   elim (TC_strap2 … HR12 … Ha02 … Ha10) -HR12 -a0 /3 width=3/
 106 | #a #a0 #_ #Ha0 #IHa #a2 #Ha02
 107   elim (TC_strap2 … HR12 … Ha02 … Ha0) -HR12 -a0 #a0 #Ha0 #Ha02
 108   elim (IHa … Ha0) -a /4 width=3/
 109 ]
 110 qed.
 111
 112 definition NF: ∀A. relation A → relation A → predicate A ≝
 113    λA,R,S,a1. ∀a2. R a1 a2 → S a2 a1.
 114
 115 inductive SN (A) (R,S:relation A): predicate A ≝
 116 | SN_intro: ∀a1. (∀a2. R a1 a2 → (S a2 a1 → ⊥) → SN A R S a2) → SN A R S a1
 117 .
 118
 119 lemma NF_to_SN: ∀A,R,S,a. NF A R S a → SN A R S a.
 120 #A #R #S #a1 #Ha1
 121 @SN_intro #a2 #HRa12 #HSa12
 122 elim (HSa12 ?) -HSa12 /2 width=1/
 123 qed.
 124
 125 definition NF_sn: ∀A. relation A → relation A → predicate A ≝
 126    λA,R,S,a2. ∀a1. R a1 a2 → S a2 a1.
 127
 128 inductive SN_sn (A) (R,S:relation A): predicate A ≝
 129 | SN_sn_intro: ∀a2. (∀a1. R a1 a2 → (S a2 a1 → ⊥) → SN_sn A R S a1) → SN_sn A R S a2
 130 .
 131
 132 lemma NF_to_SN_sn: ∀A,R,S,a. NF_sn A R S a → SN_sn A R S a.
 133 #A #R #S #a2 #Ha2
 134 @SN_sn_intro #a1 #HRa12 #HSa12
 135 elim (HSa12 ?) -HSa12 /2 width=1/
 136 qed.
 137
 138 lemma bi_TC_strip: ∀A,B,R. bi_confluent A B R →
 139                    ∀a0,a1,b0,b1. R a0 b0 a1 b1 → ∀a2,b2. bi_TC … R a0 b0 a2 b2 →
 140                    ∃∃a,b. bi_TC … R a1 b1 a b & R a2 b2 a b.
 141 #A #B #R #HR #a0 #a1 #b0 #b1 #H01 #a2 #b2 #H elim H -a2 -b2
 142 [ #a2 #b2 #H02
 143   elim (HR … H01 … H02) -HR -a0 -b0 /3 width=4/
 144 | #a2 #b2 #a3 #b3 #_ #H23 * #a #b #H1 #H2
 145   elim (HR … H23 … H2) -HR -a0 -b0 -a2 -b2 /3 width=4/
 146 ]
 147 qed.
 148
 149 lemma bi_TC_confluent: ∀A,B,R. bi_confluent A B R →
 150                        bi_confluent A B (bi_TC … R).
 151 #A #B #R #HR #a0 #a1 #b0 #b1 #H elim H -a1 -b1
 152 [ #a1 #b1 #H01 #a2 #b2 #H02
 153   elim (bi_TC_strip … HR … H01 … H02) -a0 -b0 /3 width=4/
 154 | #a1 #b1 #a3 #b3 #_ #H13 #IH #a2 #b2 #H02
 155   elim (IH … H02) -a0 -b0 #a0 #b0 #H10 #H20
 156   elim (bi_TC_strip … HR … H13 … H10) -a1 -b1 /3 width=7/
 157 ]
 158 qed.