matita/matita/contribs/lambdadelta/apps_2/examples/ex_rpx_fwd.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/reqx_fqup.ma".
  16 include "basic_2/rt_transition/lpx.ma".
  17 include "basic_2/rt_transition/rpx.ma".
  18
  19 (* EXAMPLES *****************************************************************)
  20
  21 (* Lemma "rpx_fwd_lpx_reqx" is not an inversion *****************************)
  22
  23 definition L1 (K) (s1) (s0): lenv ≝ K.ⓛ⋆s1.ⓛⓝ#0.⋆s0.
  24
  25 definition L (K) (s1) (s0): lenv ≝ K.ⓛ⋆s1.ⓛ⋆s0.
  26
  27 definition L2 (K) (i1) (s0): lenv ≝ K.ⓛ#i1.ⓛ⋆s0.
  28
  29 definition T: term ≝ #0.
  30
  31 (* Basic properties *********************************************************)
  32
  33 lemma ex_rpx_fwd_1 (G) (K) (s1) (s0):
  34       ❪G,L1 K s1 s0❫ ⊢ ⬈ L K s1 s0.
  35 /3 width=1 by lpx_pair, lpx_bind_refl_dx, cpx_eps/ qed.
  36
  37 lemma ex_rpx_fwd_2 (K) (s1) (s0) (i1) (i0):
  38       L K s1 s0 ≛[T] L2 K i1 i0.
  39 /3 width=1 by reqx_pair, reqx_sort/ qed.
  40
  41 lemma ex_rpx_fwd_3 (G) (K) (s1) (s0) (i1) (i0):
  42       ❪G,L1 K s1 s0❫ ⊢ ⬈[T] L2 K i1 i0 → ⊥.
  43 #G #K #s1 #s0 #i1 #i0 #H
  44 elim (rpx_inv_zero_pair_sn … H) -H #Y2 #X2 #H #_ normalize #H0 destruct
  45 elim (rpx_inv_flat … H) -H #H #_
  46 elim (rpx_inv_zero_pair_sn … H) -H #Y2 #X2 #_ #H #H0 destruct
  47 elim (cpx_inv_sort1 … H) #s2 #H destruct
  48 qed-.
  49
  50 (* Main properties **********************************************************)
  51
  52 theorem ex_rpx_fwd (G) (K) (s1) (s0) (i1) (i0):
  53         (❪G,L1 K s1 s0❫ ⊢ ⬈ L K s1 s0 → L K s1 s0 ≛[T] L2 K i1 i0 → ❪G,L1 K s1 s0❫ ⊢ ⬈[T] L2 K i1 i0) → ⊥.
  54 /3 width=7 by ex_rpx_fwd_3, ex_rpx_fwd_2, ex_rpx_fwd_1/ qed-.