matita/matita/contribs/lambdadelta/apps_2/examples/ex_rpx_fwd.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/reqg_fqup.ma".
  16 include "static_2/static/reqx.ma".
  17 include "basic_2/rt_transition/lpx.ma".
  18 include "basic_2/rt_transition/rpx.ma".
  19
  20 (* EXAMPLES *****************************************************************)
  21
  22 (* Lemma "rpx_fwd_lpx_reqx" is not an inversion *****************************)
  23
  24 definition L1 (K) (s1) (s0): lenv ≝ K.ⓛ⋆s1.ⓛⓝ#0.⋆s0.
  25
  26 definition L (K) (s1) (s0): lenv ≝ K.ⓛ⋆s1.ⓛ⋆s0.
  27
  28 definition L2 (K) (i1) (s0): lenv ≝ K.ⓛ#i1.ⓛ⋆s0.
  29
  30 definition T: term ≝ #0.
  31
  32 (* Basic properties *********************************************************)
  33
  34 lemma ex_rpx_fwd_1 (G) (K) (s1) (s0):
  35       ❪G,L1 K s1 s0❫ ⊢ ⬈ L K s1 s0.
  36 /3 width=1 by lpx_pair, lpx_bind_refl_dx, cpx_eps/ qed.
  37
  38 lemma ex_rpx_fwd_2 (K) (s1) (s0) (i1) (i0):
  39       L K s1 s0 ≅[T] L2 K i1 i0.
  40 /4 width=1 by reqg_refl, reqg_pair, reqg_sort, teqg_sort/ qed.
  41
  42 lemma ex_rpx_fwd_3 (G) (K) (s1) (s0) (i1) (i0):
  43       ❪G,L1 K s1 s0❫ ⊢ ⬈[T] L2 K i1 i0 → ⊥.
  44 #G #K #s1 #s0 #i1 #i0 #H
  45 elim (rpx_inv_zero_pair_sn … H) -H #Y2 #X2 #H #_ normalize #H0 destruct
  46 elim (rpx_inv_flat … H) -H #H #_
  47 elim (rpx_inv_zero_pair_sn … H) -H #Y2 #X2 #_ #H #H0 destruct
  48 elim (cpx_inv_sort1 … H) #s2 #H destruct
  49 qed-.
  50
  51 (* Main properties **********************************************************)
  52
  53 theorem ex_rpx_fwd (G) (K) (s1) (s0) (i1) (i0):
  54         (❪G,L1 K s1 s0❫ ⊢ ⬈ L K s1 s0 → L K s1 s0 ≅[T] L2 K i1 i0 → ❪G,L1 K s1 s0❫ ⊢ ⬈[T] L2 K i1 i0) → ⊥.
  55 /3 width=7 by ex_rpx_fwd_3, ex_rpx_fwd_2, ex_rpx_fwd_1/ qed-.