matita/matita/contribs/lambdadelta/apps_2/models/model_li.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/syntax/lenv.ma".
  16 include "apps_2/models/model_push.ma".
  17 include "apps_2/notation/models/inwbrackets_4.ma".
  18
  19 (* LOCAL ENVIRONMENT INTERPRETATION  ****************************************)
  20
  21 inductive li (M) (gv): relation2 lenv (evaluation M) ≝
  22 | li_atom: ∀lv. li M gv (⋆) lv
  23 | li_abbr: ∀lv,d,L,V. li M gv L lv → ⟦V⟧[gv, lv] ≗ d → li M gv (L.ⓓV) (⫯[d]lv)
  24 | li_abst: ∀lv,d,L,W. li M gv L lv → li M gv (L.ⓛW) (⫯[d]lv)
  25 | li_unit: ∀lv,d,I,L. li M gv L lv → li M gv (L.ⓤ{I}) (⫯[d]lv)
  26 .
  27
  28 interpretation "local environment interpretation (model)"
  29    'InWBrackets M gv L lv  = (li M gv L lv).
  30
  31 (* Basic inversion lemmas ***************************************************)
  32
  33 fact li_inv_abbr_aux (M) (gv): ∀v,Y. v ϵ ⟦Y⟧{M}[gv] → ∀L,V. Y = L.ⓓV →
  34                                ∃∃lv,d. lv ϵ ⟦L⟧{M}[gv] & ⟦V⟧{M}[gv, lv] ≗ d & ⫯{M}[d]lv = v.
  35 #M #gv #v #Y * -v -Y
  36 [ #lv #K #W #H destruct
  37 | #lv #d #L #V #HL #HV #K #W #H destruct /2 width=5 by ex3_2_intro/
  38 | #lv #d #L #V #_ #K #W #H destruct
  39 | #lv #d #I #L #_ #K #W #H destruct
  40 ]
  41 qed-.
  42
  43 lemma li_inv_abbr (M) (gv): ∀v,L,V. v ϵ ⟦L.ⓓV⟧{M}[gv] →
  44                             ∃∃lv,d. lv ϵ ⟦L⟧{M}[gv] & ⟦V⟧{M}[gv, lv] ≗ d & ⫯{M}[d]lv = v.
  45 /2 width=3 by li_inv_abbr_aux/ qed-.
  46
  47 fact li_inv_abst_aux (M) (gv): ∀v,Y. v ϵ ⟦Y⟧{M}[gv] → ∀L,W. Y = L.ⓛW →
  48                                ∃∃lv,d. lv ϵ ⟦L⟧{M}[gv] & ⫯{M}[d]lv = v.
  49 #M #gv #v #Y * -v -Y
  50 [ #lv #K #U #H destruct
  51 | #lv #d #L #V #_ #_ #K #U #H destruct
  52 | #lv #d #L #V #HL #K #U #H destruct /2 width=4 by ex2_2_intro/
  53 | #lv #d #I #L #_ #K #U #H destruct
  54 ]
  55 qed-.
  56
  57 lemma li_inv_abst (M) (gv): ∀v,L,W. v ϵ ⟦L.ⓛW⟧{M}[gv] →
  58                             ∃∃lv,d. lv ϵ ⟦L⟧{M}[gv] & ⫯{M}[d]lv = v.
  59 /2 width=4 by li_inv_abst_aux/ qed-.
  60
  61 fact li_inv_unit_aux (M) (gv): ∀v,Y. v ϵ ⟦Y⟧{M}[gv] → ∀I,L. Y = L.ⓤ{I} →
  62                                ∃∃lv,d. lv ϵ ⟦L⟧{M}[gv] & ⫯{M}[d]lv = v.
  63 #M #gv #v #Y * -v -Y
  64 [ #lv #J #K #H destruct
  65 | #lv #d #L #V #_ #_ #J #K #H destruct
  66 | #lv #d #L #V #_ #J #K #H destruct
  67 | #lv #d #I #L #HL #J #K #H destruct /2 width=4 by ex2_2_intro/
  68 ]
  69 qed-.
  70
  71 lemma li_inv_unit (M) (gv): ∀v,I,L. v ϵ ⟦L.ⓤ{I}⟧{M}[gv] →
  72                             ∃∃lv,d. lv ϵ ⟦L⟧{M}[gv] & ⫯{M}[d]lv = v.
  73 /2 width=4 by li_inv_unit_aux/ qed-.