matita/matita/contribs/lambdadelta/apps_2/models/model_li.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/syntax/lenv.ma".
  16 include "apps_2/models/model_vlift.ma".
  17 include "apps_2/notation/models/inwbrackets_4.ma".
  18
  19 (* LOCAL ENVIRONMENT INTERPRETATION  ****************************************)
  20
  21 inductive li (M) (gv): relation2 lenv (evaluation M) ≝
  22 | li_atom: ∀lv. li M gv (⋆) lv
  23 | li_abbr: ∀lv,d,L,V. li M gv L lv → ⟦V⟧[gv, lv] ≗ d → li M gv (L.ⓓV) (⫯[d]lv)
  24 | li_abst: ∀lv,d,L,W. li M gv L lv → li M gv (L.ⓛW) (⫯[d]lv)
  25 | li_unit: ∀lv,d,I,L. li M gv L lv → li M gv (L.ⓤ{I}) (⫯[d]lv)
  26 | li_repl: ∀lv1,lv2,L. li M gv L lv1 → lv1 ≐ lv2 → li M gv L lv2
  27 .
  28
  29 interpretation "local environment interpretation (model)"
  30    'InWBrackets M gv L lv  = (li M gv L lv).
  31
  32 (* Basic inversion lemmas ***************************************************)
  33
  34 fact li_inv_abbr_aux (M) (gv): ∀v,Y. v ϵ ⟦Y⟧{M}[gv] → ∀L,V. Y = L.ⓓV →
  35                                ∃∃lv,d. lv ϵ ⟦L⟧{M}[gv] & ⟦V⟧{M}[gv, lv] ≗ d & ⫯{M}[d]lv ≐ v.
  36 #M #gv #v #Y #H elim H -v -Y
  37 [ #lv #K #W #H destruct
  38 | #lv #d #L #V #HL #HV #_ #K #W #H destruct /2 width=5 by ex3_2_intro/
  39 | #lv #d #L #V #_ #_ #K #W #H destruct
  40 | #lv #d #I #L #_ #_ #K #W #H destruct
  41 | #lv1 #lv2 #L #_ #Hlv12 #IH #K #W #H destruct
  42   elim IH -IH [|*: // ] #lv #d #HK #HW #Hlv
  43   /3 width=5 by exteq_trans, ex3_2_intro/
  44 ]
  45 qed-.
  46
  47 lemma li_inv_abbr (M) (gv): ∀v,L,V. v ϵ ⟦L.ⓓV⟧{M}[gv] →
  48                             ∃∃lv,d. lv ϵ ⟦L⟧{M}[gv] & ⟦V⟧{M}[gv, lv] ≗ d & ⫯{M}[d]lv ≐ v.
  49 /2 width=3 by li_inv_abbr_aux/ qed-.
  50
  51 fact li_inv_abst_aux (M) (gv): ∀v,Y. v ϵ ⟦Y⟧{M}[gv] → ∀L,W. Y = L.ⓛW →
  52                                ∃∃lv,d. lv ϵ ⟦L⟧{M}[gv] & ⫯{M}[d]lv ≐ v.
  53 #M #gv #v #Y #H elim H -v -Y
  54 [ #lv #K #U #H destruct
  55 | #lv #d #L #V #_ #_ #_ #K #U #H destruct
  56 | #lv #d #L #V #HL #_ #K #U #H destruct /2 width=4 by ex2_2_intro/
  57 | #lv #d #I #L #_ #_ #K #U #H destruct
  58 | #lv1 #lv2 #L #_ #Hlv12 #IH #K #U #H destruct
  59   elim IH -IH [|*: // ] #lv #d #HK #Hlv
  60   /3 width=4 by exteq_trans, ex2_2_intro/
  61 ]
  62 qed-.
  63
  64 lemma li_inv_abst (M) (gv): ∀v,L,W. v ϵ ⟦L.ⓛW⟧{M}[gv] →
  65                             ∃∃lv,d. lv ϵ ⟦L⟧{M}[gv] & ⫯{M}[d]lv ≐ v.
  66 /2 width=4 by li_inv_abst_aux/ qed-.
  67
  68 fact li_inv_unit_aux (M) (gv): ∀v,Y. v ϵ ⟦Y⟧{M}[gv] → ∀I,L. Y = L.ⓤ{I} →
  69                                ∃∃lv,d. lv ϵ ⟦L⟧{M}[gv] & ⫯{M}[d]lv ≐ v.
  70 #M #gv #v #Y #H elim H -v -Y
  71 [ #lv #J #K #H destruct
  72 | #lv #d #L #V #_ #_ #_ #J #K #H destruct
  73 | #lv #d #L #V #_ #_ #J #K #H destruct
  74 | #lv #d #I #L #HL #_ #J #K #H destruct /2 width=4 by ex2_2_intro/
  75 | #lv1 #lv2 #L #_ #Hlv12 #IH #J #K #H destruct
  76   elim IH -IH [|*: // ] #lv #d #HK #Hlv
  77   /3 width=4 by exteq_trans, ex2_2_intro/
  78 ]
  79 qed-.
  80
  81 lemma li_inv_unit (M) (gv): ∀v,I,L. v ϵ ⟦L.ⓤ{I}⟧{M}[gv] →
  82                             ∃∃lv,d. lv ϵ ⟦L⟧{M}[gv] & ⫯{M}[d]lv ≐ v.
  83 /2 width=4 by li_inv_unit_aux/ qed-.
  84
  85 (* Advanced forward lemmas **************************************************)
  86
  87 lemma li_fwd_bind (M) (gv): ∀v,I,L. v ϵ ⟦L.ⓘ{I}⟧{M}[gv] →
  88                             ∃∃lv,d. lv ϵ ⟦L⟧{M}[gv] & ⫯{M}[d]lv ≐ v.
  89 #m #gv #v * [ #I | * #V ] #L #H
  90 [ @(li_inv_unit … H)
  91 | elim (li_inv_abbr … H) -H #lv #d #Hl #_ #Hv
  92   /2 width=4 by ex2_2_intro/
  93 | @(li_inv_abst … H)
  94 ]
  95 qed-.