matita/matita/contribs/lambdadelta/apps_2/models/model_vlift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/lib/functions.ma".
  16 include "ground_2/lib/exteq.ma".
  17 include "apps_2/notation/models/upspoon_4.ma".
  18 include "apps_2/notation/models/upspoon_3.ma".
  19 include "apps_2/models/model.ma".
  20
  21
  22 (* MODEL ********************************************************************)
  23
  24 definition vlift (M): nat → dd M → evaluation M → evaluation M ≝
  25                       λj,d,lv,i. tri … i j (lv i) d (lv (↓i)).
  26
  27 interpretation "generic lift (model evaluation)"
  28    'UpSpoon M i d lv = (vlift M i d lv).
  29
  30 interpretation "lift (model evaluation)"
  31    'UpSpoon M d lv = (vlift M O d lv).
  32
  33 (* Basic properties *********************************************************)
  34
  35 lemma vlift_lt (M): ∀lv,d,j,i. i < j → (⫯{M}[j←d] lv) i = lv i.
  36 /2 width=1 by tri_lt/ qed-.
  37
  38 lemma vlift_eq (M): ∀lv,d,i. (⫯{M}[i←d] lv) i = d.
  39 /2 width=1 by tri_eq/ qed-.
  40
  41 lemma vlift_gt (M): ∀lv,d,j,i. j < i → (⫯{M}[j←d] lv) i = lv (↓i).
  42 /2 width=1 by tri_gt/ qed-.
  43
  44 lemma vlift_ext (M): ∀i. compatible_3 … (vlift M i) (eq …) (exteq …) (exteq …).
  45 #m #i #d1 #d2 #Hd12 #lv1 #lv2 #HLv12 #j
  46 elim (lt_or_eq_or_gt j i) #Hij destruct
  47 [ >vlift_lt // >vlift_lt //
  48 | >vlift_eq >vlift_eq //
  49 | >vlift_gt // >vlift_gt //
  50 ]
  51 qed.