matita/matita/contribs/lambdadelta/apps_2/models/tm.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_equivalence/cpcs.ma".
  16 include "apps_2/functional/flifts_basic.ma".
  17 include "apps_2/models/model.ma".
  18 include "apps_2/notation/models/dotteduparrow_2.ma".
  19 include "apps_2/notation/models/dotteduparrow_3.ma".
  20
  21 (* TERM MODEL ***************************************************************)
  22
  23 definition tm_dd ≝ term.
  24
  25 definition tm_evaluation ≝ nat → tm_dd.
  26
  27 definition tm_sq (h) (T1) (T2) ≝  ⦃⋆, ⋆⦄ ⊢ T1 ⬌*[h] T2.
  28
  29 definition tm_sv (s) ≝ ⋆s.
  30
  31 definition tm_ap (V) (T) ≝ ⓐV.T.
  32
  33 definition tm_vlift (j) (gv): tm_evaluation ≝ λi. ↑[j,1](gv i).
  34
  35 interpretation "lift (term model evaluation)"
  36   'DottedUpArrow i gv = (tm_vlift i gv).
  37
  38 definition tm_vpush (j) (T) (lv): tm_evaluation ≝
  39                     λi. tri … i j (lv i) T (↑[j,1](lv (↓i))).
  40
  41 interpretation "push (term model evaluation)"
  42   'DottedUpArrow i d lv = (tm_vpush i d lv).
  43
  44 rec definition tm_ti gv lv T on T ≝ match T with
  45 [ TAtom I     ⇒ match I with
  46   [ Sort _ ⇒ T
  47   | LRef i ⇒ lv i
  48   | GRef l ⇒ gv l
  49   ]
  50 | TPair I V T ⇒ match I with
  51   [ Bind2 _ _ ⇒ TPair I (tm_ti gv lv V) (tm_ti (⇡[0]gv) (⇡[0←#0]lv) T)
  52   | Flat2 _   ⇒ TPair I (tm_ti gv lv V) (tm_ti gv lv T)
  53   ]
  54 ].
  55
  56 definition tm_lc: tm_evaluation ≝ λi.#i.
  57
  58 definition tm_gc: tm_evaluation ≝ λl.§l.
  59
  60 definition TM (h): model ≝ mk_model … .
  61 [ @tm_dd
  62 | @(tm_sq h) |6,7: skip
  63 | @tm_sv
  64 | @tm_ap
  65 | @tm_ti
  66 ].
  67 defined-.
  68
  69 (* Basic properties *********************************************************)
  70
  71 lemma tm_vlift_rw (j) (gv): ∀i. (⇡[j]gv) i = ↑[j,1](gv i).
  72 // qed.
  73
  74 lemma tm_vpush_lt (lv) (j) (T): ∀i. i < j → (⇡[j←T]lv) i = lv i.
  75 /2 width=1 by tri_lt/ qed-.
  76
  77 lemma tm_vpush_eq: ∀lv,T,i. (⇡[i←T]lv) i = T.
  78 /2 width=1 by tri_eq/ qed.
  79
  80 lemma tm_vpush_gt: ∀lv,T,j,i. j < i → (⇡[j←T]lv) i = ↑[j,1](lv (↓i)).
  81 /2 width=1 by tri_gt/ qed-.
  82
  83 lemma tm_ti_lref (h): ∀gv,lv,i. ⟦#i⟧{TM h}[gv,lv] = lv i.
  84 // qed.
  85
  86 lemma tm_ti_gref (h): ∀gv,lv,l. ⟦§l⟧{TM h}[gv,lv] = gv l.
  87 // qed.
  88
  89 lemma tm_ti_bind (h) (p) (I): ∀gv,lv,V,T.
  90                               ⟦ⓑ{p,I}V.T⟧{TM h}[gv,lv] = ⓑ{p,I}⟦V⟧[gv,lv].⟦T⟧{TM h}[⇡[0]gv,⇡[0←#0]lv].
  91 // qed.