matita/matita/contribs/lambdadelta/basic_2/computation/acp.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/ldrops.ma".
  16
  17 (* ABSTRACT COMPUTATION PROPERTIES ******************************************)
  18
  19 definition CP1 ≝ λRR:lenv→relation term. λRS:relation term.
  20                  ∀L. ∃k. NF … (RR L) RS (⋆k).
  21
  22 definition CP2 ≝ λRR:lenv→relation term. λRS:relation term.
  23                  ∀L0,L,T,T0,d,e. NF … (RR L) RS T →
  24                  ⇩[d, e] L0 ≡ L → ⇧[d, e] T ≡ T0 → NF … (RR L0) RS T0.
  25
  26 definition CP2s ≝ λRR:lenv→relation term. λRS:relation term.
  27                   ∀L0,L,des. ⇩*[des] L0 ≡ L →
  28                   ∀T,T0. ⇧*[des] T ≡ T0 →
  29                   NF … (RR L) RS T → NF … (RR L0) RS T0.
  30
  31 definition CP3 ≝ λRP:lenv→predicate term.
  32                  ∀L,T,k. RP L (ⓐ⋆k.T) → RP L T.
  33
  34 definition CP4 ≝ λRP:lenv→predicate term.
  35                  ∀L,W,T. RP L W → RP L T → RP L (ⓝW.T).
  36
  37 (* requirements for abstract computation properties *)
  38 record acp (RR:lenv->relation term) (RS:relation term) (RP:lenv→predicate term) : Prop ≝
  39 { cp1: CP1 RR RS;
  40   cp2: CP2 RR RS;
  41   cp3: CP3 RP;
  42   cp4: CP4 RP
  43 }.
  44
  45 (* Basic properties *********************************************************)
  46
  47 (* Basic_1: was: nf2_lift1 *)
  48 lemma acp_lifts: ∀RR,RS. CP2 RR RS → CP2s RR RS.
  49 #RR #RS #HRR #L1 #L2 #des #H elim H -L1 -L2 -des
  50 [ #L #T1 #T2 #H #HT1
  51   <(lifts_inv_nil … H) -H //
  52 | #L1 #L #L2 #des #d #e #_ #HL2 #IHL #T2 #T1 #H #HLT2
  53   elim (lifts_inv_cons … H) -H /3 width=9/
  54 ]
  55 qed.