matita/matita/contribs/lambdadelta/basic_2/computation/acp_aaa.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/lifts_lifts.ma".
  16 include "basic_2/substitution/ldrops_ldrops.ma".
  17 include "basic_2/static/aaa_lifts.ma".
  18 include "basic_2/static/aaa_aaa.ma".
  19 include "basic_2/computation/lsubc_ldrops.ma".
  20
  21 (* ABSTRACT COMPUTATION PROPERTIES ******************************************)
  22
  23 (* Main propertis ***********************************************************)
  24
  25 (* Basic_1: was: sc3_arity_csubc *)
  26 theorem aacr_aaa_csubc_lifts: ∀RR,RS,RP.
  27                               acp RR RS RP → acr RR RS RP (λL,T. RP L T) →
  28                               ∀L1,T,A. L1 ⊢ T ⁝ A → ∀L0,des. ⇩*[des] L0 ≡ L1 →
  29                               ∀T0. ⇧*[des] T ≡ T0 → ∀L2. L2 ⊑[RP] L0 →
  30                               ⦃L2, T0⦄ ϵ[RP] 〚A〛.
  31 #RR #RS #RP #H1RP #H2RP #L1 #T #A #H elim H -L1 -T -A
  32 [ #L #k #L0 #des #HL0 #X #H #L2 #HL20
  33   >(lifts_inv_sort1 … H) -H
  34   lapply (aacr_acr … H1RP H2RP (⓪)) #HAtom
  35   @(s4 … HAtom … ◊) //
  36 | #I #L1 #K1 #V1 #B #i #HLK1 #HKV1B #IHB #L0 #des #HL01 #X #H #L2 #HL20
  37   lapply (aacr_acr … H1RP H2RP B) #HB
  38   elim (lifts_inv_lref1 … H) -H #i1 #Hi1 #H destruct
  39   lapply (ldrop_fwd_ldrop2 … HLK1) #HK1b
  40   elim (ldrops_ldrop_trans … HL01 … HLK1) #X #des1 #i0 #HL0 #H #Hi0 #Hdes1
  41   >(at_mono … Hi1 … Hi0) -i1
  42   elim (ldrops_inv_skip2 … Hdes1 … H) -des1 #K0 #V0 #des0 #Hdes0 #HK01 #HV10 #H destruct
  43   elim (lsubc_ldrop_O1_trans … HL20 … HL0) -HL0 #X #HLK2 #H
  44   elim (lsubc_inv_pair2 … H) -H *
  45   [ #K2 #HK20 #H destruct
  46     elim (lift_total V0 0 (i0 +1)) #V #HV0
  47     elim (lifts_lift_trans  … Hi0 … Hdes0 … HV10 … HV0) -HV10 #V2 #HV12 #HV2
  48     @(s5 … HB … ◊ … HV0 HLK2) /3 width=7/ (* uses IHB HL20 V2 HV0 *)
  49   | -HLK1 -IHB -HL01 -HL20 -HK1b -Hi0 -Hdes0
  50     #K2 #V2 #A2 #HKV2A #H1KV0A #H2KV0A #_ #H1 #H2 destruct
  51     lapply (ldrop_fwd_ldrop2 … HLK2) #HLK2b
  52     lapply (aaa_lifts … HK01 … HV10 HKV1B) -HKV1B -HK01 -HV10 #HKV0B
  53     lapply (aaa_mono … H2KV0A … HKV0B) #H destruct -H2KV0A -HKV0B
  54     elim (lift_total V0 0 (i0 +1)) #V3 #HV03
  55     elim (lift_total V2 0 (i0 +1)) #V #HV2
  56     @(s5 … HB … ◊ … (ⓝV3.V) … HLK2) [2: /2 width=1/ ]
  57     @(s7 … HB … ◊) [ @(s8 … HB … HKV2A) // | @(s8 … HB … H1KV0A) // ]
  58   ]
  59 | #a #L #V #T #B #A #_ #_ #IHB #IHA #L0 #des #HL0 #X #H #L2 #HL20
  60   elim (lifts_inv_bind1 … H) -H #V0 #T0 #HV0 #HT0 #H destruct
  61   lapply (aacr_acr … H1RP H2RP A) #HA
  62   lapply (aacr_acr … H1RP H2RP B) #HB
  63   lapply (s1 … HB) -HB #HB
  64   @(s6 … HA … ◊ ◊) // /3 width=5/
  65 | #a #L #W #T #B #A #HLWB #_ #IHB #IHA #L0 #des #HL0 #X #H #L2 #HL02
  66   elim (lifts_inv_bind1 … H) -H #W0 #T0 #HW0 #HT0 #H destruct
  67   @(aacr_abst  … H1RP H2RP) [ /2 width=5/ ]
  68   #L3 #V3 #W3 #T3 #des3 #HL32 #HW03 #HT03 #H1B #H2B
  69   elim (ldrops_lsubc_trans … H1RP H2RP … HL32 … HL02) -L2 #L2 #HL32 #HL20
  70   lapply (aaa_lifts … L2 W3 … (des @@ des3) … HLWB) -HLWB /2 width=3/ #HLW2B
  71   @(IHA (L2. ⓛW3) … (des + 1 @@ des3 + 1)) -IHA /2 width=3/ /3 width=5/
  72 | #L #V #T #B #A #_ #_ #IHB #IHA #L0 #des #HL0 #X #H #L2 #HL20
  73   elim (lifts_inv_flat1 … H) -H #V0 #T0 #HV0 #HT0 #H destruct
  74   /3 width=10/
  75 | #L #V #T #A #_ #_ #IH1A #IH2A #L0 #des #HL0 #X #H #L2 #HL20
  76   elim (lifts_inv_flat1 … H) -H #V0 #T0 #HV0 #HT0 #H destruct
  77   lapply (aacr_acr … H1RP H2RP A) #HA
  78   @(s7 … HA … ◊) /2 width=5/
  79 ]
  80 qed.
  81
  82 (* Basic_1: was: sc3_arity *)
  83 lemma aacr_aaa: ∀RR,RS,RP. acp RR RS RP → acr RR RS RP (λL,T. RP L T) →
  84                 ∀L,T,A. ⦃G, L⦄ ⊢ T ⁝ A → ⦃L, T⦄ ϵ[RP] 〚A〛.
  85 /2 width=8/ qed.
  86
  87 lemma acp_aaa: ∀RR,RS,RP. acp RR RS RP → acr RR RS RP (λL,T. RP L T) →
  88                ∀L,T,A. ⦃G, L⦄ ⊢ T ⁝ A → RP L T.
  89 #RR #RS #RP #H1RP #H2RP #L #T #A #HT
  90 lapply (aacr_acr … H1RP H2RP A) #HA
  91 @(s1 … HA) /2 width=4/
  92 qed.