matita/matita/contribs/lambdadelta/basic_2/computation/acp_cr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/ineint_5.ma".
  16 include "basic_2/grammar/aarity.ma".
  17 include "basic_2/multiple/gr2_gr2.ma".
  18 include "basic_2/multiple/lifts_lift_vector.ma".
  19 include "basic_2/multiple/drops_drop.ma".
  20 include "basic_2/computation/acp.ma".
  21
  22 (* ABSTRACT COMPUTATION PROPERTIES ******************************************)
  23
  24 definition S0 ≝ λC:relation3 genv lenv term. ∀G,L2,L1,T1,d,e.
  25                 C G L1 T1 → ∀T2. ⇩[Ⓕ, d, e] L2 ≡ L1 → ⇧[d, e] T1 ≡ T2 → C G L2 T2.
  26
  27 definition S0s ≝ λC:relation3 genv lenv term.
  28                  ∀G,L1,L2,des. ⇩*[Ⓕ, des] L2 ≡ L1 →
  29                  ∀T1,T2. ⇧*[des] T1 ≡ T2 → C G L1 T1 → C G L2 T2.
  30
  31 (* Note: this is Girard's CR1 *)
  32 definition S1 ≝ λRP,C:relation3 genv lenv term.
  33                 ∀G,L,T. C G L T → RP G L T.
  34
  35 (* Note: this is Tait's iii, or Girard's CR4 *)
  36 definition S2 ≝ λRR:relation4 genv lenv term term. λRS:relation term. λRP,C:relation3 genv lenv term.
  37                 ∀G,L,Vs. all … (RP G L) Vs →
  38                 ∀T. 𝐒⦃T⦄ → NF … (RR G L) RS T → C G L (ⒶVs.T).
  39
  40 (* Note: this generalizes Tait's ii *)
  41 definition S3 ≝ λC:relation3 genv lenv term.
  42                 ∀a,G,L,Vs,V,T,W.
  43                 C G L (ⒶVs.ⓓ{a}ⓝW.V.T) → C G L (ⒶVs.ⓐV.ⓛ{a}W.T).
  44
  45 definition S4 ≝ λRP,C:relation3 genv lenv term.
  46                 ∀G,L,Vs. all … (RP G L) Vs → ∀k. C G L (ⒶVs.⋆k).
  47
  48 definition S5 ≝ λC:relation3 genv lenv term. ∀I,G,L,K,Vs,V1,V2,i.
  49                 C G L (ⒶVs.V2) → ⇧[0, i+1] V1 ≡ V2 →
  50                 ⇩[i] L ≡ K.ⓑ{I}V1 → C G L (ⒶVs.#i).
  51
  52 definition S6 ≝ λRP,C:relation3 genv lenv term.
  53                 ∀G,L,V1s,V2s. ⇧[0, 1] V1s ≡ V2s →
  54                 ∀a,V,T. C G (L.ⓓV) (ⒶV2s.T) → RP G L V → C G L (ⒶV1s.ⓓ{a}V.T).
  55
  56 definition S7 ≝ λC:relation3 genv lenv term.
  57                 ∀G,L,Vs,T,W. C G L (ⒶVs.T) → C G L (ⒶVs.W) → C G L (ⒶVs.ⓝW.T).
  58
  59 (* properties of the abstract candidate of reducibility *)
  60 record acr (RR:relation4 genv lenv term term) (RS:relation term) (RP,C:relation3 genv lenv term) : Prop ≝
  61 { s0: S0 C;
  62   s1: S1 RP C;
  63   s2: S2 RR RS RP C;
  64   s3: S3 C;
  65   s4: S4 RP C;
  66   s5: S5 C;
  67   s6: S6 RP C;
  68   s7: S7 C
  69 }.
  70
  71 (* the abstract candidate of reducibility associated to an atomic arity *)
  72 let rec aacr (RP:relation3 genv lenv term) (A:aarity) (G:genv) (L:lenv) on A: predicate term ≝
  73 λT. match A with
  74 [ AAtom     ⇒ RP G L T
  75 | APair B A ⇒ ∀L0,V0,T0,des.
  76               aacr RP B G L0 V0 → ⇩*[Ⓕ, des] L0 ≡ L → ⇧*[des] T ≡ T0 →
  77               aacr RP A G L0 (ⓐV0.T0)
  78 ].
  79
  80 interpretation
  81    "candidate of reducibility of an atomic arity (abstract)"
  82    'InEInt RP G L T A = (aacr RP A G L T).
  83
  84 (* Basic properties *********************************************************)
  85
  86 (* Basic_1: was: sc3_lift1 *)
  87 lemma acr_lifts: ∀C. S0 C → S0s C.
  88 #C #HC #G #L1 #L2 #des #H elim H -L1 -L2 -des
  89 [ #L #T1 #T2 #H #HT1 <(lifts_inv_nil … H) -H //
  90 | #L1 #L #L2 #des #d #e #_ #HL2 #IHL #T2 #T1 #H #HLT2
  91   elim (lifts_inv_cons … H) -H /3 width=10 by/
  92 ]
  93 qed.
  94
  95 lemma rp_lifts: ∀RR,RS,RP. acr RR RS RP (λG,L,T. RP G L T) →
  96                 ∀des,G,L0,L,V,V0. ⇩*[Ⓕ, des] L0 ≡ L → ⇧*[des] V ≡ V0 →
  97                 RP G L V → RP G L0 V0.
  98 #RR #RS #RP #HRP #des #G #L0 #L #V #V0 #HL0 #HV0 #HV
  99 @acr_lifts /width=7 by/
 100 @(s0 … HRP)
 101 qed.
 102
 103 (* Basic_1: was only: sns3_lifts1 *)
 104 lemma rp_liftsv_all: ∀RR,RS,RP. acr RR RS RP (λG,L,T. RP G L T) →
 105                      ∀des,G,L0,L,Vs,V0s. ⇩*[Ⓕ, des] L0 ≡ L → ⇧*[des] Vs ≡ V0s →
 106                      all … (RP G L) Vs → all … (RP G L0) V0s.
 107 #RR #RS #RP #HRP #des #G #L0 #L #Vs #V0s #HL0 #H elim H -Vs -V0s normalize //
 108 #T1s #T2s #T1 #T2 #HT12 #_ #IHT2s * /3 width=7 by rp_lifts, conj/
 109 qed.
 110
 111 (* Basic_1: was:
 112    sc3_sn3 sc3_abst sc3_appl sc3_abbr sc3_bind sc3_cast sc3_lift
 113 *)
 114 lemma aacr_acr: ∀RR,RS,RP. acp RR RS RP → acr RR RS RP (λG,L,T. RP G L T) →
 115                 ∀A. acr RR RS RP (aacr RP A).
 116 #RR #RS #RP #H1RP #H2RP #A elim A -A normalize //
 117 #B #A #IHB #IHA @mk_acr normalize
 118 [ /3 width=7 by drops_cons, lifts_cons/
 119 | #G #L #T #H
 120   elim (cp1 … H1RP G L) #k #HK
 121   lapply (H ? (⋆k) ? (⟠) ? ? ?) -H
 122   [1,3: // |2,4: skip
 123   | @(s2 … IHB … (◊)) //
 124   | #H @(cp2 … H1RP … k) @(s1 … IHA) //
 125   ]
 126 | #G #L #Vs #HVs #T #H1T #H2T #L0 #V0 #X #des #HB #HL0 #H
 127   elim (lifts_inv_applv1 … H) -H #V0s #T0 #HV0s #HT0 #H destruct
 128   lapply (s1 … IHB … HB) #HV0
 129   @(s2 … IHA … (V0 @ V0s))
 130   /3 width=14 by rp_liftsv_all, acp_lifts, cp0, lifts_simple_dx, conj/
 131 | #a #G #L #Vs #U #T #W #HA #L0 #V0 #X #des #HB #HL0 #H
 132   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 133   elim (lifts_inv_flat1 … HY) -HY #U0 #X #HU0 #HX #H destruct
 134   elim (lifts_inv_bind1 … HX) -HX #W0 #T0 #HW0 #HT0 #H destruct
 135   @(s3 … IHA … (V0 @ V0s)) /5 width=6 by lifts_applv, lifts_flat, lifts_bind/
 136 | #G #L #Vs #HVs #k #L0 #V0 #X #des #HB #HL0 #H
 137   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 138   >(lifts_inv_sort1 … HY) -Y
 139   lapply (s1 … IHB … HB) #HV0
 140   @(s4 … IHA … (V0 @ V0s)) /3 width=7 by rp_liftsv_all, conj/
 141 | #I #G #L #K #Vs #V1 #V2 #i #HA #HV12 #HLK #L0 #V0 #X #des #HB #HL0 #H
 142   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 143   elim (lifts_inv_lref1 … HY) -HY #i0 #Hi0 #H destruct
 144   elim (drops_drop_trans … HL0 … HLK) #X #des0 #i1 #HL02 #H #Hi1 #Hdes0
 145   >(at_mono … Hi1 … Hi0) in HL02; -i1 #HL02
 146   elim (drops_inv_skip2 … Hdes0 … H) -H -des0 #L2 #W1 #des0 #Hdes0 #HLK #HVW1 #H destruct
 147   elim (lift_total W1 0 (i0 + 1)) #W2 #HW12
 148   elim (lifts_lift_trans  … Hdes0 … HVW1 … HW12) // -Hdes0 -Hi0 #V3 #HV13 #HVW2
 149   >(lift_mono … HV13 … HV12) in HVW2; -V3 #HVW2
 150   @(s5 … IHA … (V0 @ V0s) … HW12 HL02) /3 width=5 by lifts_applv/
 151 | #G #L #V1s #V2s #HV12s #a #V #T #HA #HV #L0 #V10 #X #des #HB #HL0 #H
 152   elim (lifts_inv_applv1 … H) -H #V10s #Y #HV10s #HY #H destruct
 153   elim (lifts_inv_bind1 … HY) -HY #V0 #T0 #HV0 #HT0 #H destruct
 154   elim (lift_total V10 0 1) #V20 #HV120
 155   elim (liftv_total 0 1 V10s) #V20s #HV120s
 156   @(s6 … IHA … (V10 @ V10s) (V20 @ V20s)) /3 width=7 by rp_lifts, liftv_cons/
 157   @(HA … (des + 1)) /2 width=2 by drops_skip/
 158   [ @(s0 … IHB … HB … HV120) /2 width=2 by drop_drop/
 159   | @lifts_applv //
 160     elim (liftsv_liftv_trans_le … HV10s … HV120s) -V10s #V10s #HV10s #HV120s
 161     >(liftv_mono … HV12s … HV10s) -V1s //
 162   ]
 163 | #G #L #Vs #T #W #HA #HW #L0 #V0 #X #des #HB #HL0 #H
 164   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 165   elim (lifts_inv_flat1 … HY) -HY #W0 #T0 #HW0 #HT0 #H destruct
 166   @(s7 … IHA … (V0 @ V0s)) /3 width=5 by lifts_applv/
 167 ]
 168 qed.
 169
 170 lemma aacr_abst: ∀RR,RS,RP. acp RR RS RP → acr RR RS RP (λG,L,T. RP G L T) →
 171                  ∀a,G,L,W,T,A,B. ⦃G, L, W⦄ ϵ[RP] 〚B〛 → (
 172                     ∀L0,V0,W0,T0,des. ⇩*[Ⓕ, des] L0 ≡ L → ⇧*[des ] W ≡ W0 → ⇧*[des + 1] T ≡ T0 →
 173                                    ⦃G, L0, V0⦄ ϵ[RP] 〚B〛 → ⦃G, L0, W0⦄ ϵ[RP] 〚B〛 → ⦃G, L0.ⓓⓝW0.V0, T0⦄ ϵ[RP] 〚A〛
 174                  ) →
 175                  ⦃G, L, ⓛ{a}W.T⦄ ϵ[RP] 〚②B.A〛.
 176 #RR #RS #RP #H1RP #H2RP #a #G #L #W #T #A #B #HW #HA #L0 #V0 #X #des #HB #HL0 #H
 177 lapply (aacr_acr … H1RP H2RP A) #HCA
 178 lapply (aacr_acr … H1RP H2RP B) #HCB
 179 elim (lifts_inv_bind1 … H) -H #W0 #T0 #HW0 #HT0 #H destruct
 180 lapply (acr_lifts … HL0 … HW0 HW) -HW [ @(s0 … HCB) ] #HW0
 181 @(s3 … HCA … (◊))
 182 @(s6 … HCA … (◊) (◊)) //
 183 [ @(HA … HL0) //
 184 | lapply (s1 … HCB) -HCB #HCB
 185   @(cp3 … H1RP) /2 width=1 by/
 186 ]
 187 qed.
 188
 189 (* Basic_1: removed theorems 2: sc3_arity_gen sc3_repl *)
 190 (* Basic_1: removed local theorems 1: sc3_sn3_abst *)