matita/matita/contribs/lambdadelta/basic_2/computation/acp_cr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/aarity.ma".
  16 include "basic_2/substitution/gr2_gr2.ma".
  17 include "basic_2/substitution/lifts_lift_vector.ma".
  18 include "basic_2/substitution/ldrops_ldrop.ma".
  19 include "basic_2/computation/acp.ma".
  20
  21 (* ABSTRACT COMPUTATION PROPERTIES ******************************************)
  22
  23 (* Note: this is Girard's CR1 *)
  24 definition S1 ≝ λRP,C:lenv→predicate term.
  25                 ∀L,T. C L T → RP L T.
  26
  27 (* Note: this is Tait's iii, or Girard's CR4 *)
  28 definition S2 ≝ λRR:lenv→relation term. λRS:relation term. λRP,C:lenv→predicate term.
  29                 ∀L,Vs. all … (RP L) Vs →
  30                 ∀T. 𝐒⦃T⦄ → NF … (RR L) RS T → C L (ⒶVs.T).
  31
  32 (* Note: this generalizes Tait's ii *)
  33 definition S3 ≝ λC:lenv→predicate term.
  34                 ∀a,L,Vs,V,T,W. C L (ⒶVs.ⓓ{a}ⓝW.V.T) → C L (ⒶVs.ⓐV.ⓛ{a}W.T).
  35
  36 definition S4 ≝ λRP,C:lenv→predicate term.
  37                 ∀L,Vs. all … (RP L) Vs → ∀k. C L (ⒶVs.⋆k).
  38
  39 definition S5 ≝ λC:lenv→predicate term. ∀I,L,K,Vs,V1,V2,i.
  40                 C L (ⒶVs.V2) → ⇧[0, i + 1] V1 ≡ V2 →
  41                 ⇩[0, i] L ≡ K.ⓑ{I}V1 → C L (Ⓐ Vs.#i).
  42
  43 definition S6 ≝ λRP,C:lenv→predicate term.
  44                 ∀L,V1s,V2s. ⇧[0, 1] V1s ≡ V2s →
  45                 ∀a,V,T. C (L.ⓓV) (ⒶV2s.T) → RP L V → C L (ⒶV1s.ⓓ{a}V.T).
  46
  47 definition S7 ≝ λC:lenv→predicate term.
  48                 ∀L,Vs,T,W. C L (ⒶVs.T) → C L (ⒶVs.W) → C L (ⒶVs.ⓝW.T).
  49
  50 definition S8 ≝ λC:lenv→predicate term. ∀L2,L1,T1,d,e.
  51                 C L1 T1 → ∀T2. ⇩[d, e] L2 ≡ L1 → ⇧[d, e] T1 ≡ T2 → C L2 T2.
  52
  53 definition S8s ≝ λC:lenv→predicate term.
  54                  ∀L1,L2,des. ⇩*[des] L2 ≡ L1 →
  55                  ∀T1,T2. ⇧*[des] T1 ≡ T2 → C L1 T1 → C L2 T2.
  56
  57 (* properties of the abstract candidate of reducibility *)
  58 record acr (RR:lenv->relation term) (RS:relation term) (RP,C:lenv→predicate term) : Prop ≝
  59 { s1: S1 RP C;
  60   s2: S2 RR RS RP C;
  61   s3: S3 C;
  62   s4: S4 RP C;
  63   s5: S5 C;
  64   s6: S6 RP C;
  65   s7: S7 C;
  66   s8: S8 C
  67 }.
  68
  69 (* the abstract candidate of reducibility associated to an atomic arity *)
  70 let rec aacr (RP:lenv→predicate term) (A:aarity) (L:lenv) on A: predicate term ≝
  71 λT. match A with
  72 [ AAtom     ⇒ RP L T
  73 | APair B A ⇒ ∀L0,V0,T0,des. aacr RP B L0 V0 → ⇩*[des] L0 ≡ L → ⇧*[des] T ≡ T0 →
  74               aacr RP A L0 (ⓐV0.T0)
  75 ].
  76
  77 interpretation
  78    "candidate of reducibility of an atomic arity (abstract)"
  79    'InEInt RP L T A = (aacr RP A L T).
  80
  81 (* Basic properties *********************************************************)
  82
  83 (* Basic_1: was: sc3_lift1 *)
  84 lemma acr_lifts: ∀C. S8 C → S8s C.
  85 #C #HC #L1 #L2 #des #H elim H -L1 -L2 -des
  86 [ #L #T1 #T2 #H #HT1
  87   <(lifts_inv_nil … H) -H //
  88 | #L1 #L #L2 #des #d #e #_ #HL2 #IHL #T2 #T1 #H #HLT2
  89   elim (lifts_inv_cons … H) -H /3 width=9/
  90 ]
  91 qed.
  92
  93 lemma rp_lifts: ∀RR,RS,RP. acr RR RS RP (λL,T. RP L T) →
  94                 ∀des,L0,L,V,V0. ⇩*[des] L0 ≡ L → ⇧*[des] V ≡ V0 →
  95                 RP L V → RP L0 V0.
  96 #RR #RS #RP #HRP #des #L0 #L #V #V0 #HL0 #HV0 #HV
  97 @acr_lifts /width=6/
  98 @(s8 … HRP)
  99 qed.
 100
 101 (* Basic_1: was only: sns3_lifts1 *)
 102 lemma rp_liftsv_all: ∀RR,RS,RP. acr RR RS RP (λL,T. RP L T) →
 103                      ∀des,L0,L,Vs,V0s. ⇧*[des] Vs ≡ V0s → ⇩*[des] L0 ≡ L →
 104                      all … (RP L) Vs → all … (RP L0) V0s.
 105 #RR #RS #RP #HRP #des #L0 #L #Vs #V0s #H elim H -Vs -V0s normalize //
 106 #T1s #T2s #T1 #T2 #HT12 #_ #IHT2s #HL0 * #HT1 #HT1s
 107 @conj /2 width=1/ /2 width=6 by rp_lifts/
 108 qed.
 109
 110 (* Basic_1: was:
 111    sc3_sn3 sc3_abst sc3_appl sc3_abbr sc3_bind sc3_cast sc3_lift
 112 *)
 113 lemma aacr_acr: ∀RR,RS,RP. acp RR RS RP → acr RR RS RP (λL,T. RP L T) →
 114                 ∀A. acr RR RS RP (aacr RP A).
 115 #RR #RS #RP #H1RP #H2RP #A elim A -A normalize //
 116 #B #A #IHB #IHA @mk_acr normalize
 117 [ #L #T #H
 118   elim (cp1 … H1RP L) #k #HK
 119   lapply (H ? (⋆k) ? ⟠ ? ? ?) -H
 120   [1,3: // |2,4: skip
 121   | @(s2 … IHB … ◊) //
 122   | #H @(cp3 … H1RP … k) @(s1 … IHA) //
 123   ]
 124 | #L #Vs #HVs #T #H1T #H2T #L0 #V0 #X #des #HB #HL0 #H
 125   elim (lifts_inv_applv1 … H) -H #V0s #T0 #HV0s #HT0 #H destruct
 126   lapply (s1 … IHB … HB) #HV0
 127   @(s2 … IHA … (V0 @ V0s)) /2 width=4 by lifts_simple_dx/ /3 width=6/
 128 | #a #L #Vs #U #T #W #HA #L0 #V0 #X #des #HB #HL0 #H
 129   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 130   elim (lifts_inv_flat1 … HY) -HY #U0 #X #HU0 #HX #H destruct
 131   elim (lifts_inv_bind1 … HX) -HX #W0 #T0 #HW0 #HT0 #H destruct
 132   @(s3 … IHA … (V0 @ V0s)) /5 width=5/
 133 | #L #Vs #HVs #k #L0 #V0 #X #hdes #HB #HL0 #H
 134   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 135   >(lifts_inv_sort1 … HY) -Y
 136   lapply (s1 … IHB … HB) #HV0
 137   @(s4 … IHA … (V0 @ V0s)) /3 width=6/
 138 | #I #L #K #Vs #V1 #V2 #i #HA #HV12 #HLK #L0 #V0 #X #des #HB #HL0 #H
 139   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 140   elim (lifts_inv_lref1 … HY) -HY #i0 #Hi0 #H destruct
 141   elim (ldrops_ldrop_trans … HL0 … HLK) #X #des0 #i1 #HL02 #H #Hi1 #Hdes0
 142   >(at_mono … Hi1 … Hi0) in HL02; -i1 #HL02
 143   elim (ldrops_inv_skip2 … Hdes0 … H) -H -des0 #L2 #W1 #des0 #Hdes0 #HLK #HVW1 #H destruct
 144   elim (lift_total W1 0 (i0 + 1)) #W2 #HW12
 145   elim (lifts_lift_trans  … Hdes0 … HVW1 … HW12) // -Hdes0 -Hi0 #V3 #HV13 #HVW2
 146   >(lift_mono … HV13 … HV12) in HVW2; -V3 #HVW2
 147   @(s5 … IHA … (V0 @ V0s) … HW12 HL02) /3 width=4/
 148 | #L #V1s #V2s #HV12s #a #V #T #HA #HV #L0 #V10 #X #des #HB #HL0 #H
 149   elim (lifts_inv_applv1 … H) -H #V10s #Y #HV10s #HY #H destruct
 150   elim (lifts_inv_bind1 … HY) -HY #V0 #T0 #HV0 #HT0 #H destruct
 151   elim (lift_total V10 0 1) #V20 #HV120
 152   elim (liftv_total 0 1 V10s) #V20s #HV120s
 153   @(s6 … IHA … (V10 @ V10s) (V20 @ V20s)) /2 width=1/ /3 width=6 by rp_lifts/
 154   @(HA … (des + 1)) /2 width=1/
 155   [ @(s8 … IHB … HB … HV120) /2 width=1/
 156   | @lifts_applv //
 157     elim (liftsv_liftv_trans_le … HV10s … HV120s) -V10s #V10s #HV10s #HV120s
 158     >(liftv_mono … HV12s … HV10s) -V1s //
 159   ]
 160 | #L #Vs #T #W #HA #HW #L0 #V0 #X #des #HB #HL0 #H
 161   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 162   elim (lifts_inv_flat1 … HY) -HY #W0 #T0 #HW0 #HT0 #H destruct
 163   @(s7 … IHA … (V0 @ V0s)) /3 width=4/
 164 | /3 width=7/
 165 ]
 166 qed.
 167
 168 lemma aacr_abst: ∀RR,RS,RP. acp RR RS RP → acr RR RS RP (λL,T. RP L T) →
 169                  ∀a,L,W,T,A,B. ⦃L, W⦄ ϵ[RP] 〚B〛 → (
 170                     ∀L0,V0,W0,T0,des. ⇩*[des] L0 ≡ L → ⇧*[des ] W ≡ W0 → ⇧*[des + 1] T ≡ T0 →
 171                                    ⦃L0, V0⦄ ϵ[RP] 〚B〛 → ⦃L0, W0⦄ ϵ[RP] 〚B〛 → ⦃L0.ⓓⓝW0.V0, T0⦄ ϵ[RP] 〚A〛
 172                  ) →
 173                  ⦃L, ⓛ{a}W.T⦄ ϵ[RP] 〚②B.A〛.
 174 #RR #RS #RP #H1RP #H2RP #a #L #W #T #A #B #HW #HA #L0 #V0 #X #des #HB #HL0 #H
 175 lapply (aacr_acr … H1RP H2RP A) #HCA
 176 lapply (aacr_acr … H1RP H2RP B) #HCB
 177 elim (lifts_inv_bind1 … H) -H #W0 #T0 #HW0 #HT0 #H destruct
 178 lapply (acr_lifts … HL0 … HW0 HW) -HW [ @(s8 … HCB) ] #HW0
 179 @(s3 … HCA … ◊)
 180 @(s6 … HCA … ◊ ◊) //
 181 [ @(HA … HL0) //
 182 | lapply (s1 … HCB) -HCB #HCB
 183   @(cp4 … H1RP) /2 width=1/
 184 ]
 185 qed.
 186
 187 (* Basic_1: removed theorems 2: sc3_arity_gen sc3_repl *)
 188 (* Basic_1: removed local theorems 1: sc3_sn3_abst *)