matita/matita/contribs/lambdadelta/basic_2/computation/acp_cr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/ineint_5.ma".
  16 include "basic_2/grammar/aarity.ma".
  17 include "basic_2/substitution/gr2_gr2.ma".
  18 include "basic_2/substitution/lifts_lift_vector.ma".
  19 include "basic_2/substitution/ldrops_ldrop.ma".
  20 include "basic_2/computation/acp.ma".
  21
  22 (* ABSTRACT COMPUTATION PROPERTIES ******************************************)
  23
  24 (* Note: this is Girard's CR1 *)
  25 definition S1 ≝ λRP,C:relation3 genv lenv term.
  26                 ∀G,L,T. C G L T → RP G L T.
  27
  28 (* Note: this is Tait's iii, or Girard's CR4 *)
  29 definition S2 ≝ λRR:relation4 genv lenv term term. λRS:relation term. λRP,C:relation3 genv lenv term.
  30                 ∀G,L,Vs. all … (RP G L) Vs →
  31                 ∀T. 𝐒⦃T⦄ → NF … (RR G L) RS T → C G L (ⒶVs.T).
  32
  33 (* Note: this generalizes Tait's ii *)
  34 definition S3 ≝ λC:relation3 genv lenv term.
  35                 ∀a,G,L,Vs,V,T,W.
  36                 C G L (ⒶVs.ⓓ{a}ⓝW.V.T) → C G L (ⒶVs.ⓐV.ⓛ{a}W.T).
  37
  38 definition S4 ≝ λRP,C:relation3 genv lenv term.
  39                 ∀G,L,Vs. all … (RP G L) Vs → ∀k. C G L (ⒶVs.⋆k).
  40
  41 definition S5 ≝ λC:relation3 genv lenv term. ∀I,G,L,K,Vs,V1,V2,i.
  42                 C G L (ⒶVs.V2) → ⇧[0, i + 1] V1 ≡ V2 →
  43                 ⇩[0, i] L ≡ K.ⓑ{I}V1 → C G L (ⒶVs.#i).
  44
  45 definition S6 ≝ λRP,C:relation3 genv lenv term.
  46                 ∀G,L,V1s,V2s. ⇧[0, 1] V1s ≡ V2s →
  47                 ∀a,V,T. C G (L.ⓓV) (ⒶV2s.T) → RP G L V → C G L (ⒶV1s.ⓓ{a}V.T).
  48
  49 definition S7 ≝ λC:relation3 genv lenv term.
  50                 ∀G,L,Vs,T,W. C G L (ⒶVs.T) → C G L (ⒶVs.W) → C G L (ⒶVs.ⓝW.T).
  51
  52 definition S8 ≝ λC:relation3 genv lenv term. ∀G,L2,L1,T1,d,e.
  53                 C G L1 T1 → ∀T2. ⇩[d, e] L2 ≡ L1 → ⇧[d, e] T1 ≡ T2 → C G L2 T2.
  54
  55 definition S8s ≝ λC:relation3 genv lenv term.
  56                  ∀G,L1,L2,des. ⇩*[des] L2 ≡ L1 →
  57                  ∀T1,T2. ⇧*[des] T1 ≡ T2 → C G L1 T1 → C G L2 T2.
  58
  59 (* properties of the abstract candidate of reducibility *)
  60 record acr (RR:relation4 genv lenv term term) (RS:relation term) (RP,C:relation3 genv lenv term) : Prop ≝
  61 { s1: S1 RP C;
  62   s2: S2 RR RS RP C;
  63   s3: S3 C;
  64   s4: S4 RP C;
  65   s5: S5 C;
  66   s6: S6 RP C;
  67   s7: S7 C;
  68   s8: S8 C
  69 }.
  70
  71 (* the abstract candidate of reducibility associated to an atomic arity *)
  72 let rec aacr (RP:relation3 genv lenv term) (A:aarity) (G:genv) (L:lenv) on A: predicate term ≝
  73 λT. match A with
  74 [ AAtom     ⇒ RP G L T
  75 | APair B A ⇒ ∀L0,V0,T0,des.
  76               aacr RP B G L0 V0 → ⇩*[des] L0 ≡ L → ⇧*[des] T ≡ T0 →
  77               aacr RP A G L0 (ⓐV0.T0)
  78 ].
  79
  80 interpretation
  81    "candidate of reducibility of an atomic arity (abstract)"
  82    'InEInt RP G L T A = (aacr RP A G L T).
  83
  84 (* Basic properties *********************************************************)
  85
  86 (* Basic_1: was: sc3_lift1 *)
  87 lemma acr_lifts: ∀C. S8 C → S8s C.
  88 #C #HC #G #L1 #L2 #des #H elim H -L1 -L2 -des
  89 [ #L #T1 #T2 #H #HT1
  90   <(lifts_inv_nil … H) -H //
  91 | #L1 #L #L2 #des #d #e #_ #HL2 #IHL #T2 #T1 #H #HLT2
  92   elim (lifts_inv_cons … H) -H /3 width=9/
  93 ]
  94 qed.
  95
  96 lemma rp_lifts: ∀RR,RS,RP. acr RR RS RP (λG,L,T. RP G L T) →
  97                 ∀des,G,L0,L,V,V0. ⇩*[des] L0 ≡ L → ⇧*[des] V ≡ V0 →
  98                 RP G L V → RP G L0 V0.
  99 #RR #RS #RP #HRP #des #G #L0 #L #V #V0 #HL0 #HV0 #HV
 100 @acr_lifts /width=6/
 101 @(s8 … HRP)
 102 qed.
 103
 104 (* Basic_1: was only: sns3_lifts1 *)
 105 lemma rp_liftsv_all: ∀RR,RS,RP. acr RR RS RP (λG,L,T. RP G L T) →
 106                      ∀des,G,L0,L,Vs,V0s. ⇧*[des] Vs ≡ V0s → ⇩*[des] L0 ≡ L →
 107                      all … (RP G L) Vs → all … (RP G L0) V0s.
 108 #RR #RS #RP #HRP #des #G #L0 #L #Vs #V0s #H elim H -Vs -V0s normalize //
 109 #T1s #T2s #T1 #T2 #HT12 #_ #IHT2s #HL0 * #HT1 #HT1s
 110 @conj /2 width=1/ /2 width=6 by rp_lifts/
 111 qed.
 112
 113 (* Basic_1: was:
 114    sc3_sn3 sc3_abst sc3_appl sc3_abbr sc3_bind sc3_cast sc3_lift
 115 *)
 116 lemma aacr_acr: ∀RR,RS,RP. acp RR RS RP → acr RR RS RP (λG,L,T. RP G L T) →
 117                 ∀A. acr RR RS RP (aacr RP A).
 118 #RR #RS #RP #H1RP #H2RP #A elim A -A normalize //
 119 #B #A #IHB #IHA @mk_acr normalize
 120 [ #G #L #T #H
 121   elim (cp1 … H1RP G L) #k #HK
 122   lapply (H ? (⋆k) ? ⟠ ? ? ?) -H
 123   [1,3: // |2,4: skip
 124   | @(s2 … IHB … ◊) //
 125   | #H @(cp3 … H1RP … k) @(s1 … IHA) //
 126   ]
 127 | #G #L #Vs #HVs #T #H1T #H2T #L0 #V0 #X #des #HB #HL0 #H
 128   elim (lifts_inv_applv1 … H) -H #V0s #T0 #HV0s #HT0 #H destruct
 129   lapply (s1 … IHB … HB) #HV0
 130   @(s2 … IHA … (V0 @ V0s)) /2 width=4 by lifts_simple_dx/ /3 width=6/
 131 | #a #G #L #Vs #U #T #W #HA #L0 #V0 #X #des #HB #HL0 #H
 132   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 133   elim (lifts_inv_flat1 … HY) -HY #U0 #X #HU0 #HX #H destruct
 134   elim (lifts_inv_bind1 … HX) -HX #W0 #T0 #HW0 #HT0 #H destruct
 135   @(s3 … IHA … (V0 @ V0s)) /5 width=5/
 136 | #G #L #Vs #HVs #k #L0 #V0 #X #hdes #HB #HL0 #H
 137   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 138   >(lifts_inv_sort1 … HY) -Y
 139   lapply (s1 … IHB … HB) #HV0
 140   @(s4 … IHA … (V0 @ V0s)) /3 width=6/
 141 | #I #G #L #K #Vs #V1 #V2 #i #HA #HV12 #HLK #L0 #V0 #X #des #HB #HL0 #H
 142   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 143   elim (lifts_inv_lref1 … HY) -HY #i0 #Hi0 #H destruct
 144   elim (ldrops_ldrop_trans … HL0 … HLK) #X #des0 #i1 #HL02 #H #Hi1 #Hdes0
 145   >(at_mono … Hi1 … Hi0) in HL02; -i1 #HL02
 146   elim (ldrops_inv_skip2 … Hdes0 … H) -H -des0 #L2 #W1 #des0 #Hdes0 #HLK #HVW1 #H destruct
 147   elim (lift_total W1 0 (i0 + 1)) #W2 #HW12
 148   elim (lifts_lift_trans  … Hdes0 … HVW1 … HW12) // -Hdes0 -Hi0 #V3 #HV13 #HVW2
 149   >(lift_mono … HV13 … HV12) in HVW2; -V3 #HVW2
 150   @(s5 … IHA … (V0 @ V0s) … HW12 HL02) /3 width=4/
 151 | #G #L #V1s #V2s #HV12s #a #V #T #HA #HV #L0 #V10 #X #des #HB #HL0 #H
 152   elim (lifts_inv_applv1 … H) -H #V10s #Y #HV10s #HY #H destruct
 153   elim (lifts_inv_bind1 … HY) -HY #V0 #T0 #HV0 #HT0 #H destruct
 154   elim (lift_total V10 0 1) #V20 #HV120
 155   elim (liftv_total 0 1 V10s) #V20s #HV120s
 156   @(s6 … IHA … (V10 @ V10s) (V20 @ V20s)) /2 width=1/ /3 width=6 by rp_lifts/
 157   @(HA … (des + 1)) /2 width=1/
 158   [ @(s8 … IHB … HB … HV120) /2 width=1/
 159   | @lifts_applv //
 160     elim (liftsv_liftv_trans_le … HV10s … HV120s) -V10s #V10s #HV10s #HV120s
 161     >(liftv_mono … HV12s … HV10s) -V1s //
 162   ]
 163 | #G #L #Vs #T #W #HA #HW #L0 #V0 #X #des #HB #HL0 #H
 164   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 165   elim (lifts_inv_flat1 … HY) -HY #W0 #T0 #HW0 #HT0 #H destruct
 166   @(s7 … IHA … (V0 @ V0s)) /3 width=4/
 167 | /3 width=7/
 168 ]
 169 qed.
 170
 171 lemma aacr_abst: ∀RR,RS,RP. acp RR RS RP → acr RR RS RP (λG,L,T. RP G L T) →
 172                  ∀a,G,L,W,T,A,B. ⦃G, L, W⦄ ϵ[RP] 〚B〛 → (
 173                     ∀L0,V0,W0,T0,des. ⇩*[des] L0 ≡ L → ⇧*[des ] W ≡ W0 → ⇧*[des + 1] T ≡ T0 →
 174                                    ⦃G, L0, V0⦄ ϵ[RP] 〚B〛 → ⦃G, L0, W0⦄ ϵ[RP] 〚B〛 → ⦃G, L0.ⓓⓝW0.V0, T0⦄ ϵ[RP] 〚A〛
 175                  ) →
 176                  ⦃G, L, ⓛ{a}W.T⦄ ϵ[RP] 〚②B.A〛.
 177 #RR #RS #RP #H1RP #H2RP #a #G #L #W #T #A #B #HW #HA #L0 #V0 #X #des #HB #HL0 #H
 178 lapply (aacr_acr … H1RP H2RP A) #HCA
 179 lapply (aacr_acr … H1RP H2RP B) #HCB
 180 elim (lifts_inv_bind1 … H) -H #W0 #T0 #HW0 #HT0 #H destruct
 181 lapply (acr_lifts … HL0 … HW0 HW) -HW [ @(s8 … HCB) ] #HW0
 182 @(s3 … HCA … ◊)
 183 @(s6 … HCA … ◊ ◊) //
 184 [ @(HA … HL0) //
 185 | lapply (s1 … HCB) -HCB #HCB
 186   @(cp4 … H1RP) /2 width=1/
 187 ]
 188 qed.
 189
 190 (* Basic_1: removed theorems 2: sc3_arity_gen sc3_repl *)
 191 (* Basic_1: removed local theorems 1: sc3_sn3_abst *)