matita/matita/contribs/lambdadelta/basic_2/computation/cpds_cpds.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/sstas_sstas.ma".
  16 include "basic_2/computation/lprs_cprs.ma".
  17 include "basic_2/computation/cpxs_cpxs.ma".
  18 include "basic_2/computation/cpds.ma".
  19
  20 (* DECOMPOSED EXTENDED PARALLEL COMPUTATION ON TERMS ************************)
  21
  22 (* Advanced properties ******************************************************)
  23
  24 lemma cpds_cprs_trans: ∀h,g,L,T1,T,T2.
  25                        ⦃h, L⦄ ⊢ T1 •*➡*[g] T → L ⊢ T ➡* T2 → ⦃h, L⦄ ⊢ T1 •*➡*[g] T2.
  26 #h #g #L #T1 #T #T2 * #T0 #HT10 #HT0 #HT2
  27 lapply (cprs_trans … HT0 … HT2) -T /2 width=3/
  28 qed-.
  29
  30 lemma sstas_cpds_trans: ∀h,g,L,T1,T,T2.
  31                         ⦃h, L⦄ ⊢ T1 •*[g] T → ⦃h, L⦄ ⊢ T •*➡*[g] T2 → ⦃h, L⦄ ⊢ T1 •*➡*[g] T2.
  32 #h #g #L #T1 #T #T2 #HT1 * #T0 #HT0 #HT02
  33 lapply (sstas_trans … HT1 … HT0) -T /2 width=3/
  34 qed-.
  35
  36 (* Advanced inversion lemmas ************************************************)
  37
  38 lemma cpds_inv_abst1: ∀h,g,a,L,V1,T1,U2. ⦃h, L⦄ ⊢ ⓛ{a}V1. T1 •*➡*[g] U2 →
  39                       ∃∃V2,T2. L ⊢ V1 ➡* V2 & ⦃h, L.ⓛV1⦄ ⊢ T1 •*➡*[g] T2 &
  40                                U2 = ⓛ{a}V2. T2.
  41 #h #g #a #L #V1 #T1 #U2 * #X #H1 #H2
  42 elim (sstas_inv_bind1 … H1) -H1 #U #HTU1 #H destruct
  43 elim (cprs_inv_abst1 … H2) -H2 #V2 #T2 #HV12 #HUT2 #H destruct /3 width=5/
  44 qed-.
  45
  46 lemma cpds_inv_abbr_abst: ∀h,g,a1,a2,L,V1,W2,T1,T2. ⦃h, L⦄ ⊢ ⓓ{a1}V1.T1 •*➡*[g] ⓛ{a2}W2.T2 →
  47                           ∃∃T. ⦃h, L.ⓓV1⦄ ⊢ T1 •*➡*[g] T & ⇧[0, 1] ⓛ{a2}W2.T2 ≡ T & a1 = true.
  48 #h #g #a1 #a2 #L #V1 #W2 #T1 #T2 * #X #H1 #H2
  49 elim (sstas_inv_bind1 … H1) -H1 #U1 #HTU1 #H destruct
  50 elim (cprs_inv_abbr1 … H2) -H2 *
  51 [ #V2 #U2 #HV12 #HU12 #H destruct
  52 | /3 width=3/
  53 ]
  54 qed-.
  55
  56 (* Advanced forward lemmas **************************************************)
  57
  58 lemma cpds_fwd_cpxs: ∀h,g,L,T1,T2. ⦃h, L⦄ ⊢ T1 •*➡*[g] T2 → ⦃h, L⦄ ⊢ T1 ➡*[g] T2.
  59 #h #g #L #T1 #T2 * /3 width=3 by cpxs_trans, sstas_cpxs, cprs_cpxs/
  60 qed-.