matita/matita/contribs/lambdadelta/basic_2/computation/cprs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predstar_4.ma".
  16 include "basic_2/reduction/cnr.ma".
  17
  18 (* CONTEXT-SENSITIVE PARALLEL COMPUTATION ON TERMS **************************)
  19
  20 (* Basic_1: includes: pr1_pr0 *)
  21 definition cprs: relation4 genv lenv term term ≝
  22                  λG. LTC … (cpr G).
  23
  24 interpretation "context-sensitive parallel computation (term)"
  25    'PRedStar G L T1 T2 = (cprs G L T1 T2).
  26
  27 (* Basic eliminators ********************************************************)
  28
  29 lemma cprs_ind: ∀G,L,T1. ∀R:predicate term. R T1 →
  30                 (∀T,T2. ⦃G, L⦄ ⊢ T1 ➡* T → ⦃G, L⦄ ⊢ T ➡ T2 → R T → R T2) →
  31                 ∀T2. ⦃G, L⦄ ⊢ T1 ➡* T2 → R T2.
  32 #G #L #T1 #R #HT1 #IHT1 #T2 #HT12
  33 @(TC_star_ind … HT1 IHT1 … HT12) //
  34 qed-.
  35
  36 lemma cprs_ind_dx: ∀G,L,T2. ∀R:predicate term. R T2 →
  37                    (∀T1,T. ⦃G, L⦄ ⊢ T1 ➡ T → ⦃G, L⦄ ⊢ T ➡* T2 → R T → R T1) →
  38                    ∀T1. ⦃G, L⦄ ⊢ T1 ➡* T2 → R T1.
  39 #G #L #T2 #R #HT2 #IHT2 #T1 #HT12
  40 @(TC_star_ind_dx … HT2 IHT2 … HT12) //
  41 qed-.
  42
  43 (* Basic properties *********************************************************)
  44
  45 (* Basic_1: was: pr3_pr2 *)
  46 lemma cpr_cprs: ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡ T2 → ⦃G, L⦄ ⊢ T1 ➡* T2.
  47 /2 width=1/ qed.
  48
  49 (* Basic_1: was: pr3_refl *)
  50 lemma cprs_refl: ∀G,L,T. ⦃G, L⦄ ⊢ T ➡* T.
  51 /2 width=1/ qed.
  52
  53 lemma cprs_strap1: ∀G,L,T1,T,T2.
  54                    ⦃G, L⦄ ⊢ T1 ➡* T → ⦃G, L⦄ ⊢ T ➡ T2 → ⦃G, L⦄ ⊢ T1 ➡* T2.
  55 normalize /2 width=3/ qed.
  56
  57 (* Basic_1: was: pr3_step *)
  58 lemma cprs_strap2: ∀G,L,T1,T,T2.
  59                    ⦃G, L⦄ ⊢ T1 ➡ T → ⦃G, L⦄ ⊢ T ➡* T2 → ⦃G, L⦄ ⊢ T1 ➡* T2.
  60 normalize /2 width=3/ qed.
  61
  62 lemma lsubr_cprs_trans: ∀G. lsub_trans … (cprs G) lsubr.
  63 /3 width=5 by lsubr_cpr_trans, TC_lsub_trans/
  64 qed-.
  65
  66 (* Basic_1: was: pr3_pr1 *)
  67 lemma tprs_cprs: ∀G,L,T1,T2. ⦃G, ⋆⦄ ⊢ T1 ➡* T2 → ⦃G, L⦄ ⊢ T1 ➡* T2.
  68 #G #L #T1 #T2 #H @(lsubr_cprs_trans … H) -H //
  69 qed.
  70
  71 lemma cprs_bind_dx: ∀G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡ V2 → ∀I,T1,T2. ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡* T2 →
  72                     ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V1. T1 ➡* ⓑ{a,I}V2. T2.
  73 #G #L #V1 #V2 #HV12 #I #T1 #T2 #HT12 #a @(cprs_ind_dx … HT12) -T1
  74 /3 width=1/ /3 width=3/
  75 qed.
  76
  77 (* Basic_1: was only: pr3_thin_dx *)
  78 lemma cprs_flat_dx: ∀I,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡ V2 → ∀T1,T2. ⦃G, L⦄ ⊢ T1 ➡* T2 →
  79                     ⦃G, L⦄ ⊢ ⓕ{I} V1. T1 ➡* ⓕ{I} V2. T2.
  80 #I #G #L #V1 #V2 #HV12 #T1 #T2 #HT12 @(cprs_ind … HT12) -T2 /3 width=1/
  81 #T #T2 #_ #HT2 #IHT1
  82 @(cprs_strap1 … IHT1) -V1 -T1 /2 width=1/
  83 qed.
  84
  85 lemma cprs_flat_sn: ∀I,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡ T2 → ∀V1,V2. ⦃G, L⦄ ⊢ V1 ➡* V2 →
  86                     ⦃G, L⦄ ⊢ ⓕ{I} V1. T1 ➡* ⓕ{I} V2. T2.
  87 #I #G #L #T1 #T2 #HT12 #V1 #V2 #H @(cprs_ind … H) -V2 /3 width=1/
  88 #V #V2 #_ #HV2 #IHV1
  89 @(cprs_strap1 … IHV1) -V1 -T1 /2 width=1/
  90 qed.
  91
  92 lemma cprs_zeta: ∀G,L,V,T1,T,T2. ⇧[0, 1] T2 ≡ T →
  93                  ⦃G, L.ⓓV⦄ ⊢ T1 ➡* T → ⦃G, L⦄ ⊢ +ⓓV.T1 ➡* T2.
  94 #G #L #V #T1 #T #T2 #HT2 #H @(TC_ind_dx … T1 H) -T1 /3 width=3/
  95 qed.
  96
  97 lemma cprs_tau: ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡* T2 → ∀V. ⦃G, L⦄ ⊢ ⓝV.T1 ➡* T2.
  98 #G #L #T1 #T2 #H elim H -T2 /2 width=3/ /3 width=1/
  99 qed.
 100
 101 lemma cprs_beta_dx: ∀a,G,L,V1,V2,W1,W2,T1,T2.
 102                     ⦃G, L⦄ ⊢ V1 ➡ V2 → ⦃G, L⦄ ⊢ W1 ➡ W2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ➡* T2 →
 103                     ⦃G, L⦄ ⊢ ⓐV1.ⓛ{a}W1.T1 ➡* ⓓ{a}ⓝW2.V2.T2.
 104 #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 * -T2 /3 width=1/
 105 /4 width=7 by cprs_strap1, cprs_bind_dx, cprs_flat_dx, cpr_beta/ (**) (* auto too slow without trace *)
 106 qed.
 107
 108 lemma cprs_theta_dx: ∀a,G,L,V1,V,V2,W1,W2,T1,T2.
 109                      ⦃G, L⦄ ⊢ V1 ➡ V → ⇧[0, 1] V ≡ V2 → ⦃G, L.ⓓW1⦄ ⊢ T1 ➡* T2 →
 110                      ⦃G, L⦄ ⊢ W1 ➡ W2 → ⦃G, L⦄ ⊢ ⓐV1.ⓓ{a}W1.T1 ➡* ⓓ{a}W2.ⓐV2.T2.
 111 #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 * -T2 [ /3 width=3/ ]
 112 /4 width=9 by cprs_strap1, cprs_bind_dx, cprs_flat_dx, cpr_theta/ (**) (* auto too slow without trace *)
 113 qed.
 114
 115 (* Basic inversion lemmas ***************************************************)
 116
 117 (* Basic_1: was: pr3_gen_sort *)
 118 lemma cprs_inv_sort1: ∀G,L,U2,k. ⦃G, L⦄ ⊢ ⋆k ➡* U2 → U2 = ⋆k.
 119 #G #L #U2 #k #H @(cprs_ind … H) -U2 //
 120 #U2 #U #_ #HU2 #IHU2 destruct
 121 >(cpr_inv_sort1 … HU2) -HU2 //
 122 qed-.
 123
 124 (* Basic_1: was: pr3_gen_cast *)
 125 lemma cprs_inv_cast1: ∀G,L,W1,T1,U2. ⦃G, L⦄ ⊢ ⓝW1.T1 ➡* U2 → ⦃G, L⦄ ⊢ T1 ➡* U2 ∨
 126                       ∃∃W2,T2. ⦃G, L⦄ ⊢ W1 ➡* W2 & ⦃G, L⦄ ⊢ T1 ➡* T2 & U2 = ⓝW2.T2.
 127 #G #L #W1 #T1 #U2 #H @(cprs_ind … H) -U2 /3 width=5/
 128 #U2 #U #_ #HU2 * /3 width=3/ *
 129 #W #T #HW1 #HT1 #H destruct
 130 elim (cpr_inv_cast1 … HU2) -HU2 /3 width=3/ *
 131 #W2 #T2 #HW2 #HT2 #H destruct /4 width=5/
 132 qed-.
 133
 134 (* Basic_1: was: nf2_pr3_unfold *)
 135 lemma cprs_inv_cnr1: ∀G,L,T,U. ⦃G, L⦄ ⊢ T ➡* U → ⦃G, L⦄ ⊢ 𝐍⦃T⦄ → T = U.
 136 #G #L #T #U #H @(cprs_ind_dx … H) -T //
 137 #T0 #T #H1T0 #_ #IHT #H2T0
 138 lapply (H2T0 … H1T0) -H1T0 #H destruct /2 width=1/
 139 qed-.
 140
 141 (* Basic_1: removed theorems 13:
 142    pr1_head_1 pr1_head_2 pr1_comp
 143    clear_pr3_trans pr3_cflat pr3_gen_bind
 144    pr3_head_1 pr3_head_2 pr3_head_21 pr3_head_12
 145    pr3_iso_appl_bind pr3_iso_appls_appl_bind pr3_iso_appls_bind
 146 *)