matita/matita/contribs/lambdadelta/basic_2/computation/cprs_cprs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/reduction/lpr_lpr.ma".
  16 include "basic_2/computation/cprs_lift.ma".
  17
  18 (* CONTEXT-SENSITIVE PARALLEL COMPUTATION ON TERMS **************************)
  19
  20 (* Main properties **********************************************************)
  21
  22 (* Basic_1: was: pr3_t *)
  23 (* Basic_1: includes: pr1_t *)
  24 theorem cprs_trans: ∀L. Transitive … (cprs L).
  25 #L #T1 #T #HT1 #T2 @trans_TC @HT1 qed-. (**) (* auto /3 width=3/ does not work because a δ-expansion gets in the way *)
  26
  27 (* Basic_1: was: pr3_confluence *)
  28 (* Basic_1: includes: pr1_confluence *)
  29 theorem cprs_conf: ∀L. confluent2 … (cprs L) (cprs L).
  30 #L @TC_confluent2 /2 width=3 by cpr_conf/ qed-. (**) (* auto /3 width=3/ does not work because a δ-expansion gets in the way *)
  31
  32 theorem cprs_ext_bind: ∀L,V1,V2. L ⊢ V1 ➡* V2 → ∀V,T1,T2. L.ⓛV ⊢ T1 ➡* T2 →
  33                        ∀a,I. L ⊢ ⓑ{a,I}V1. T1 ➡* ⓑ{a,I}V2. T2.
  34 #L #V1 #V2 #H #V #T1 #T2 #HT12 #a #I @(TC_ind_dx … V1 H) -V1 /2 width=3/
  35 #V1 #V0 #HV10 #_ #IHV02
  36 @(cprs_trans … IHV02) /2 width=1/
  37 qed.
  38
  39 theorem cprs_bind: ∀a,I,L,V1,V2,T1,T2. L. ⓑ{I}V1 ⊢ T1 ➡* T2 → L ⊢ V1 ➡* V2 →
  40                    L ⊢ ⓑ{a,I}V1. T1 ➡* ⓑ{a,I}V2. T2.
  41 #a #I #L #V1 #V2 #T1 #T2 #HT12 #H @(cprs_ind … H) -V2 /2 width=1/
  42 #V #V2 #_ #HV2 #IHV1
  43 @(cprs_trans … IHV1) -V1 /2 width=1/
  44 qed.
  45
  46 (* Basic_1: was: pr3_flat *)
  47 theorem cprs_flat: ∀I,L,V1,V2,T1,T2. L ⊢ T1 ➡* T2 → L ⊢ V1 ➡* V2 →
  48                    L ⊢ ⓕ{I} V1. T1 ➡* ⓕ{I} V2. T2.
  49 #I #L #V1 #V2 #T1 #T2 #HT12 #H @(cprs_ind … H) -V2 /2 width=1/
  50 #V #V2 #_ #HV2 #IHV1
  51 @(cprs_trans … IHV1) -IHV1 /2 width=1/
  52 qed.
  53
  54 theorem cprs_beta: ∀a,L,V1,V2,W,T1,T2.
  55                    L.ⓛW ⊢ T1 ➡* T2 → L ⊢ V1 ➡* V2 →
  56                    L ⊢ ⓐV1.ⓛ{a}W.T1 ➡* ⓓ{a}V2.T2.
  57 #a #L #V1 #V2 #W #T1 #T2 #HT12 #H @(cprs_ind … H) -V2 /2 width=1/
  58 #V #V2 #_ #HV2 #IHV1
  59 @(cprs_trans … IHV1) /2 width=1/
  60 qed.
  61
  62 theorem cprs_theta_rc: ∀a,L,V1,V,V2,W1,W2,T1,T2.
  63                        L ⊢ V1 ➡ V → ⇧[0, 1] V ≡ V2 → L.ⓓW1 ⊢ T1 ➡* T2 →
  64                        L ⊢ W1 ➡* W2 → L ⊢ ⓐV1.ⓓ{a}W1.T1 ➡* ⓓ{a}W2.ⓐV2.T2.
  65 #a #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HT12 #H elim H -W2 /2 width=3/
  66 #W #W2 #_ #HW2 #IHW1
  67 @(cprs_trans … IHW1) /2 width=1/
  68 qed.
  69
  70 theorem cprs_theta: ∀a,L,V1,V,V2,W1,W2,T1,T2.
  71                     ⇧[0, 1] V ≡ V2 → L ⊢ W1 ➡* W2 → L.ⓓW1 ⊢ T1 ➡* T2 →
  72                     L ⊢ V1 ➡* V → L ⊢ ⓐV1.ⓓ{a}W1.T1 ➡* ⓓ{a}W2.ⓐV2.T2.
  73 #a #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV2 #HW12 #HT12 #H @(TC_ind_dx … V1 H) -V1 /2 width=3/
  74 #V1 #V0 #HV10 #_ #IHV0
  75 @(cprs_trans … IHV0) /2 width=1/
  76 qed.
  77
  78 (* Properties concerning sn parallel reduction on local environments ********)
  79
  80 (* Basic_1: was just: pr3_pr2_pr2_t *)
  81 (* Basic_1: includes: pr3_pr0_pr2_t *)
  82 lemma lpr_cpr_trans: s_r_trans … cpr lpr.
  83 #L2 #T1 #T2 #HT12 elim HT12 -L2 -T1 -T2
  84 [ /2 width=3/
  85 | #L2 #K2 #V0 #V2 #W2 #i #HLK2 #_ #HVW2 #IHV02 #L1 #HL12
  86   elim (lpr_ldrop_trans_O1 … HL12 … HLK2) -L2 #X #HLK1 #H
  87   elim (lpr_inv_pair2 … H) -H #K1 #V1 #HK12 #HV10 #H destruct
  88   lapply (IHV02 … HK12) -K2 #HV02
  89   lapply (cprs_strap2 … HV10 … HV02) -V0 /2 width=6/
  90 | #a #I #L2 #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L1 #HL12
  91   lapply (IHT12 (L1.ⓑ{I}V1) ?) -IHT12 /2 width=1/ /3 width=1/
  92 |4,6: /3 width=1/
  93 | #L2 #V2 #T1 #T #T2 #_ #HT2 #IHT1 #L1 #HL12
  94   lapply (IHT1 (L1.ⓓV2) ?) -IHT1 /2 width=1/ /2 width=3/
  95 | #a #L2 #V1 #V2 #W #T1 #T2 #_ #_ #IHV12 #IHT12 #L1 #HL12
  96   lapply (IHT12 (L1.ⓛW) ?) -IHT12 /2 width=1/ /3 width=1/
  97 | #a #L2 #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV1 #IHW12 #IHT12 #L1 #HL12
  98   lapply (IHT12 (L1.ⓓW1) ?) -IHT12 /2 width=1/ /3 width=3/
  99 ]
 100 qed-.
 101
 102 lemma cpr_bind2: ∀L,V1,V2. L ⊢ V1 ➡ V2 → ∀I,T1,T2. L. ⓑ{I}V2 ⊢ T1 ➡ T2 →
 103                  ∀a. L ⊢ ⓑ{a,I}V1. T1 ➡* ⓑ{a,I}V2. T2.
 104 #L #V1 #V2 #HV12 #I #T1 #T2 #HT12
 105 lapply (lpr_cpr_trans … HT12 (L.ⓑ{I}V1) ?) /2 width=1/
 106 qed.
 107
 108 (* Advanced properties ******************************************************)
 109
 110 (* Basic_1: was only: pr3_pr2_pr3_t pr3_wcpr0_t *)
 111 lemma lpr_cprs_trans: s_rs_trans … cpr lpr.
 112 /3 width=5 by s_r_trans_TC1, lpr_cpr_trans/ qed-.
 113
 114 (* Basic_1: was: pr3_strip *)
 115 (* Basic_1: includes: pr1_strip *)
 116 lemma cprs_strip: ∀L. confluent2 … (cprs L) (cpr L).
 117 #L @TC_strip1 /2 width=3 by cpr_conf/ qed-. (**) (* auto /3 width=3/ does not work because a δ-expansion gets in the way *)
 118
 119 lemma cprs_lpr_conf_dx: ∀L0,T0,T1. L0 ⊢ T0 ➡* T1 → ∀L1. L0 ⊢ ➡ L1 →
 120                         ∃∃T. L1 ⊢ T1 ➡* T & L1 ⊢ T0 ➡* T.
 121 #L0 #T0 #T1 #H elim H -T1
 122 [ #T1 #HT01 #L1 #HL01
 123   elim (lpr_cpr_conf_dx … HT01 … HL01) -L0 /3 width=3/
 124 | #T #T1 #_ #HT1 #IHT0 #L1 #HL01
 125   elim (IHT0 … HL01) #T2 #HT2 #HT02
 126   elim (lpr_cpr_conf_dx … HT1 … HL01) -L0 #T3 #HT3 #HT13
 127   elim (cprs_strip … HT2 … HT3) -T #T #HT2 #HT3
 128   lapply (cprs_strap2 … HT13 … HT3) -T3
 129   lapply (cprs_strap1 … HT02 … HT2) -T2 /2 width=3/
 130 ]
 131 qed-.
 132
 133 lemma cprs_lpr_conf_sn: ∀L0,T0,T1. L0 ⊢ T0 ➡* T1 → ∀L1. L0 ⊢ ➡ L1 →
 134                         ∃∃T. L0 ⊢ T1 ➡* T & L1 ⊢ T0 ➡* T.
 135 #L0 #T0 #T1 #HT01 #L1 #HL01
 136 elim (cprs_lpr_conf_dx … HT01 … HL01) -HT01 #T #HT1
 137 lapply (lpr_cprs_trans … HT1 … HL01) -HT1 /2 width=3/
 138 qed-.
 139
 140 lemma cprs_bind2_dx: ∀L,V1,V2. L ⊢ V1 ➡ V2 → ∀I,T1,T2. L. ⓑ{I}V2 ⊢ T1 ➡* T2 →
 141                      ∀a. L ⊢ ⓑ{a,I}V1. T1 ➡* ⓑ{a,I}V2. T2.
 142 #L #V1 #V2 #HV12 #I #T1 #T2 #HT12
 143 lapply (lpr_cprs_trans … HT12 (L.ⓑ{I}V1) ?) /2 width=1/
 144 qed.