matita/matita/contribs/lambdadelta/basic_2/computation/cprs_lfpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/reducibility/ltpr_tps.ma".
  16 include "basic_2/reducibility/cpr_ltpss.ma".
  17 include "basic_2/reducibility/lfpr.ma".
  18 include "basic_2/computation/cprs.ma".
  19
  20 (* CONTEXT-SENSITIVE PARALLEL COMPUTATION ON TERMS **************************)
  21
  22 (* Properties concerning focalized parallel reduction on local environments *)
  23
  24 lemma ltpr_tpss_trans: ∀L1,L2. L1 ➡ L2 → ∀T1,T2,d,e. L2 ⊢ T1 ▶* [d, e] T2 →
  25                        ∃∃T. L1 ⊢ T1 ▶* [d, e] T & L1 ⊢ T ➡* T2.
  26 #L1 #L2 #HL12 #T1 #T2 #d #e #H @(tpss_ind … H) -T2
  27 [ /2 width=3/
  28 | #T #T2 #_ #HT2 * #T0 #HT10 #HT0
  29   elim (ltpr_tps_trans … HT2 … HL12) -L2 #T3 #HT3 #HT32
  30   @(ex2_1_intro … HT10) -T1 (**) (* explicit constructors *)
  31   @(cprs_strap1 … T3 …) /2 width=1/ -HT32
  32   @(cprs_strap1 … HT0) -HT0 /3 width=3/
  33 ]
  34 qed.
  35
  36 (* Basic_1: was just: pr3_pr0_pr2_t *)
  37 lemma ltpr_cpr_trans: ∀L1,L2. L1 ➡ L2 → ∀T1,T2. L2 ⊢ T1 ➡ T2 → L1 ⊢ T1 ➡* T2.
  38 #L1 #L2 #HL12 #T1 #T2 * #T #HT1
  39 <(ltpr_fwd_length … HL12) #HT2
  40 elim (ltpr_tpss_trans … HL12 … HT2) -L2 /3 width=3/
  41 qed.
  42
  43 (* Basic_1: was just: pr3_pr2_pr2_t *)
  44 lemma lfpr_cpr_trans: ∀L1,L2. ⦃L1⦄ ➡ ⦃L2⦄ → ∀T1,T2. L2 ⊢ T1 ➡ T2 → L1 ⊢ T1 ➡* T2.
  45 #L1 #L2 * /3 width=7/
  46 qed.