matita/matita/contribs/lambdadelta/basic_2/computation/cpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/reduction/cnx.ma".
  16 include "basic_2/computation/cprs.ma".
  17
  18 (* CONTEXT-SENSITIVE EXTENDED PARALLEL COMPUTATION ON TERMS *****************)
  19
  20 definition cpxs: ∀h. sd h → lenv → relation term ≝
  21                  λh,g. LTC … (cpx h g).
  22
  23 interpretation "extended context-sensitive parallel computation (term)"
  24    'PRedStar h g L T1 T2 = (cpxs h g L T1 T2).
  25
  26 (* Basic eliminators ********************************************************)
  27
  28 lemma cpxs_ind: ∀h,g,L,T1. ∀R:predicate term. R T1 →
  29                 (∀T,T2. ⦃h, L⦄ ⊢ T1 ➡*[g] T → ⦃h, L⦄ ⊢ T ➡[g] T2 → R T → R T2) →
  30                 ∀T2. ⦃h, L⦄ ⊢ T1 ➡*[g] T2 → R T2.
  31 #h #g #L #T1 #R #HT1 #IHT1 #T2 #HT12
  32 @(TC_star_ind … HT1 IHT1 … HT12) //
  33 qed-.
  34
  35 lemma cpxs_ind_dx: ∀h,g,L,T2. ∀R:predicate term. R T2 →
  36                    (∀T1,T. ⦃h, L⦄ ⊢ T1 ➡[g] T → ⦃h, L⦄ ⊢ T ➡*[g] T2 → R T → R T1) →
  37                    ∀T1. ⦃h, L⦄ ⊢ T1 ➡*[g] T2 → R T1.
  38 #h #g #L #T2 #R #HT2 #IHT2 #T1 #HT12
  39 @(TC_star_ind_dx … HT2 IHT2 … HT12) //
  40 qed-.
  41
  42 (* Basic properties *********************************************************)
  43
  44 lemma cpxs_refl: ∀h,g,L,T. ⦃h, L⦄ ⊢ T ➡*[g] T.
  45 /2 width=1/ qed.
  46
  47 lemma cpx_cpxs: ∀h,g,L,T1,T2. ⦃h, L⦄ ⊢ T1 ➡[g] T2 → ⦃h, L⦄ ⊢ T1 ➡*[g] T2.
  48 /2 width=1/ qed.
  49
  50 lemma cpxs_strap1: ∀h,g,L,T1,T. ⦃h, L⦄ ⊢ T1 ➡*[g] T →
  51                    ∀T2. ⦃h, L⦄ ⊢ T ➡[g] T2 → ⦃h, L⦄ ⊢ T1 ➡*[g] T2.
  52 normalize /2 width=3/ qed.
  53
  54 lemma cpxs_strap2: ∀h,g,L,T1,T. ⦃h, L⦄ ⊢ T1 ➡[g] T →
  55                    ∀T2. ⦃h, L⦄ ⊢ T ➡*[g] T2 → ⦃h, L⦄ ⊢ T1 ➡*[g] T2.
  56 normalize /2 width=3/ qed.
  57
  58 lemma lsubx_cpxs_trans: ∀h,g. lsub_trans … (cpxs h g) lsubx.
  59 /3 width=5 by lsubx_cpx_trans, TC_lsub_trans/
  60 qed-.
  61
  62 axiom cprs_cpxs: ∀h,g,L,T1,T2. L ⊢ T1 ➡* T2 → ⦃h, L⦄ ⊢ T1 ➡*[g] T2.
  63 (*
  64 #h #g #L #T1 #T2 #H @(cprs_ind … H) -T2 // /3 width=3/
  65 qed.
  66 *)
  67 lemma cpxs_bind_dx: ∀h,g,L,V1,V2. ⦃h, L⦄ ⊢ V1 ➡[g] V2 →
  68                     ∀I,T1,T2. ⦃h, L. ⓑ{I}V1⦄ ⊢ T1 ➡*[g] T2 →
  69                     ∀a. ⦃h, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡*[g] ⓑ{a,I}V2.T2.
  70 #h #g #L #V1 #V2 #HV12 #I #T1 #T2 #HT12 #a @(cpxs_ind_dx … HT12) -T1
  71 /3 width=1/ /3 width=3/
  72 qed.
  73
  74 lemma cpxs_flat_dx: ∀h,g,L,V1,V2. ⦃h, L⦄ ⊢ V1 ➡[g] V2 →
  75                     ∀T1,T2. ⦃h, L⦄ ⊢ T1 ➡*[g] T2 →
  76                     ∀I. ⦃h, L⦄ ⊢ ⓕ{I} V1. T1 ➡*[g] ⓕ{I} V2. T2.
  77 #h #g #L #V1 #V2 #HV12 #T1 #T2 #HT12 @(cpxs_ind … HT12) -T2 /3 width=1/ /3 width=5/
  78 qed.
  79
  80 lemma cpxs_flat_sn: ∀h,g,L,T1,T2. ⦃h, L⦄ ⊢ T1 ➡[g] T2 →
  81                     ∀V1,V2. ⦃h, L⦄ ⊢ V1 ➡*[g] V2 →
  82                     ∀I. ⦃h, L⦄ ⊢ ⓕ{I} V1. T1 ➡*[g] ⓕ{I} V2. T2.
  83 #h #g #L #T1 #T2 #HT12 #V1 #V2 #H @(cpxs_ind … H) -V2 /3 width=1/ /3 width=5/
  84 qed.
  85
  86 lemma cpxs_zeta: ∀h,g,L,V,T1,T,T2. ⇧[0, 1] T2 ≡ T →
  87                  ⦃h, L.ⓓV⦄ ⊢ T1 ➡*[g] T → ⦃h, L⦄ ⊢ +ⓓV.T1 ➡*[g] T2.
  88 #h #g #L #V #T1 #T #T2 #HT2 #H @(TC_ind_dx … T1 H) -T1 /3 width=3/
  89 qed.
  90
  91 lemma cpxs_tau: ∀h,g,L,T1,T2. ⦃h, L⦄ ⊢ T1 ➡*[g] T2 → ∀V. ⦃h, L⦄ ⊢ ⓝV.T1 ➡*[g] T2.
  92 #h #g #L #T1 #T2 #H elim H -T2 /2 width=3/ /3 width=1/
  93 qed.
  94
  95 lemma cpxs_ti: ∀h,g,L,V1,V2. ⦃h, L⦄ ⊢ V1 ➡*[g] V2 → ∀T. ⦃h, L⦄ ⊢ ⓝV1.T ➡*[g] V2.
  96 #h #g #L #V1 #V2 #H elim H -V2 /2 width=3/ /3 width=1/
  97 qed.
  98
  99 lemma cpxs_beta_dx: ∀h,g,a,L,V1,V2,W1,W2,T1,T2.
 100                     ⦃h, L⦄ ⊢ V1 ➡[g] V2 → ⦃h, L.ⓛW1⦄ ⊢ T1 ➡*[g] T2 → ⦃h, L⦄ ⊢ W1 ➡[g] W2 →
 101                     ⦃h, L⦄ ⊢ ⓐV1.ⓛ{a}W1.T1 ➡*[g] ⓓ{a}ⓝW2.V2.T2.
 102 #h #g #a #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 * -T2 /3 width=1/
 103 /4 width=7 by cpxs_strap1, cpxs_bind_dx, cpxs_flat_dx, cpx_beta/ (**) (* auto too slow without trace *)
 104 qed.
 105
 106 lemma cpxs_theta_dx: ∀h,g,a,L,V1,V,V2,W1,W2,T1,T2.
 107                      ⦃h, L⦄ ⊢ V1 ➡[g] V → ⇧[0, 1] V ≡ V2 → ⦃h, L.ⓓW1⦄ ⊢ T1 ➡*[g] T2 →
 108                      ⦃h, L⦄ ⊢ W1 ➡[g] W2 → ⦃h, L⦄ ⊢ ⓐV1.ⓓ{a}W1.T1 ➡*[g] ⓓ{a}W2.ⓐV2.T2.
 109 #h #g #a #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 * -T2 [ /3 width=3/ ]
 110 /4 width=9 by cpxs_strap1, cpxs_bind_dx, cpxs_flat_dx, cpx_theta/ (**) (* auto too slow without trace *)
 111 qed.
 112
 113 (* Basic inversion lemmas ***************************************************)
 114
 115 lemma cpxs_inv_sort1: ∀h,g,L,U2,k. ⦃h, L⦄ ⊢ ⋆k ➡*[g] U2 →
 116                       ∃∃n,l. deg h g k (n+l) & U2 = ⋆((next h)^n k).
 117 #h #g #L #U2 #k #H @(cpxs_ind … H) -U2
 118 [ elim (deg_total h g k) #l #Hkl
 119   @(ex2_2_intro … 0 … Hkl) -Hkl //
 120 | #U #U2 #_ #HU2 * #n #l #Hknl #H destruct
 121   elim (cpx_inv_sort1 … HU2) -HU2
 122   [ #H destruct /2 width=4/
 123   | * #l0 #Hkl0 #H destruct -l
 124     @(ex2_2_intro … (n+1) l0) /2 width=1 by deg_inv_prec/ >iter_SO //
 125   ]
 126 ]
 127 qed-.
 128
 129 lemma cpxs_inv_cast1: ∀h,g,L,W1,T1,U2. ⦃h, L⦄ ⊢ ⓝW1.T1 ➡*[g] U2 →
 130                       ∨∨ ∃∃W2,T2. ⦃h, L⦄ ⊢ W1 ➡*[g] W2 & ⦃h, L⦄ ⊢ T1 ➡*[g] T2 & U2 = ⓝW2.T2
 131                        | ⦃h, L⦄ ⊢ T1 ➡*[g] U2
 132                        | ⦃h, L⦄ ⊢ W1 ➡*[g] U2.
 133 #h #g #L #W1 #T1 #U2 #H @(cpxs_ind … H) -U2 /3 width=5/
 134 #U2 #U #_ #HU2 * /3 width=3/ *
 135 #W #T #HW1 #HT1 #H destruct
 136 elim (cpx_inv_cast1 … HU2) -HU2 /3 width=3/ *
 137 #W2 #T2 #HW2 #HT2 #H destruct
 138 lapply (cpxs_strap1 … HW1 … HW2) -W
 139 lapply (cpxs_strap1 … HT1 … HT2) -T /3 width=5/
 140 qed-.
 141
 142 lemma cpxs_inv_cnx1: ∀h,g,L,T,U. ⦃h, L⦄ ⊢ T ➡*[g] U → ⦃h, L⦄ ⊢ 𝐍[g]⦃T⦄ → T = U.
 143 #h #g #L #T #U #H @(cpxs_ind_dx … H) -T //
 144 #T0 #T #H1T0 #_ #IHT #H2T0
 145 lapply (H2T0 … H1T0) -H1T0 #H destruct /2 width=1/
 146 qed-.