matita/matita/contribs/lambdadelta/basic_2/computation/cpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predstar_6.ma".
  16 include "basic_2/reduction/cnx.ma".
  17 include "basic_2/computation/cprs.ma".
  18
  19 (* CONTEXT-SENSITIVE EXTENDED PARALLEL COMPUTATION ON TERMS *****************)
  20
  21 definition cpxs: ∀h. sd h → relation4 genv lenv term term ≝
  22                  λh,g,G. LTC … (cpx h g G).
  23
  24 interpretation "extended context-sensitive parallel computation (term)"
  25    'PRedStar h g G L T1 T2 = (cpxs h g G L T1 T2).
  26
  27 (* Basic eliminators ********************************************************)
  28
  29 lemma cpxs_ind: ∀h,g,G,L,T1. ∀R:predicate term. R T1 →
  30                 (∀T,T2. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T → ⦃G, L⦄ ⊢ T ➡[h, g] T2 → R T → R T2) →
  31                 ∀T2. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 → R T2.
  32 #h #g #L #G #T1 #R #HT1 #IHT1 #T2 #HT12
  33 @(TC_star_ind … HT1 IHT1 … HT12) //
  34 qed-.
  35
  36 lemma cpxs_ind_dx: ∀h,g,G,L,T2. ∀R:predicate term. R T2 →
  37                    (∀T1,T. ⦃G, L⦄ ⊢ T1 ➡[h, g] T → ⦃G, L⦄ ⊢ T ➡*[h, g] T2 → R T → R T1) →
  38                    ∀T1. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 → R T1.
  39 #h #g #G #L #T2 #R #HT2 #IHT2 #T1 #HT12
  40 @(TC_star_ind_dx … HT2 IHT2 … HT12) //
  41 qed-.
  42
  43 (* Basic properties *********************************************************)
  44
  45 lemma cpxs_refl: ∀h,g,G,L,T. ⦃G, L⦄ ⊢ T ➡*[h, g] T.
  46 /2 width=1/ qed.
  47
  48 lemma cpx_cpxs: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[h, g] T2 → ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2.
  49 /2 width=1/ qed.
  50
  51 lemma cpxs_strap1: ∀h,g,G,L,T1,T. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T →
  52                    ∀T2. ⦃G, L⦄ ⊢ T ➡[h, g] T2 → ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2.
  53 normalize /2 width=3/ qed.
  54
  55 lemma cpxs_strap2: ∀h,g,G,L,T1,T. ⦃G, L⦄ ⊢ T1 ➡[h, g] T →
  56                    ∀T2. ⦃G, L⦄ ⊢ T ➡*[h, g] T2 → ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2.
  57 normalize /2 width=3/ qed.
  58
  59 lemma lsubr_cpxs_trans: ∀h,g,G. lsub_trans … (cpxs h g G) lsubr.
  60 /3 width=5 by lsubr_cpx_trans, TC_lsub_trans/
  61 qed-.
  62
  63 lemma cprs_cpxs: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡* T2 → ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2.
  64 #h #g #G #L #T1 #T2 #H @(cprs_ind … H) -T2 // /3 width=3/
  65 qed.
  66
  67 lemma cpxs_bind_dx: ∀h,g,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h, g] V2 →
  68                     ∀I,T1,T2. ⦃G, L. ⓑ{I}V1⦄ ⊢ T1 ➡*[h, g] T2 →
  69                     ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡*[h, g] ⓑ{a,I}V2.T2.
  70 #h #g #G #L #V1 #V2 #HV12 #I #T1 #T2 #HT12 #a @(cpxs_ind_dx … HT12) -T1
  71 /3 width=1/ /3 width=3/
  72 qed.
  73
  74 lemma cpxs_flat_dx: ∀h,g,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h, g] V2 →
  75                     ∀T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 →
  76                     ∀I. ⦃G, L⦄ ⊢ ⓕ{I}V1.T1 ➡*[h, g] ⓕ{I}V2.T2.
  77 #h #g #G #L #V1 #V2 #HV12 #T1 #T2 #HT12 @(cpxs_ind … HT12) -T2 /3 width=1/ /3 width=5/
  78 qed.
  79
  80 lemma cpxs_flat_sn: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[h, g] T2 →
  81                     ∀V1,V2. ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 →
  82                     ∀I. ⦃G, L⦄ ⊢ ⓕ{I}V1.T1 ➡*[h, g] ⓕ{I}V2.T2.
  83 #h #g #G #L #T1 #T2 #HT12 #V1 #V2 #H @(cpxs_ind … H) -V2 /3 width=1/ /3 width=5/
  84 qed.
  85
  86 lemma cpxs_zeta: ∀h,g,G,L,V,T1,T,T2. ⇧[0, 1] T2 ≡ T →
  87                  ⦃G, L.ⓓV⦄ ⊢ T1 ➡*[h, g] T → ⦃G, L⦄ ⊢ +ⓓV.T1 ➡*[h, g] T2.
  88 #h #g #G #L #V #T1 #T #T2 #HT2 #H @(TC_ind_dx … T1 H) -T1 /3 width=3/
  89 qed.
  90
  91 lemma cpxs_tau: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 →
  92                 ∀V. ⦃G, L⦄ ⊢ ⓝV.T1 ➡*[h, g] T2.
  93 #h #g #G #L #T1 #T2 #H elim H -T2 /2 width=3/ /3 width=1/
  94 qed.
  95
  96 lemma cpxs_ti: ∀h,g,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 →
  97                ∀T. ⦃G, L⦄ ⊢ ⓝV1.T ➡*[h, g] V2.
  98 #h #g #G #L #V1 #V2 #H elim H -V2 /2 width=3/ /3 width=1/
  99 qed.
 100
 101 lemma cpxs_beta_dx: ∀h,g,a,G,L,V1,V2,W1,W2,T1,T2.
 102                     ⦃G, L⦄ ⊢ V1 ➡[h, g] V2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ➡*[h, g] T2 → ⦃G, L⦄ ⊢ W1 ➡[h, g] W2 →
 103                     ⦃G, L⦄ ⊢ ⓐV1.ⓛ{a}W1.T1 ➡*[h, g] ⓓ{a}ⓝW2.V2.T2.
 104 #h #g #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 * -T2 /3 width=1/
 105 /4 width=7 by cpxs_strap1, cpxs_bind_dx, cpxs_flat_dx, cpx_beta/ (**) (* auto too slow without trace *)
 106 qed.
 107
 108 lemma cpxs_theta_dx: ∀h,g,a,G,L,V1,V,V2,W1,W2,T1,T2.
 109                      ⦃G, L⦄ ⊢ V1 ➡[h, g] V → ⇧[0, 1] V ≡ V2 → ⦃G, L.ⓓW1⦄ ⊢ T1 ➡*[h, g] T2 →
 110                      ⦃G, L⦄ ⊢ W1 ➡[h, g] W2 → ⦃G, L⦄ ⊢ ⓐV1.ⓓ{a}W1.T1 ➡*[h, g] ⓓ{a}W2.ⓐV2.T2.
 111 #h #g #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 * -T2 [ /3 width=3/ ]
 112 /4 width=9 by cpxs_strap1, cpxs_bind_dx, cpxs_flat_dx, cpx_theta/ (**) (* auto too slow without trace *)
 113 qed.
 114
 115 (* Basic inversion lemmas ***************************************************)
 116
 117 lemma cpxs_inv_sort1: ∀h,g,G,L,U2,k. ⦃G, L⦄ ⊢ ⋆k ➡*[h, g] U2 →
 118                       ∃∃n,l. deg h g k (n+l) & U2 = ⋆((next h)^n k).
 119 #h #g #G #L #U2 #k #H @(cpxs_ind … H) -U2
 120 [ elim (deg_total h g k) #l #Hkl
 121   @(ex2_2_intro … 0 … Hkl) -Hkl //
 122 | #U #U2 #_ #HU2 * #n #l #Hknl #H destruct
 123   elim (cpx_inv_sort1 … HU2) -HU2
 124   [ #H destruct /2 width=4/
 125   | * #l0 #Hkl0 #H destruct -l
 126     @(ex2_2_intro … (n+1) l0) /2 width=1 by deg_inv_prec/ >iter_SO //
 127   ]
 128 ]
 129 qed-.
 130
 131 lemma cpxs_inv_cast1: ∀h,g,G,L,W1,T1,U2. ⦃G, L⦄ ⊢ ⓝW1.T1 ➡*[h, g] U2 →
 132                       ∨∨ ∃∃W2,T2. ⦃G, L⦄ ⊢ W1 ➡*[h, g] W2 & ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 & U2 = ⓝW2.T2
 133                        | ⦃G, L⦄ ⊢ T1 ➡*[h, g] U2
 134                        | ⦃G, L⦄ ⊢ W1 ➡*[h, g] U2.
 135 #h #g #G #L #W1 #T1 #U2 #H @(cpxs_ind … H) -U2 /3 width=5/
 136 #U2 #U #_ #HU2 * /3 width=3/ *
 137 #W #T #HW1 #HT1 #H destruct
 138 elim (cpx_inv_cast1 … HU2) -HU2 /3 width=3/ *
 139 #W2 #T2 #HW2 #HT2 #H destruct
 140 lapply (cpxs_strap1 … HW1 … HW2) -W
 141 lapply (cpxs_strap1 … HT1 … HT2) -T /3 width=5/
 142 qed-.
 143
 144 lemma cpxs_inv_cnx1: ∀h,g,G,L,T,U. ⦃G, L⦄ ⊢ T ➡*[h, g] U → ⦃G, L⦄ ⊢ 𝐍[h, g]⦃T⦄ → T = U.
 145 #h #g #G #L #T #U #H @(cpxs_ind_dx … H) -T //
 146 #T0 #T #H1T0 #_ #IHT #H2T0
 147 lapply (H2T0 … H1T0) -H1T0 #H destruct /2 width=1/
 148 qed-.