matita/matita/contribs/lambdadelta/basic_2/computation/csn_lpx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/tstc_tstc.ma".
  16 include "basic_2/computation/cpxs_cpxs.ma".
  17 include "basic_2/computation/csn_alt.ma".
  18 include "basic_2/computation/csn_lift.ma".
  19
  20 (* CONTEXT-SENSITIVE EXTENDED STRONGLY NORMALIZING TERMS ********************)
  21
  22 (* Advanced properties ******************************************************)
  23
  24 lemma csn_lpx_conf: ∀h,g,L1,L2. ⦃h, L1⦄ ⊢ ➡[g] L2 →
  25                     ∀T. ⦃h, L1⦄ ⊢ ⬊*[g] T → ⦃h, L2⦄ ⊢ ⬊*[g] T.
  26 #h #g #L1 #L2 #HL12 #T #H @(csn_ind_alt … H) -T #T #_ #IHT
  27 @csn_intro #T0 #HLT0 #HT0
  28 @IHT /2 width=2/ -IHT -HT0 /2 width=3 by lpx_cpx_trans/
  29 qed.
  30
  31 lemma csn_abst: ∀h,g,a,L,W. ⦃h, L⦄ ⊢ ⬊*[g] W →
  32                 ∀T. ⦃h, L.ⓛW⦄ ⊢ ⬊*[g] T → ⦃h, L⦄ ⊢ ⬊*[g] ⓛ{a}W.T.
  33 #h #g #a #L #W #HW @(csn_ind … HW) -W #W #_ #IHW #T #HT @(csn_ind … HT) -T #T #HT #IHT
  34 @csn_intro #X #H1 #H2
  35 elim (cpx_inv_abst1 … H1) -H1
  36 #W0 #T0 #HLW0 #HLT0 #H destruct
  37 elim (eq_false_inv_tpair_sn … H2) -H2
  38 [ -IHT #H lapply (csn_cpx_trans … HLT0) // -HT
  39   #HT0 lapply (csn_lpx_conf … (L.ⓛW0) … HT0) -HT0 /2 width=1/ /3 width=1/
  40 | -IHW -HLW0 -HT * #H destruct /3 width=1/
  41 ]
  42 qed.
  43
  44 lemma csn_abbr: ∀h,g,a,L,V. ⦃h, L⦄ ⊢ ⬊*[g] V →
  45                 ∀T. ⦃h, L.ⓓV⦄ ⊢ ⬊*[g] T → ⦃h, L⦄ ⊢ ⬊*[g] ⓓ{a}V. T.
  46 #h #g #a #L #V #HV elim HV -V #V #_ #IHV #T #HT @(csn_ind_alt … HT) -T #T #HT #IHT
  47 @csn_intro #X #H1 #H2
  48 elim (cpx_inv_abbr1 … H1) -H1 *
  49 [ #V1 #T1 #HLV1 #HLT1 #H destruct
  50   elim (eq_false_inv_tpair_sn … H2) -H2
  51   [ #HV1 @IHV // /2 width=1/ -HV1
  52     @(csn_lpx_conf … (L. ⓓV)) /2 width=1/ -HLV1 /2 width=3 by csn_cpx_trans/
  53   | -IHV -HLV1 * #H destruct /3 width=1/
  54   ]
  55 | -IHV -IHT -H2 #T0 #HLT0 #HT0
  56   lapply (csn_cpx_trans … HT … HLT0) -T #HLT0
  57   lapply (csn_inv_lift … HLT0 … HT0) -T0 /2 width=3/
  58 ]
  59 qed.
  60
  61 fact csn_appl_beta_aux: ∀h,g,a,L,U1. ⦃h, L⦄ ⊢ ⬊*[g] U1 →
  62                         ∀V,W,T1. U1 = ⓓ{a}ⓝW.V.T1 → ⦃h, L⦄ ⊢ ⬊*[g] ⓐV.ⓛ{a}W.T1.
  63 #h #g #a #L #X #H @(csn_ind … H) -X
  64 #X #HT1 #IHT1 #V #W #T1 #H1 destruct
  65 @csn_intro #X #H1 #H2
  66 elim (cpx_inv_appl1 … H1) -H1 *
  67 [ -HT1 #V0 #Y #HLV0 #H #H0 destruct
  68   elim (cpx_inv_abst1 … H) -H #W0 #T0 #HLW0 #HLT0 #H destruct
  69   @IHT1 -IHT1 [4: // | skip |3: #H destruct /2 width=1/ ] -H2
  70   lapply (lsubr_cpx_trans … HLT0 (L.ⓓⓝW.V) ?) -HLT0 [ /2 width=1/ ] /3 width=1/
  71 | -IHT1 -H2 #b #V0 #W0 #W2 #T0 #T2 #HLV0 #HLW02 #HLT02 #H1 #H3 destruct
  72   lapply (lsubr_cpx_trans … HLT02 (L.ⓓⓝW0.V) ?) -HLT02 [ /2 width=1/ ] #HT02
  73   @(csn_cpx_trans … HT1) -HT1 /3 width=1/
  74 | -HT1 -IHT1 -H2 #b #V0 #V1 #W0 #W1 #T0 #T3 #_ #_ #_ #_ #H destruct
  75 ]
  76 qed-.
  77
  78 (* Basic_1: was just: sn3_beta *)
  79 lemma csn_appl_beta: ∀h,g,a,L,V,W,T. ⦃h, L⦄ ⊢ ⬊*[g] ⓓ{a}ⓝW.V.T → ⦃h, L⦄ ⊢ ⬊*[g] ⓐV.ⓛ{a}W.T.
  80 /2 width=3 by csn_appl_beta_aux/ qed.
  81
  82 fact csn_appl_theta_aux: ∀h,g,a,L,U. ⦃h, L⦄ ⊢ ⬊*[g] U → ∀V1,V2. ⇧[0, 1] V1 ≡ V2 →
  83                          ∀V,T. U = ⓓ{a}V.ⓐV2.T → ⦃h, L⦄ ⊢ ⬊*[g] ⓐV1.ⓓ{a}V.T.
  84 #h #g #a #L #X #H @(csn_ind_alt … H) -X #X #HVT #IHVT #V1 #V2 #HV12 #V #T #H destruct
  85 lapply (csn_fwd_pair_sn … HVT) #HV
  86 lapply (csn_fwd_bind_dx … HVT) -HVT #HVT
  87 @csn_intro #X #HL #H
  88 elim (cpx_inv_appl1 … HL) -HL *
  89 [ -HV #V0 #Y #HLV10 #HL #H0 destruct
  90   elim (cpx_inv_abbr1 … HL) -HL *
  91   [ #V3 #T3 #HV3 #HLT3 #H0 destruct
  92     elim (lift_total V0 0 1) #V4 #HV04
  93     elim (term_eq_dec (ⓓ{a}V.ⓐV2.T) (ⓓ{a}V3.ⓐV4.T3))
  94     [ -IHVT #H0 destruct
  95       elim (eq_false_inv_tpair_sn … H) -H
  96       [ -HLV10 -HV3 -HLT3 -HVT
  97         >(lift_inj … HV12 … HV04) -V4
  98         #H elim H //
  99       | * #_ #H elim H //
 100       ]
 101     | -H -HVT #H
 102       lapply (cpx_lift … HLV10 (L. ⓓV) … HV12 … HV04) -HLV10 -HV12 /2 width=1/ #HV24
 103       @(IHVT … H … HV04) -IHVT // -H -HV04 /4 width=1/
 104     ]
 105   | -H -IHVT #T0 #HLT0 #HT0 #H0 destruct
 106     lapply (csn_cpx_trans … HVT (ⓐV2.T0) ?) /2 width=1/ -T #HVT0
 107     lapply (csn_inv_lift … L … 1 HVT0 ? ? ?) -HVT0 [ /2 width=4/ |2,3: skip | /2 width=1/ ] -V2 -T0 #HVY
 108     @(csn_cpx_trans … HVY) /2 width=1/
 109   ]
 110 | -HV -HV12 -HVT -IHVT -H #b #V0 #W0 #W1 #T0 #T1 #_ #_ #_ #H destruct
 111 | -IHVT -H #b #V0 #V3 #W0 #W1 #T0 #T1 #HLV10 #HV03 #HLW01 #HLT01 #H1 #H2 destruct
 112   lapply (cpx_lift … HLV10 (L. ⓓW0) … HV12 … HV03) -HLV10 -HV12 -HV03 /2 width=1/ #HLV23
 113   @csn_abbr /2 width=3 by csn_cpx_trans/ -HV
 114   @(csn_lpx_conf … (L. ⓓW0)) /2 width=1/ -W1
 115   @(csn_cpxs_trans … HVT) -HVT /3 width=1/
 116 ]
 117 qed-.
 118
 119 lemma csn_appl_theta: ∀h,g,a,V1,V2. ⇧[0, 1] V1 ≡ V2 →
 120                       ∀L,V,T. ⦃h, L⦄ ⊢ ⬊*[g] ⓓ{a}V.ⓐV2.T → ⦃h, L⦄ ⊢ ⬊*[g] ⓐV1.ⓓ{a}V.T.
 121 /2 width=5 by csn_appl_theta_aux/ qed.
 122
 123 (* Basic_1: was just: sn3_appl_appl *)
 124 lemma csn_appl_simple_tstc: ∀h,g,L,V. ⦃h, L⦄ ⊢ ⬊*[g] V → ∀T1. ⦃h, L⦄ ⊢ ⬊*[g] T1 →
 125                             (∀T2. ⦃h, L⦄ ⊢ T1 ➡*[g] T2 → (T1 ≃ T2 → ⊥) → ⦃h, L⦄ ⊢ ⬊*[g] ⓐV.T2) →
 126                             𝐒⦃T1⦄ → ⦃h, L⦄ ⊢ ⬊*[g] ⓐV.T1.
 127 #h #g #L #V #H @(csn_ind … H) -V #V #_ #IHV #T1 #H @(csn_ind … H) -T1 #T1 #H1T1 #IHT1 #H2T1 #H3T1
 128 @csn_intro #X #HL #H
 129 elim (cpx_inv_appl1_simple … HL) -HL //
 130 #V0 #T0 #HLV0 #HLT10 #H0 destruct
 131 elim (eq_false_inv_tpair_sn … H) -H
 132 [ -IHT1 #HV0
 133   @(csn_cpx_trans … (ⓐV0.T1)) /2 width=1/ -HLT10
 134   @IHV -IHV // -H1T1 -H3T1 /2 width=1/ -HV0
 135   #T2 #HLT12 #HT12
 136   @(csn_cpx_trans … (ⓐV.T2)) /2 width=1/ -HLV0
 137   @H2T1 -H2T1 // -HLT12 /2 width=1/
 138 | -IHV -H1T1 -HLV0 * #H #H1T10 destruct
 139   elim (tstc_dec T1 T0) #H2T10
 140   [ @IHT1 -IHT1 // /2 width=1/ -H1T10 /2 width=3/ -H3T1
 141     #T2 #HLT02 #HT02
 142     @H2T1 -H2T1 /2 width=3/ -HLT10 -HLT02 /3 width=3/
 143   | -IHT1 -H3T1 -H1T10
 144     @H2T1 -H2T1 /2 width=1/
 145   ]
 146 ]
 147 qed.