matita/matita/contribs/lambdadelta/basic_2/computation/fpbg.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/btpredstarproper_8.ma".
  16 include "basic_2/reduction/fpbc.ma".
  17 include "basic_2/computation/fpbs.ma".
  18
  19 (* "BIG TREE" PROPER PARALLEL COMPUTATION FOR CLOSURES **********************)
  20
  21 inductive fpbg (h) (g) (G1) (L1) (T1): relation3 genv lenv term ≝
  22 | fpbg_inj : ∀G,G2,L,L2,T,T2. ⦃G1, L1, T1⦄ ≥[h, g] ⦃G, L, T⦄ → ⦃G, L, T⦄ ≻[h, g] ⦃G2, L2, T2⦄ →
  23              fpbg h g G1 L1 T1 G2 L2 T2
  24 | fpbg_step: ∀G,L,L2,T. fpbg h g G1 L1 T1 G L T → ⦃G, L⦄ ⊢ ➡[h, g] L2 → fpbg h g G1 L1 T1 G L2 T
  25 .
  26
  27 interpretation "'big tree' proper parallel computation (closure)"
  28    'BTPRedStarProper h g G1 L1 T1 G2 L2 T2 = (fpbg h g G1 L1 T1 G2 L2 T2).
  29
  30 (* Basic forvard lemmas *****************************************************)
  31
  32 lemma fpbg_fwd_fpbs: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄ →
  33                      ⦃G1, L1, T1⦄ ≥[h, g] ⦃G2, L2, T2⦄.
  34 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G2 -L2 -T2
  35 /3 width=5 by fpbs_strap1, fpbc_fwd_fpb, fpb_lpx/
  36 qed-.
  37
  38 (* Basic properties *********************************************************)
  39
  40 lemma fpbc_fpbg: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≻[h, g] ⦃G2, L2, T2⦄ →
  41                  ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  42 /3 width=5 by fpbg_inj, fpbg_step/ qed.
  43
  44 lemma fpbg_strap1: ∀h,g,G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ >[h, g] ⦃G, L, T⦄ →
  45                    ⦃G, L, T⦄ ≽[h, g] ⦃G2, L2, T2⦄ →  ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  46 #h #g #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2
  47 lapply (fpbg_fwd_fpbs … H1) #H0
  48 elim (fpb_fpbc_or_fpn … H2) -H2 [| * #HG2 #HL2 #HT2 destruct ]
  49 /2 width=5 by fpbg_inj, fpbg_step/
  50 qed-.
  51
  52 lemma fpbg_strap2: ∀h,g,G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ ≽[h, g] ⦃G, L, T⦄ →
  53                    ⦃G, L, T⦄ >[h, g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  54 #h #g #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2 elim H2 -G2 -L2 -T2
  55 /3 width=5 by fpbg_step, fpbg_inj, fpbs_strap2/
  56 qed-.
  57
  58 lemma fpbg_fpbs_trans: ∀h,g,G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ >[h, g] ⦃G, L, T⦄ →
  59                        ⦃G, L, T⦄ ≥[h, g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  60 #h #g #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #HT1 #HT2 @(fpbs_ind … HT2) -G2 -L2 -T2
  61 /2 width=5 by fpbg_strap1/
  62 qed-.
  63
  64 lemma fpbs_fpbg_trans: ∀h,g,G1,G,L1,L,T1,T. ⦃G1, L1, T1⦄ ≥[h, g] ⦃G, L, T⦄ →
  65                        ∀G2,L2,T2. ⦃G, L, T⦄ >[h, g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  66 #h #g #G1 #G #L1 #L #T1 #T #HT1 @(fpbs_ind … HT1) -G -L -T
  67 /3 width=5 by fpbg_strap2/
  68 qed-.
  69
  70 lemma fqup_fpbg: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  71 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … L2 T2 H) -G2 -L2 -T2
  72 /4 width=5 by fpbg_strap1, fpbc_fpbg, fpbc_fqu, fpb_fquq, fqu_fquq/
  73 qed.
  74
  75 lemma cpxs_fpbg: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 → (T1 = T2 → ⊥) →
  76                  ⦃G, L, T1⦄ >[h, g] ⦃G, L, T2⦄.
  77 #h #g #G #L #T1 #T2 #H @(cpxs_ind … H) -T2
  78 [ #H elim H //
  79 | #T #T2 #_ #HT2 #IHT1 #HT12
  80   elim (term_eq_dec T1 T) #H destruct
  81   [ -IHT1 /4 width=1/
  82   | lapply (IHT1 … H) -IHT1 -H -HT12 #HT1
  83     @(fpbg_strap1 … HT1) -HT1 /2 width=1 by fpb_cpx/
  84   ]
  85 ]
  86 qed.
  87
  88 lemma cprs_fpbg: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡* T2 → (T1 = T2 → ⊥) →
  89                  ⦃G, L, T1⦄ >[h, g] ⦃G, L, T2⦄.
  90 /3 width=1 by cprs_cpxs, cpxs_fpbg/ qed.