matita/matita/contribs/lambdadelta/basic_2/computation/fpbg.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/btpredstarproper_8.ma".
  16 include "basic_2/substitution/fqup.ma".
  17 include "basic_2/reduction/fpbc.ma".
  18 include "basic_2/computation/fpbs.ma".
  19
  20 (* "BIG TREE" PROPER PARALLEL COMPUTATION FOR CLOSURES **********************)
  21
  22 inductive fpbg (h) (g) (G1) (L1) (T1): relation3 genv lenv term ≝
  23 | fpbg_inj : ∀G,G2,L,L2,T,T2. ⦃G1, L1, T1⦄ ≥[h, g] ⦃G, L, T⦄ → ⦃G, L, T⦄ ≻[h, g] ⦃G2, L2, T2⦄ →
  24              fpbg h g G1 L1 T1 G2 L2 T2
  25 | fpbg_step: ∀G,L,L2,T. fpbg h g G1 L1 T1 G L T → ⦃G, L⦄ ⊢ ➡[h, g] L2 → fpbg h g G1 L1 T1 G L2 T
  26 .
  27
  28 interpretation "'big tree' proper parallel computation (closure)"
  29    'BTPRedStarProper h g G1 L1 T1 G2 L2 T2 = (fpbg h g G1 L1 T1 G2 L2 T2).
  30
  31 (* Basic forvard lemmas *****************************************************)
  32
  33 lemma fpbg_fwd_fpbs: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄ →
  34                      ⦃G1, L1, T1⦄ ≥[h, g] ⦃G2, L2, T2⦄.
  35 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G2 -L2 -T2
  36 /3 width=5 by fpbs_strap1, fpbc_fpb, fpb_lpx/
  37 qed-.
  38
  39 (* Basic properties *********************************************************)
  40
  41 lemma fpbc_fpbg: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≻[h, g] ⦃G2, L2, T2⦄ →
  42                  ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  43 /3 width=5 by fpbg_inj, fpbg_step/ qed.
  44
  45 lemma fpbg_strap1: ∀h,g,G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ >[h, g] ⦃G, L, T⦄ →
  46                    ⦃G, L, T⦄ ≽[h, g] ⦃G2, L2, T2⦄ →  ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  47 #h #g #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2
  48 lapply (fpbg_fwd_fpbs … H1) #H0
  49 elim (fpb_inv_fpbc … H2) -H2 [| * #HG2 #HL2 #HT2 destruct ]
  50 /2 width=5 by fpbg_inj, fpbg_step/
  51 qed-.
  52
  53 lemma fpbg_strap2: ∀h,g,G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ ≽[h, g] ⦃G, L, T⦄ →
  54                    ⦃G, L, T⦄ >[h, g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  55 #h #g #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2 elim H2 -G2 -L2 -T2
  56 /3 width=5 by fpbg_step, fpbg_inj, fpbs_strap2/
  57 qed-.
  58
  59 lemma fpbg_fpbs_trans: ∀h,g,G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ >[h, g] ⦃G, L, T⦄ →
  60                        ⦃G, L, T⦄ ≥[h, g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  61 #h #g #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #HT1 #HT2 @(fpbs_ind … HT2) -G2 -L2 -T2
  62 /2 width=5 by fpbg_strap1/
  63 qed-.
  64
  65 lemma fpbs_fpbg_trans: ∀h,g,G1,G,L1,L,T1,T. ⦃G1, L1, T1⦄ ≥[h, g] ⦃G, L, T⦄ →
  66                        ∀G2,L2,T2. ⦃G, L, T⦄ >[h, g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  67 #h #g #G1 #G #L1 #L #T1 #T #HT1 @(fpbs_ind … HT1) -G -L -T
  68 /3 width=5 by fpbg_strap2/
  69 qed-.
  70
  71 lemma fqup_fpbg: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >[h, g] ⦃G2, L2, T2⦄.
  72 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … L2 T2 H) -G2 -L2 -T2
  73 /4 width=5 by fpbg_strap1, fpbc_fpbg, fpbc_fqu, fpb_fquq, fqu_fquq/
  74 qed.
  75
  76 lemma cpxs_fpbg: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 → (T1 = T2 → ⊥) →
  77                  ⦃G, L, T1⦄ >[h, g] ⦃G, L, T2⦄.
  78 #h #g #G #L #T1 #T2 #H @(cpxs_ind … H) -T2
  79 [ #H elim H //
  80 | #T #T2 #_ #HT2 #IHT1 #HT12
  81   elim (term_eq_dec T1 T) #H destruct
  82   [ -IHT1 /4 width=1/
  83   | lapply (IHT1 … H) -IHT1 -H -HT12 #HT1
  84     @(fpbg_strap1 … HT1) -HT1 /2 width=1 by fpb_cpx/
  85   ]
  86 ]
  87 qed.
  88
  89 lemma cprs_fpbg: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡* T2 → (T1 = T2 → ⊥) →
  90                  ⦃G, L, T1⦄ >[h, g] ⦃G, L, T2⦄.
  91 /3 width=1 by cprs_cpxs, cpxs_fpbg/ qed.