matita/matita/contribs/lambdadelta/basic_2/computation/fsb_alt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/btsnalt_5.ma".
  16 include "basic_2/computation/fpbg_fpbg.ma".
  17 include "basic_2/computation/fsb.ma".
  18
  19 (* "BIG TREE" STRONGLY NORMALIZING TERMS ************************************)
  20
  21 (* Note: alternative definition of fsb *)
  22 inductive fsba (h) (g): relation3 genv lenv term ≝
  23 | fsba_intro: ∀G1,L1,T1. (
  24                  ∀G2,L2,T2. ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄ → fsba h g G2 L2 T2
  25               ) → fsba h g G1 L1 T1.
  26
  27 interpretation
  28    "'big tree' strong normalization (closure) alternative"
  29    'BTSNAlt h g G L T = (fsba h g G L T).
  30
  31 (* Basic eliminators ********************************************************)
  32
  33 lemma fsba_ind_alt: ∀h,g. ∀R: relation3 …. (
  34                        ∀G1,L1,T1. ⦃G1, L1⦄ ⊢ ⦥⦥[h,g] T1 → (
  35                           ∀G2,L2,T2. ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄ → R G2 L2 T2
  36                        ) → R G1 L1 T1
  37                     ) →
  38                     ∀G,L,T. ⦃G, L⦄ ⊢ ⦥⦥[h, g] T → R G L T.
  39 #h #g #R #IH #G #L #T #H elim H -G -L -T
  40 /4 width=1 by fsba_intro/
  41 qed-.
  42
  43 (* Basic properties *********************************************************)
  44
  45 lemma fsba_fpbs_trans: ∀h,g,G1,L1,T1. ⦃G1, L1⦄ ⊢ ⦥⦥[h, g] T1 →
  46                        ∀G2,L2,T2. ⦃G1, L1, T1⦄ ≥[h, g] ⦃G2, L2, T2⦄ → ⦃G2, L2⦄ ⊢ ⦥⦥[h, g] T2.
  47 #h #g #G1 #L1 #T1 #H @(fsba_ind_alt … H) -G1 -L1 -T1
  48 /4 width=5 by fsba_intro, fpbs_fpbg_trans/
  49 qed-.
  50
  51 (* Main properties **********************************************************)
  52
  53 theorem fsb_fsba: ∀h,g,G,L,T. ⦃G, L⦄ ⊢ ⦥[h, g] T → ⦃G, L⦄ ⊢ ⦥⦥[h, g] T.
  54 #h #g #G #L #T #H @(fsb_ind_alt … H) -G -L -T
  55 #G1 #L1 #T1 #_ #IH @fsba_intro
  56 #G2 #L2 #T2 #H elim (fpbg_inv_fpbu_sn … H) -H
  57 /3 width=5 by fsba_fpbs_trans/
  58 qed.
  59
  60 (* Main inversion lemmas ****************************************************)
  61
  62 theorem fsba_inv_fsb: ∀h,g,G,L,T. ⦃G, L⦄ ⊢ ⦥⦥[h, g] T → ⦃G, L⦄ ⊢ ⦥[h, g] T.
  63 #h #g #G #L #T #H @(fsba_ind_alt … H) -G -L -T
  64 /5 width=1 by fsb_intro, fpbc_fpbg, fpbu_fpbc/
  65 qed-.
  66
  67 (* Advanced properties ******************************************************)
  68
  69 lemma fsb_fpbs_trans: ∀h,g,G1,L1,T1. ⦃G1, L1⦄ ⊢ ⦥[h, g] T1 →
  70                       ∀G2,L2,T2. ⦃G1, L1, T1⦄ ≥[h, g] ⦃G2, L2, T2⦄ → ⦃G2, L2⦄ ⊢ ⦥[h, g] T2.
  71 /4 width=5 by fsba_inv_fsb, fsb_fsba, fsba_fpbs_trans/ qed-.
  72
  73 (* Advanced eliminators *****************************************************)
  74
  75 lemma fsb_ind_fpbg: ∀h,g. ∀R:relation3 genv lenv term.
  76                     (∀G1,L1,T1. ⦃G1, L1⦄ ⊢ ⦥[h, g] T1 →
  77                                 (∀G2,L2,T2. ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄ → R G2 L2 T2) →
  78                                 R G1 L1 T1
  79                     ) →
  80                     ∀G1,L1,T1. ⦃G1, L1⦄ ⊢ ⦥[h, g] T1 → R G1 L1 T1.
  81 #h #g #R #IH #G1 #L1 #T1 #H @(fsba_ind_alt h g … G1 L1 T1)
  82 /3 width=1 by fsba_inv_fsb, fsb_fsba/
  83 qed-.