matita/matita/contribs/lambdadelta/basic_2/computation/lprs_cprs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/computation/cprs_cprs.ma".
  16 include "basic_2/computation/lprs.ma".
  17
  18 (* SN PARALLEL COMPUTATION ON LOCAL ENVIRONMENTS ****************************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma lprs_pair: ∀I,G,L1,L2. ⦃G, L1⦄ ⊢ ➡* L2 →
  23                  ∀V1,V2. ⦃G, L1⦄ ⊢ V1 ➡* V2 → ⦃G, L1.ⓑ{I}V1⦄ ⊢ ➡* L2.ⓑ{I}V2.
  24 /2 width=1 by TC_lpx_sn_pair/ qed.
  25
  26 (* Advanced inversion lemmas ************************************************)
  27
  28 lemma lprs_inv_pair1: ∀I,G,K1,L2,V1. ⦃G, K1.ⓑ{I}V1⦄ ⊢ ➡* L2 →
  29                       ∃∃K2,V2. ⦃G, K1⦄ ⊢ ➡* K2 & ⦃G, K1⦄ ⊢ V1 ➡* V2 &
  30                                L2 = K2.ⓑ{I}V2.
  31 /3 width=3 by TC_lpx_sn_inv_pair1, lpr_cprs_trans/ qed-.
  32
  33 lemma lprs_inv_pair2: ∀I,G,L1,K2,V2. ⦃G, L1⦄ ⊢ ➡* K2.ⓑ{I}V2 →
  34                       ∃∃K1,V1. ⦃G, K1⦄ ⊢ ➡* K2 & ⦃G, K1⦄ ⊢ V1 ➡* V2 &
  35                                L1 = K1.ⓑ{I}V1.
  36 /3 width=3 by TC_lpx_sn_inv_pair2, lpr_cprs_trans/ qed-.
  37
  38 (* Properties on context-sensitive parallel computation for terms ***********)
  39
  40 lemma lprs_cpr_trans: ∀G. s_r_transitive … (cpr G) (λ_. lprs G).
  41 /3 width=5 by s_r_trans_LTC2, lpr_cprs_trans/ qed-.
  42
  43 (* Basic_1: was just: pr3_pr3_pr3_t *)
  44 (* Note: alternative proof /3 width=5 by s_r_trans_LTC1, lprs_cpr_trans/ *)
  45 lemma lprs_cprs_trans: ∀G. s_rs_transitive … (cpr G) (λ_. lprs G).
  46 #G @s_r_to_s_rs_trans @s_r_trans_LTC2
  47 @s_rs_trans_TC1 /2 width=3 by lpr_cprs_trans/ (**) (* full auto too slow *)
  48 qed-.
  49
  50 lemma lprs_cprs_conf_dx: ∀G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ➡* T1 →
  51                          ∀L1. ⦃G, L0⦄ ⊢ ➡* L1 →
  52                          ∃∃T. ⦃G, L1⦄ ⊢ T1 ➡* T & ⦃G, L1⦄ ⊢ T0 ➡* T.
  53 #G #L0 #T0 #T1 #HT01 #L1 #H @(lprs_ind … H) -L1 /2 width=3 by ex2_intro/
  54 #L #L1 #_ #HL1 * #T #HT1 #HT0 -L0
  55 elim (cprs_lpr_conf_dx … HT1 … HL1) -HT1 #T2 #HT2
  56 elim (cprs_lpr_conf_dx … HT0 … HL1) -L #T3 #HT3
  57 elim (cprs_conf … HT2 … HT3) -T
  58 /3 width=5 by cprs_trans, ex2_intro/
  59 qed-.
  60
  61 lemma lprs_cpr_conf_dx: ∀G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ➡ T1 →
  62                         ∀L1. ⦃G, L0⦄ ⊢ ➡* L1 →
  63                         ∃∃T. ⦃G, L1⦄ ⊢ T1 ➡* T & ⦃G, L1⦄ ⊢ T0 ➡* T.
  64 /3 width=3 by lprs_cprs_conf_dx, cpr_cprs/ qed-.
  65
  66 (* Note: this can be proved on its own using lprs_ind_dx *)
  67 lemma lprs_cprs_conf_sn: ∀G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ➡* T1 →
  68                          ∀L1. ⦃G, L0⦄ ⊢ ➡* L1 →
  69                          ∃∃T. ⦃G, L0⦄ ⊢ T1 ➡* T & ⦃G, L1⦄ ⊢ T0 ➡* T.
  70 #G #L0 #T0 #T1 #HT01 #L1 #HL01
  71 elim (lprs_cprs_conf_dx … HT01 … HL01) -HT01
  72 /3 width=3 by lprs_cprs_trans, ex2_intro/
  73 qed-.
  74
  75 lemma lprs_cpr_conf_sn: ∀G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ➡ T1 →
  76                         ∀L1. ⦃G, L0⦄ ⊢ ➡* L1 →
  77                         ∃∃T. ⦃G, L0⦄ ⊢ T1 ➡* T & ⦃G, L1⦄ ⊢ T0 ➡* T.
  78 /3 width=3 by lprs_cprs_conf_sn, cpr_cprs/ qed-.
  79
  80 lemma cprs_bind2: ∀G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡* V2 →
  81                   ∀I,T1,T2. ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ➡* T2 →
  82                   ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡* ⓑ{a,I}V2.T2.
  83 /4 width=5 by lprs_cprs_trans, lprs_pair, cprs_bind/ qed.
  84
  85 (* Inversion lemmas on context-sensitive parallel computation for terms *****)
  86
  87 (* Basic_1: was: pr3_gen_abst *)
  88 lemma cprs_inv_abst1: ∀a,G,L,W1,T1,U2. ⦃G, L⦄ ⊢ ⓛ{a}W1.T1 ➡* U2 →
  89                       ∃∃W2,T2. ⦃G, L⦄ ⊢ W1 ➡* W2 & ⦃G, L.ⓛW1⦄ ⊢ T1 ➡* T2 &
  90                                U2 = ⓛ{a}W2.T2.
  91 #a #G #L #V1 #T1 #U2 #H @(cprs_ind … H) -U2 /2 width=5 by ex3_2_intro/
  92 #U0 #U2 #_ #HU02 * #V0 #T0 #HV10 #HT10 #H destruct
  93 elim (cpr_inv_abst1 … HU02) -HU02 #V2 #T2 #HV02 #HT02 #H destruct
  94 lapply (lprs_cpr_trans … HT02 (L.ⓛV1) ?)
  95 /3 width=5 by lprs_pair, cprs_trans, cprs_strap1, ex3_2_intro/
  96 qed-.
  97
  98 lemma cprs_inv_abst: ∀a,G,L,W1,W2,T1,T2. ⦃G, L⦄ ⊢ ⓛ{a}W1.T1 ➡* ⓛ{a}W2.T2 →
  99                      ⦃G, L⦄ ⊢ W1 ➡* W2 ∧ ⦃G, L.ⓛW1⦄ ⊢ T1 ➡* T2.
 100 #a #G #L #W1 #W2 #T1 #T2 #H elim (cprs_inv_abst1 … H) -H
 101 #W #T #HW1 #HT1 #H destruct /2 width=1 by conj/
 102 qed-.
 103
 104 (* Basic_1: was pr3_gen_abbr *)
 105 lemma cprs_inv_abbr1: ∀a,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓓ{a}V1.T1 ➡* U2 → (
 106                       ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡* V2 & ⦃G, L.ⓓV1⦄ ⊢ T1 ➡* T2 &
 107                                U2 = ⓓ{a}V2.T2
 108                       ) ∨
 109                       ∃∃T2. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡* T2 & ⇧[0, 1] U2 ≡ T2 & a = true.
 110 #a #G #L #V1 #T1 #U2 #H @(cprs_ind … H) -U2 /3 width=5 by ex3_2_intro, or_introl/
 111 #U0 #U2 #_ #HU02 * *
 112 [ #V0 #T0 #HV10 #HT10 #H destruct
 113   elim (cpr_inv_abbr1 … HU02) -HU02 *
 114   [ #V2 #T2 #HV02 #HT02 #H destruct
 115     lapply (lprs_cpr_trans … HT02 (L.ⓓV1) ?)
 116     /4 width=5 by lprs_pair, cprs_trans, cprs_strap1, ex3_2_intro, or_introl/
 117   | #T2 #HT02 #HUT2
 118     lapply (lprs_cpr_trans … HT02 (L.ⓓV1) ?) -HT02
 119     /4 width=3 by lprs_pair, cprs_trans, ex3_intro, or_intror/
 120   ]
 121 | #U1 #HTU1 #HU01 elim (lift_total U2 0 1)
 122   #U #HU2 lapply (cpr_lift … HU02 (L.ⓓV1) … HU01 … HU2) -U0
 123   /4 width=3 by cprs_strap1, ldrop_drop, ex3_intro, or_intror/
 124 ]
 125 qed-.
 126
 127 (* More advanced properties *************************************************)
 128
 129 lemma lprs_pair2: ∀I,G,L1,L2. ⦃G, L1⦄ ⊢ ➡* L2 →
 130                   ∀V1,V2. ⦃G, L2⦄ ⊢ V1 ➡* V2 → ⦃G, L1.ⓑ{I}V1⦄ ⊢ ➡* L2.ⓑ{I}V2.
 131 /3 width=3 by lprs_pair, lprs_cprs_trans/ qed.