matita/matita/contribs/lambdadelta/basic_2/computation/lpxs_cpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/computation/cpxs_cpxs.ma".
  16 include "basic_2/computation/lpxs.ma".
  17
  18 (* SN EXTENDED PARALLEL COMPUTATION ON LOCAL ENVIRONMENTS *******************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma lpxs_pair: ∀h,g,I,G,L1,L2. ⦃G, L1⦄ ⊢ ➡*[h, g] L2 →
  23                  ∀V1,V2. ⦃G, L1⦄ ⊢ V1 ➡*[h, g] V2 →
  24                  ⦃G, L1.ⓑ{I}V1⦄ ⊢ ➡*[h, g] L2.ⓑ{I}V2.
  25 /2 width=1 by TC_lpx_sn_pair/ qed.
  26
  27 (* Advanced inversion lemmas ************************************************)
  28
  29 lemma lpxs_inv_pair1: ∀h,g,I,G,K1,L2,V1. ⦃G, K1.ⓑ{I}V1⦄ ⊢ ➡*[h, g] L2 →
  30                       ∃∃K2,V2. ⦃G, K1⦄ ⊢ ➡*[h, g] K2 & ⦃G, K1⦄ ⊢ V1 ➡*[h, g] V2 & L2 = K2.ⓑ{I}V2.
  31 /3 width=3 by TC_lpx_sn_inv_pair1, lpx_cpxs_trans/ qed-.
  32
  33 lemma lpxs_inv_pair2: ∀h,g,I,G,L1,K2,V2. ⦃G, L1⦄ ⊢ ➡*[h, g] K2.ⓑ{I}V2 →
  34                       ∃∃K1,V1. ⦃G, K1⦄ ⊢ ➡*[h, g] K2 & ⦃G, K1⦄ ⊢ V1 ➡*[h, g] V2 & L1 = K1.ⓑ{I}V1.
  35 /3 width=3 by TC_lpx_sn_inv_pair2, lpx_cpxs_trans/ qed-.
  36
  37 (* Properties on context-sensitive extended parallel computation for terms **)
  38
  39 lemma lpxs_cpx_trans: ∀h,g,G. s_r_transitive … (cpx h g G) (λ_.lpxs h g G).
  40 /3 width=5 by s_r_trans_LTC2, lpx_cpxs_trans/ qed-.
  41
  42 (* Note: alternative proof: /3 width=5 by s_r_trans_TC1, lpxs_cpx_trans/ *)
  43 lemma lpxs_cpxs_trans: ∀h,g,G. s_rs_transitive … (cpx h g G) (λ_.lpxs h g G).
  44 #h #g #G @s_r_to_s_rs_trans @s_r_trans_LTC2
  45 @s_rs_trans_TC1 /2 width=3 by lpx_cpxs_trans/ (**) (* full auto too slow *)
  46 qed-.
  47
  48 lemma cpxs_bind2: ∀h,g,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 →
  49                   ∀I,T1,T2. ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ➡*[h, g] T2 →
  50                   ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡*[h, g] ⓑ{a,I}V2.T2.
  51 /4 width=5 by lpxs_cpxs_trans, lpxs_pair, cpxs_bind/ qed.
  52
  53 (* Inversion lemmas on context-sensitive ext parallel computation for terms *)
  54
  55 lemma cpxs_inv_abst1: ∀h,g,a,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓛ{a}V1.T1 ➡*[h, g] U2 →
  56                       ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 & ⦃G, L.ⓛV1⦄ ⊢ T1 ➡*[h, g] T2 &
  57                                U2 = ⓛ{a}V2.T2.
  58 #h #g #a #G #L #V1 #T1 #U2 #H @(cpxs_ind … H) -U2 /2 width=5 by ex3_2_intro/
  59 #U0 #U2 #_ #HU02 * #V0 #T0 #HV10 #HT10 #H destruct
  60 elim (cpx_inv_abst1 … HU02) -HU02 #V2 #T2 #HV02 #HT02 #H destruct
  61 lapply (lpxs_cpx_trans … HT02 (L.ⓛV1) ?)
  62 /3 width=5 by lpxs_pair, cpxs_trans, cpxs_strap1, ex3_2_intro/
  63 qed-.
  64
  65 lemma cpxs_inv_abbr1: ∀h,g,a,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓓ{a}V1.T1 ➡*[h, g] U2 → (
  66                       ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 & ⦃G, L.ⓓV1⦄ ⊢ T1 ➡*[h, g] T2 &
  67                                U2 = ⓓ{a}V2.T2
  68                       ) ∨
  69                       ∃∃T2. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡*[h, g] T2 & ⇧[0, 1] U2 ≡ T2 & a = true.
  70 #h #g #a #G #L #V1 #T1 #U2 #H @(cpxs_ind … H) -U2 /3 width=5 by ex3_2_intro, or_introl/
  71 #U0 #U2 #_ #HU02 * *
  72 [ #V0 #T0 #HV10 #HT10 #H destruct
  73   elim (cpx_inv_abbr1 … HU02) -HU02 *
  74   [ #V2 #T2 #HV02 #HT02 #H destruct
  75     lapply (lpxs_cpx_trans … HT02 (L.ⓓV1) ?)
  76     /4 width=5 by lpxs_pair, cpxs_trans, cpxs_strap1, ex3_2_intro, or_introl/
  77   | #T2 #HT02 #HUT2
  78     lapply (lpxs_cpx_trans … HT02 (L.ⓓV1) ?) -HT02
  79     /4 width=3 by lpxs_pair, cpxs_trans, ex3_intro, or_intror/
  80   ]
  81 | #U1 #HTU1 #HU01
  82   elim (lift_total U2 0 1) #U #HU2
  83   /6 width=12 by cpxs_strap1, cpx_lift, ldrop_drop, ex3_intro, or_intror/
  84 ]
  85 qed-.
  86
  87 (* More advanced properties *************************************************)
  88
  89 lemma lpxs_pair2: ∀h,g,I,G,L1,L2. ⦃G, L1⦄ ⊢ ➡*[h, g] L2 →
  90                   ∀V1,V2. ⦃G, L2⦄ ⊢ V1 ➡*[h, g] V2 → ⦃G, L1.ⓑ{I}V1⦄ ⊢ ➡*[h, g] L2.ⓑ{I}V2.
  91 /3 width=3 by lpxs_pair, lpxs_cpxs_trans/ qed.
  92
  93 (* Properties on supclosure *************************************************)
  94
  95 lemma lpx_fqup_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ →
  96                       ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 →
  97                       ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ➡*[h, g] T & ⦃G1, K1, T⦄ ⊃+ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2.
  98 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
  99 [ #G2 #L2 #T2 #H12 #K1 #HKL1 elim (lpx_fqu_trans … H12 … HKL1) -L1
 100   /3 width=5 by cpx_cpxs, fqu_fqup, ex3_2_intro/
 101 | #G #G2 #L #L2 #T #T2 #_ #H2 #IH1 #K1 #HLK1 elim (IH1 … HLK1) -L1
 102   #L0 #T0 #HT10 #HT0 #HL0 elim (lpx_fqu_trans … H2 … HL0) -L
 103   #L #T3 #HT3 #HT32 #HL2 elim (fqup_cpx_trans … HT0 … HT3) -T
 104   /3 width=7 by cpxs_strap1, fqup_strap1, ex3_2_intro/
 105 ]
 106 qed-.
 107
 108 lemma lpx_fqus_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄ →
 109                       ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 →
 110                       ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ➡*[h, g] T & ⦃G1, K1, T⦄ ⊃* ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2.
 111 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqus_ind … H) -G2 -L2 -T2 /2 width=5 by ex3_2_intro/
 112 #G #G2 #L #L2 #T #T2 #_ #H2 #IH1 #K1 #HLK1 elim (IH1 … HLK1) -L1
 113 #L0 #T0 #HT10 #HT0 #HL0 elim (lpx_fquq_trans … H2 … HL0) -L
 114 #L #T3 #HT3 #HT32 #HL2 elim (fqus_cpx_trans … HT0 … HT3) -T
 115 /3 width=7 by cpxs_strap1, fqus_strap1, ex3_2_intro/
 116 qed-.
 117
 118 lemma lpxs_fquq_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃⸮ ⦃G2, L2, T2⦄ →
 119                        ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, g] L1 →
 120                        ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ➡*[h, g] T & ⦃G1, K1, T⦄ ⊃⸮ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, g] L2.
 121 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #HT12 #K1 #H @(lpxs_ind_dx … H) -K1
 122 [ /2 width=5 by ex3_2_intro/
 123 | #K1 #K #HK1 #_ * #L #T #HT1 #HT2 #HL2 -HT12
 124   lapply (lpx_cpxs_trans … HT1 … HK1) -HT1
 125   elim (lpx_fquq_trans … HT2 … HK1) -K
 126   /3 width=7 by lpxs_strap2, cpxs_strap1, ex3_2_intro/
 127 ]
 128 qed-.
 129
 130 lemma lpxs_fqup_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ →
 131                        ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, g] L1 →
 132                        ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ➡*[h, g] T & ⦃G1, K1, T⦄ ⊃+ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, g] L2.
 133 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #HT12 #K1 #H @(lpxs_ind_dx … H) -K1
 134 [ /2 width=5 by ex3_2_intro/
 135 | #K1 #K #HK1 #_ * #L #T #HT1 #HT2 #HL2 -HT12
 136   lapply (lpx_cpxs_trans … HT1 … HK1) -HT1
 137   elim (lpx_fqup_trans … HT2 … HK1) -K
 138   /3 width=7 by lpxs_strap2, cpxs_trans, ex3_2_intro/
 139 ]
 140 qed-.
 141
 142 lemma lpxs_fqus_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄ →
 143                        ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, g] L1 →
 144                        ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ➡*[h, g] T & ⦃G1, K1, T⦄ ⊃* ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, g] L2.
 145 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqus_ind … H) -G2 -L2 -T2 /2 width=5 by ex3_2_intro/
 146 #G #G2 #L #L2 #T #T2 #_ #H2 #IH1 #K1 #HLK1 elim (IH1 … HLK1) -L1
 147 #L0 #T0 #HT10 #HT0 #HL0 elim (lpxs_fquq_trans … H2 … HL0) -L
 148 #L #T3 #HT3 #HT32 #HL2 elim (fqus_cpxs_trans … HT3 … HT0) -T
 149 /3 width=7 by cpxs_trans, fqus_strap1, ex3_2_intro/
 150 qed-.