matita/matita/contribs/lambdadelta/basic_2/computation/lpxs_cpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/computation/cpxs_cpxs.ma".
  16 include "basic_2/computation/lpxs.ma".
  17
  18 (* SN EXTENDED PARALLEL COMPUTATION ON LOCAL ENVIRONMENTS *******************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma lpxs_pair: ∀h,g,I,G,L1,L2. ⦃G, L1⦄ ⊢ ➡*[h, g] L2 →
  23                  ∀V1,V2. ⦃G, L1⦄ ⊢ V1 ➡*[h, g] V2 →
  24                  ⦃G, L1.ⓑ{I}V1⦄ ⊢ ➡*[h, g] L2.ⓑ{I}V2.
  25 /2 width=1 by TC_lpx_sn_pair/ qed.
  26
  27 (* Advanced inversion lemmas ************************************************)
  28
  29 lemma lpxs_inv_pair1: ∀h,g,I,G,K1,L2,V1. ⦃G, K1.ⓑ{I}V1⦄ ⊢ ➡*[h, g] L2 →
  30                       ∃∃K2,V2. ⦃G, K1⦄ ⊢ ➡*[h, g] K2 & ⦃G, K1⦄ ⊢ V1 ➡*[h, g] V2 & L2 = K2.ⓑ{I}V2.
  31 /3 width=3 by TC_lpx_sn_inv_pair1, lpx_cpxs_trans/ qed-.
  32
  33 lemma lpxs_inv_pair2: ∀h,g,I,G,L1,K2,V2. ⦃G, L1⦄ ⊢ ➡*[h, g] K2.ⓑ{I}V2 →
  34                       ∃∃K1,V1. ⦃G, K1⦄ ⊢ ➡*[h, g] K2 & ⦃G, K1⦄ ⊢ V1 ➡*[h, g] V2 & L1 = K1.ⓑ{I}V1.
  35 /3 width=3 by TC_lpx_sn_inv_pair2, lpx_cpxs_trans/ qed-.
  36
  37 (* Properties on context-sensitive extended parallel computation for terms **)
  38
  39 lemma lpxs_cpx_trans: ∀h,g,G. s_r_trans … (cpx h g G) (lpxs h g G).
  40 /3 width=5 by s_r_trans_TC2, lpx_cpxs_trans/ qed-.
  41
  42 lemma lpxs_cpxs_trans: ∀h,g,G. s_rs_trans … (cpx h g G) (lpxs h g G).
  43 /3 width=5 by s_r_trans_TC1, lpxs_cpx_trans/ qed-.
  44
  45 lemma cpxs_bind2: ∀h,g,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 →
  46                   ∀I,T1,T2. ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ➡*[h, g] T2 →
  47                   ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡*[h, g] ⓑ{a,I}V2.T2.
  48 /4 width=5 by lpxs_cpxs_trans, lpxs_pair, cpxs_bind/ qed.
  49
  50 (* Inversion lemmas on context-sensitive ext parallel computation for terms *)
  51
  52 lemma cpxs_inv_abst1: ∀h,g,a,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓛ{a}V1.T1 ➡*[h, g] U2 →
  53                       ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 & ⦃G, L.ⓛV1⦄ ⊢ T1 ➡*[h, g] T2 &
  54                                U2 = ⓛ{a}V2.T2.
  55 #h #g #a #G #L #V1 #T1 #U2 #H @(cpxs_ind … H) -U2 /2 width=5 by ex3_2_intro/
  56 #U0 #U2 #_ #HU02 * #V0 #T0 #HV10 #HT10 #H destruct
  57 elim (cpx_inv_abst1 … HU02) -HU02 #V2 #T2 #HV02 #HT02 #H destruct
  58 lapply (lpxs_cpx_trans … HT02 (L.ⓛV1) ?)
  59 /3 width=5 by lpxs_pair, cpxs_trans, cpxs_strap1, ex3_2_intro/
  60 qed-.
  61
  62 lemma cpxs_inv_abbr1: ∀h,g,a,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓓ{a}V1.T1 ➡*[h, g] U2 → (
  63                       ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 & ⦃G, L.ⓓV1⦄ ⊢ T1 ➡*[h, g] T2 &
  64                                U2 = ⓓ{a}V2.T2
  65                       ) ∨
  66                       ∃∃T2. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡*[h, g] T2 & ⇧[0, 1] U2 ≡ T2 & a = true.
  67 #h #g #a #G #L #V1 #T1 #U2 #H @(cpxs_ind … H) -U2 /3 width=5 by ex3_2_intro, or_introl/
  68 #U0 #U2 #_ #HU02 * *
  69 [ #V0 #T0 #HV10 #HT10 #H destruct
  70   elim (cpx_inv_abbr1 … HU02) -HU02 *
  71   [ #V2 #T2 #HV02 #HT02 #H destruct
  72     lapply (lpxs_cpx_trans … HT02 (L.ⓓV1) ?)
  73     /4 width=5 by lpxs_pair, cpxs_trans, cpxs_strap1, ex3_2_intro, or_introl/
  74   | #T2 #HT02 #HUT2
  75     lapply (lpxs_cpx_trans … HT02 (L.ⓓV1) ?) -HT02
  76     /4 width=3 by lpxs_pair, cpxs_trans, ex3_intro, or_intror/
  77   ]
  78 | #U1 #HTU1 #HU01
  79   elim (lift_total U2 0 1) #U #HU2
  80   /6 width=11 by cpxs_strap1, cpx_lift, ldrop_drop, ex3_intro, or_intror/
  81 ]
  82 qed-.
  83
  84 (* More advanced properties *************************************************)
  85
  86 lemma lpxs_pair2: ∀h,g,I,G,L1,L2. ⦃G, L1⦄ ⊢ ➡*[h, g] L2 →
  87                   ∀V1,V2. ⦃G, L2⦄ ⊢ V1 ➡*[h, g] V2 → ⦃G, L1.ⓑ{I}V1⦄ ⊢ ➡*[h, g] L2.ⓑ{I}V2.
  88 /3 width=3 by lpxs_pair, lpxs_cpxs_trans/ qed.
  89
  90 (* Properties on supclosure *************************************************)
  91
  92 lemma lpxs_fquq_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃⸮ ⦃G2, L2, T2⦄ →
  93                        ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, g] L1 →
  94                        ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ➡*[h, g] T & ⦃G1, K1, T⦄ ⊃⸮ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, g] L2.
  95 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #HT12 #K1 #H @(lpxs_ind_dx … H) -K1
  96 [ /2 width=5 by ex3_2_intro/
  97 | #K1 #K #HK1 #_ * #L #T #HT1 #HT2 #HL2 -HT12
  98   lapply (lpx_cpxs_trans … HT1 … HK1) -HT1
  99   elim (lpx_fquq_trans … HT2 … HK1) -K
 100   /3 width=7 by lpxs_strap2, cpxs_strap1, ex3_2_intro/
 101 ]
 102 qed-.
 103
 104 lemma lpxs_fqus_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄ →
 105                        ∀K1. ⦃G1, K1⦄ ⊢ ➡*[h, g] L1 →
 106                        ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ➡*[h, g] T & ⦃G1, K1, T⦄ ⊃* ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡*[h, g] L2.
 107 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqus_ind … H) -G2 -L2 -T2 /2 width=5 by ex3_2_intro/
 108 #G #G2 #L #L2 #T #T2 #_ #H2 #IH1 #K1 #HLK1 elim (IH1 … HLK1) -L1
 109 #L0 #T0 #HT10 #HT0 #HL0 elim (lpxs_fquq_trans … H2 … HL0) -L
 110 #L #T3 #HT3 #HT32 #HL2 elim (fqus_cpxs_trans … HT3 … HT0) -T
 111 /3 width=7 by cpxs_trans, fqus_strap1, ex3_2_intro/
 112 qed-.
 113
 114 lemma lpx_fqus_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄ →
 115                       ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 →
 116                       ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ➡*[h, g] T & ⦃G1, K1, T⦄ ⊃* ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2.
 117 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqus_ind … H) -G2 -L2 -T2 /2 width=5 by ex3_2_intro/
 118 #G #G2 #L #L2 #T #T2 #_ #H2 #IH1 #K1 #HLK1 elim (IH1 … HLK1) -L1
 119 #L0 #T0 #HT10 #HT0 #HL0 elim (lpx_fquq_trans … H2 … HL0) -L
 120 #L #T3 #HT3 #HT32 #HL2 elim (fqus_cpx_trans … HT0 … HT3) -T
 121 /3 width=7 by cpxs_strap1, fqus_strap1, ex3_2_intro/
 122 qed-.