matita/matita/contribs/lambdadelta/basic_2/computation/lsubc.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/static/aaa.ma".
  16 include "basic_2/computation/acp_cr.ma".
  17
  18 (* LOCAL ENVIRONMENT REFINEMENT FOR ABSTRACT CANDIDATES OF REDUCIBILITY *****)
  19
  20 inductive lsubc (RP:lenv→predicate term): relation lenv ≝
  21 | lsubc_atom: lsubc RP (⋆) (⋆)
  22 | lsubc_pair: ∀I,L1,L2,V. lsubc RP L1 L2 → lsubc RP (L1. ⓑ{I} V) (L2. ⓑ{I} V)
  23 | lsubc_abbr: ∀L1,L2,V,W,A. ⦃L1, V⦄ ϵ[RP] 〚A〛 → ⦃L1, W⦄ ϵ[RP] 〚A〛 → L2 ⊢ W ⁝ A →
  24               lsubc RP L1 L2 → lsubc RP (L1. ⓓⓝW.V) (L2. ⓛW)
  25 .
  26
  27 interpretation
  28   "local environment refinement (abstract candidates of reducibility)"
  29   'CrSubEq L1 RP L2 = (lsubc RP L1 L2).
  30
  31 (* Basic inversion lemmas ***************************************************)
  32
  33 fact lsubc_inv_atom1_aux: ∀RP,L1,L2. L1 ⊑[RP] L2 → L1 = ⋆ → L2 = ⋆.
  34 #RP #L1 #L2 * -L1 -L2
  35 [ //
  36 | #I #L1 #L2 #V #_ #H destruct
  37 | #L1 #L2 #V #W #A #_ #_ #_ #_ #H destruct
  38 ]
  39 qed-.
  40
  41 (* Basic_1: was just: csubc_gen_sort_r *)
  42 lemma lsubc_inv_atom1: ∀RP,L2. ⋆ ⊑[RP] L2 → L2 = ⋆.
  43 /2 width=4 by lsubc_inv_atom1_aux/ qed-.
  44
  45 fact lsubc_inv_pair1_aux: ∀RP,L1,L2. L1 ⊑[RP] L2 → ∀I,K1,X. L1 = K1.ⓑ{I}X →
  46                           (∃∃K2. K1 ⊑[RP] K2 & L2 = K2. ⓑ{I}X) ∨
  47                           ∃∃K2,V,W,A. ⦃K1, V⦄ ϵ[RP] 〚A〛 & ⦃K1, W⦄ ϵ[RP] 〚A〛 & K2 ⊢ W ⁝ A &
  48                                       K1 ⊑[RP] K2 &
  49                                       L2 = K2. ⓛW & X = ⓝW.V & I = Abbr.
  50 #RP #L1 #L2 * -L1 -L2
  51 [ #I #K1 #V #H destruct
  52 | #J #L1 #L2 #V #HL12 #I #K1 #W #H destruct /3 width=3/
  53 | #L1 #L2 #V1 #W2 #A #HV1 #H1W2 #H2W2 #HL12 #I #K1 #V #H destruct /3 width=10/
  54 ]
  55 qed-.
  56
  57 (* Basic_1: was: csubc_gen_head_r *)
  58 lemma lsubc_inv_pair1: ∀RP,I,K1,L2,X. K1.ⓑ{I}X ⊑[RP] L2 →
  59                        (∃∃K2. K1 ⊑[RP] K2 & L2 = K2.ⓑ{I}X) ∨
  60                        ∃∃K2,V,W,A. ⦃K1, V⦄ ϵ[RP] 〚A〛 & ⦃K1, W⦄ ϵ[RP] 〚A〛 & K2 ⊢ W ⁝ A &
  61                                    K1 ⊑[RP] K2 &
  62                                    L2 = K2. ⓛW & X = ⓝW.V & I = Abbr.
  63 /2 width=3 by lsubc_inv_pair1_aux/ qed-.
  64
  65 fact lsubc_inv_atom2_aux: ∀RP,L1,L2. L1 ⊑[RP] L2 → L2 = ⋆ → L1 = ⋆.
  66 #RP #L1 #L2 * -L1 -L2
  67 [ //
  68 | #I #L1 #L2 #V #_ #H destruct
  69 | #L1 #L2 #V #W #A #_ #_ #_ #_ #H destruct
  70 ]
  71 qed-.
  72
  73 (* Basic_1: was just: csubc_gen_sort_l *)
  74 lemma lsubc_inv_atom2: ∀RP,L1. L1 ⊑[RP] ⋆ → L1 = ⋆.
  75 /2 width=4 by lsubc_inv_atom2_aux/ qed-.
  76
  77 fact lsubc_inv_pair2_aux: ∀RP,L1,L2. L1 ⊑[RP] L2 → ∀I,K2,W. L2 = K2. ⓑ{I} W →
  78                           (∃∃K1. K1 ⊑[RP] K2 & L1 = K1. ⓑ{I} W) ∨
  79                           ∃∃K1,V,A. ⦃K1, V⦄ ϵ[RP] 〚A〛 & ⦃K1, W⦄ ϵ[RP] 〚A〛 & K2 ⊢ W ⁝ A &
  80                                     K1 ⊑[RP] K2 &
  81                                     L1 = K1. ⓓⓝW.V & I = Abst.
  82 #RP #L1 #L2 * -L1 -L2
  83 [ #I #K2 #W #H destruct
  84 | #J #L1 #L2 #V #HL12 #I #K2 #W #H destruct /3 width=3/
  85 | #L1 #L2 #V1 #W2 #A #HV1 #H1W2 #H2W2 #HL12 #I #K2 #W #H destruct /3 width=8/
  86 ]
  87 qed-.
  88
  89 (* Basic_1: was just: csubc_gen_head_l *)
  90 lemma lsubc_inv_pair2: ∀RP,I,L1,K2,W. L1 ⊑[RP] K2. ⓑ{I} W →
  91                        (∃∃K1. K1 ⊑[RP] K2 & L1 = K1.ⓑ{I} W) ∨
  92                        ∃∃K1,V,A. ⦃K1, V⦄ ϵ[RP] 〚A〛 & ⦃K1, W⦄ ϵ[RP] 〚A〛 & K2 ⊢ W ⁝ A &
  93                                  K1 ⊑[RP] K2 &
  94                                  L1 = K1.ⓓⓝW.V & I = Abst.
  95 /2 width=3 by lsubc_inv_pair2_aux/ qed-.
  96
  97 (* Basic properties *********************************************************)
  98
  99 (* Basic_1: was just: csubc_refl *)
 100 lemma lsubc_refl: ∀RP,L. L ⊑[RP] L.
 101 #RP #L elim L -L // /2 width=1/
 102 qed.
 103
 104 (* Basic_1: removed theorems 3:
 105             csubc_clear_conf csubc_getl_conf csubc_csuba
 106 *)