matita/matita/contribs/lambdadelta/basic_2/computation/lsubc.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/crsubeq_3.ma".
  16 include "basic_2/static/aaa.ma".
  17 include "basic_2/computation/acp_cr.ma".
  18
  19 (* LOCAL ENVIRONMENT REFINEMENT FOR ABSTRACT CANDIDATES OF REDUCIBILITY *****)
  20
  21 inductive lsubc (RP:lenv→predicate term): relation lenv ≝
  22 | lsubc_atom: lsubc RP (⋆) (⋆)
  23 | lsubc_pair: ∀I,L1,L2,V. lsubc RP L1 L2 → lsubc RP (L1. ⓑ{I} V) (L2. ⓑ{I} V)
  24 | lsubc_abbr: ∀L1,L2,V,W,A. ⦃L1, V⦄ ϵ[RP] 〚A〛 → ⦃L1, W⦄ ϵ[RP] 〚A〛 → L2 ⊢ W ⁝ A →
  25               lsubc RP L1 L2 → lsubc RP (L1. ⓓⓝW.V) (L2. ⓛW)
  26 .
  27
  28 interpretation
  29   "local environment refinement (abstract candidates of reducibility)"
  30   'CrSubEq L1 RP L2 = (lsubc RP L1 L2).
  31
  32 (* Basic inversion lemmas ***************************************************)
  33
  34 fact lsubc_inv_atom1_aux: ∀RP,L1,L2. L1 ⊑[RP] L2 → L1 = ⋆ → L2 = ⋆.
  35 #RP #L1 #L2 * -L1 -L2
  36 [ //
  37 | #I #L1 #L2 #V #_ #H destruct
  38 | #L1 #L2 #V #W #A #_ #_ #_ #_ #H destruct
  39 ]
  40 qed-.
  41
  42 (* Basic_1: was just: csubc_gen_sort_r *)
  43 lemma lsubc_inv_atom1: ∀RP,L2. ⋆ ⊑[RP] L2 → L2 = ⋆.
  44 /2 width=4 by lsubc_inv_atom1_aux/ qed-.
  45
  46 fact lsubc_inv_pair1_aux: ∀RP,L1,L2. L1 ⊑[RP] L2 → ∀I,K1,X. L1 = K1.ⓑ{I}X →
  47                           (∃∃K2. K1 ⊑[RP] K2 & L2 = K2. ⓑ{I}X) ∨
  48                           ∃∃K2,V,W,A. ⦃K1, V⦄ ϵ[RP] 〚A〛 & ⦃K1, W⦄ ϵ[RP] 〚A〛 & K2 ⊢ W ⁝ A &
  49                                       K1 ⊑[RP] K2 &
  50                                       L2 = K2. ⓛW & X = ⓝW.V & I = Abbr.
  51 #RP #L1 #L2 * -L1 -L2
  52 [ #I #K1 #V #H destruct
  53 | #J #L1 #L2 #V #HL12 #I #K1 #W #H destruct /3 width=3/
  54 | #L1 #L2 #V1 #W2 #A #HV1 #H1W2 #H2W2 #HL12 #I #K1 #V #H destruct /3 width=10/
  55 ]
  56 qed-.
  57
  58 (* Basic_1: was: csubc_gen_head_r *)
  59 lemma lsubc_inv_pair1: ∀RP,I,K1,L2,X. K1.ⓑ{I}X ⊑[RP] L2 →
  60                        (∃∃K2. K1 ⊑[RP] K2 & L2 = K2.ⓑ{I}X) ∨
  61                        ∃∃K2,V,W,A. ⦃K1, V⦄ ϵ[RP] 〚A〛 & ⦃K1, W⦄ ϵ[RP] 〚A〛 & K2 ⊢ W ⁝ A &
  62                                    K1 ⊑[RP] K2 &
  63                                    L2 = K2. ⓛW & X = ⓝW.V & I = Abbr.
  64 /2 width=3 by lsubc_inv_pair1_aux/ qed-.
  65
  66 fact lsubc_inv_atom2_aux: ∀RP,L1,L2. L1 ⊑[RP] L2 → L2 = ⋆ → L1 = ⋆.
  67 #RP #L1 #L2 * -L1 -L2
  68 [ //
  69 | #I #L1 #L2 #V #_ #H destruct
  70 | #L1 #L2 #V #W #A #_ #_ #_ #_ #H destruct
  71 ]
  72 qed-.
  73
  74 (* Basic_1: was just: csubc_gen_sort_l *)
  75 lemma lsubc_inv_atom2: ∀RP,L1. L1 ⊑[RP] ⋆ → L1 = ⋆.
  76 /2 width=4 by lsubc_inv_atom2_aux/ qed-.
  77
  78 fact lsubc_inv_pair2_aux: ∀RP,L1,L2. L1 ⊑[RP] L2 → ∀I,K2,W. L2 = K2. ⓑ{I} W →
  79                           (∃∃K1. K1 ⊑[RP] K2 & L1 = K1. ⓑ{I} W) ∨
  80                           ∃∃K1,V,A. ⦃K1, V⦄ ϵ[RP] 〚A〛 & ⦃K1, W⦄ ϵ[RP] 〚A〛 & K2 ⊢ W ⁝ A &
  81                                     K1 ⊑[RP] K2 &
  82                                     L1 = K1. ⓓⓝW.V & I = Abst.
  83 #RP #L1 #L2 * -L1 -L2
  84 [ #I #K2 #W #H destruct
  85 | #J #L1 #L2 #V #HL12 #I #K2 #W #H destruct /3 width=3/
  86 | #L1 #L2 #V1 #W2 #A #HV1 #H1W2 #H2W2 #HL12 #I #K2 #W #H destruct /3 width=8/
  87 ]
  88 qed-.
  89
  90 (* Basic_1: was just: csubc_gen_head_l *)
  91 lemma lsubc_inv_pair2: ∀RP,I,L1,K2,W. L1 ⊑[RP] K2. ⓑ{I} W →
  92                        (∃∃K1. K1 ⊑[RP] K2 & L1 = K1.ⓑ{I} W) ∨
  93                        ∃∃K1,V,A. ⦃K1, V⦄ ϵ[RP] 〚A〛 & ⦃K1, W⦄ ϵ[RP] 〚A〛 & K2 ⊢ W ⁝ A &
  94                                  K1 ⊑[RP] K2 &
  95                                  L1 = K1.ⓓⓝW.V & I = Abst.
  96 /2 width=3 by lsubc_inv_pair2_aux/ qed-.
  97
  98 (* Basic properties *********************************************************)
  99
 100 (* Basic_1: was just: csubc_refl *)
 101 lemma lsubc_refl: ∀RP,L. L ⊑[RP] L.
 102 #RP #L elim L -L // /2 width=1/
 103 qed.
 104
 105 (* Basic_1: removed theorems 3:
 106             csubc_clear_conf csubc_getl_conf csubc_csuba
 107 *)