matita/matita/contribs/lambdadelta/basic_2/computation/lsubc_ldrop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/static/aaa_lift.ma".
  16 include "basic_2/computation/lsubc.ma".
  17
  18 (* LOCAL ENVIRONMENT REFINEMENT FOR ABSTRACT CANDIDATES OF REDUCIBILITY *****)
  19
  20 (* Properties concerning basic local environment slicing ********************)
  21
  22 (* Basic_1: was: csubc_drop_conf_O *)
  23 (* Note: the constant 0 can not be generalized *)
  24 lemma lsubc_ldrop_O1_trans: ∀RP,L1,L2. L1 ⊑[RP] L2 → ∀K2,e. ⇩[0, e] L2 ≡ K2 →
  25                             ∃∃K1. ⇩[0, e] L1 ≡ K1 & K1 ⊑[RP] K2.
  26 #RP #L1 #L2 #H elim H -L1 -L2
  27 [ #X #e #H elim (ldrop_inv_atom1 … H) -H /2 width=3/
  28 | #I #L1 #L2 #V #_ #IHL12 #X #e #H
  29   elim (ldrop_inv_O1_pair1 … H) -H * #He #H destruct
  30   [ elim (IHL12 L2 0) -IHL12 // #X #H <(ldrop_inv_O2 … H) -H /3 width=3/
  31   | elim (IHL12 … H) -L2 /3 width=3/
  32   ]
  33 | #L1 #L2 #V #W #A #HV #H1W #H2W #_ #IHL12 #X #e #H
  34   elim (ldrop_inv_O1_pair1 … H) -H * #He #H destruct
  35   [ elim (IHL12 L2 0) -IHL12 // #X #H <(ldrop_inv_O2 … H) -H /3 width=8/
  36   | elim (IHL12 … H) -L2 /3 width=3/
  37   ]
  38 qed-.
  39
  40 (* Basic_1: was: csubc_drop_conf_rev *)
  41 lemma ldrop_lsubc_trans: ∀RR,RS,RP.
  42                          acp RR RS RP → acr RR RS RP (λL,T. RP L T) →
  43                          ∀L1,K1,d,e. ⇩[d, e] L1 ≡ K1 → ∀K2. K1 ⊑[RP] K2 →
  44                          ∃∃L2. L1 ⊑[RP] L2 & ⇩[d, e] L2 ≡ K2.
  45 #RR #RS #RP #Hacp #Hacr #L1 #K1 #d #e #H elim H -L1 -K1 -d -e
  46 [ #d #X #H elim (lsubc_inv_atom1 … H) -H /2 width=3/
  47 | #L1 #I #V1 #X #H
  48   elim (lsubc_inv_pair1 … H) -H *
  49   [ #K1 #HLK1 #H destruct /3 width=3/
  50   | #K1 #V #W1 #A #HV1 #H1W1 #H2W1 #HLK1 #H1 #H2 #H3 destruct /3 width=4/
  51   ]
  52 | #L1 #K1 #I #V1 #e #_ #IHLK1 #K2 #HK12
  53   elim (IHLK1 … HK12) -K1 /3 width=5/
  54 | #L1 #K1 #I #V1 #V2 #d #e #HLK1 #HV21 #IHLK1 #X #H
  55   elim (lsubc_inv_pair1 … H) -H *
  56   [ #K2 #HK12 #H destruct
  57     elim (IHLK1 … HK12) -K1 /3 width=5/
  58   | #K2 #V #W2 #A #HV2 #H1W2 #H2W2 #HK12 #H1 #H2 #H3 destruct
  59     elim (lift_inv_flat1 … HV21) -HV21 #W3 #V3 #HW23 #HV3 #H destruct
  60     elim (IHLK1 … HK12) #K #HL1K #HK2
  61     lapply (aacr_acr … Hacp Hacr A) -Hacp -Hacr #HA
  62     lapply (s8 … HA … HV2 … HLK1 HV3) -HV2
  63     lapply (s8 … HA … H1W2 … HLK1 HW23) -H1W2 /4 width=10/
  64   ]
  65 ]
  66 qed-.