matita/matita/contribs/lambdadelta/basic_2/computation/lsx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/lazysn_6.ma".
  16 include "basic_2/substitution/lleq.ma".
  17 include "basic_2/computation/lpxs.ma".
  18
  19 (* SN EXTENDED STRONGLY NORMALIZING LOCAL ENVIRONMENTS **********************)
  20
  21 definition lsx: ∀h. sd h → relation4 ynat term genv lenv ≝
  22                 λh,g,d,T,G. SN … (lpxs h g G) (lleq d T).
  23
  24 interpretation
  25    "extended strong normalization (local environment)"
  26    'LazySN h g d T G L = (lsx h g T d G L).
  27
  28 (* Basic eliminators ********************************************************)
  29
  30 lemma lsx_ind: ∀h,g,G,T,d. ∀R:predicate lenv.
  31                (∀L1. G ⊢ ⋕⬊*[h, g, T, d] L1 →
  32                      (∀L2. ⦃G, L1⦄ ⊢ ➡*[h, g] L2 → (L1 ⋕[T, d] L2 → ⊥) → R L2) →
  33                      R L1
  34                ) →
  35                ∀L. G ⊢ ⋕⬊*[h, g, T, d] L → R L.
  36 #h #g #G #T #d #R #H0 #L1 #H elim H -L1
  37 /5 width=1 by lleq_sym, SN_intro/
  38 qed-.
  39
  40 (* Basic properties *********************************************************)
  41
  42 lemma lsx_intro: ∀h,g,G,L1,T,d.
  43                  (∀L2. ⦃G, L1⦄ ⊢ ➡*[h, g] L2 → (L1 ⋕[T, d] L2 → ⊥) → G ⊢ ⋕⬊*[h, g, T, d] L2) →
  44                  G ⊢ ⋕⬊*[h, g, T, d] L1.
  45 /5 width=1 by lleq_sym, SN_intro/ qed.
  46
  47 lemma lsx_atom: ∀h,g,G,T,d. G ⊢ ⋕⬊*[h, g, T, d] ⋆.
  48 #h #g #G #T #d @lsx_intro
  49 #X #H #HT lapply (lpxs_inv_atom1 … H) -H
  50 #H destruct elim HT -HT //
  51 qed.
  52
  53 lemma lsx_sort: ∀h,g,G,L,d,k. G ⊢ ⋕⬊*[h, g, ⋆k, d] L.
  54 #h #g #G #L1 #d #k @lsx_intro
  55 #L2 #HL12 #H elim H -H
  56 /3 width=4 by lpxs_fwd_length, lleq_sort/
  57 qed.
  58
  59 lemma lsx_gref: ∀h,g,G,L,d,p. G ⊢ ⋕⬊*[h, g, §p, d] L.
  60 #h #g #G #L1 #d #p @lsx_intro
  61 #L2 #HL12 #H elim H -H
  62 /3 width=4 by lpxs_fwd_length, lleq_gref/
  63 qed.
  64
  65 lemma lsx_be: ∀h,g,G,L,T,U,dt,d,e. yinj d ≤ dt → dt ≤ d + e →
  66               ⇧[d, e] T ≡ U → G ⊢ ⋕⬊*[h, g, U, dt] L → G ⊢ ⋕⬊*[h, g, U, d] L.
  67 #h #g #G #L #T #U #dt #d #e #Hddt #Hdtde #HTU #H @(lsx_ind … H) -L
  68 /5 width=7 by lsx_intro, lleq_be/
  69 qed-.
  70
  71 (* Basic forward lemmas *****************************************************)
  72
  73 lemma lsx_fwd_bind_sn: ∀h,g,a,I,G,L,V,T,d. G ⊢ ⋕⬊*[h, g, ⓑ{a,I}V.T, d] L →
  74                        G ⊢ ⋕⬊*[h, g, V, d] L.
  75 #h #g #a #I #G #L #V #T #d #H @(lsx_ind … H) -L
  76 #L1 #_ #IHL1 @lsx_intro
  77 #L2 #HL12 #HV @IHL1 /3 width=4 by lleq_fwd_bind_sn/
  78 qed-.
  79
  80 lemma lsx_fwd_flat_sn: ∀h,g,I,G,L,V,T,d. G ⊢ ⋕⬊*[h, g, ⓕ{I}V.T, d] L →
  81                        G ⊢ ⋕⬊*[h, g, V, d] L.
  82 #h #g #I #G #L #V #T #d #H @(lsx_ind … H) -L
  83 #L1 #_ #IHL1 @lsx_intro
  84 #L2 #HL12 #HV @IHL1 /3 width=3 by lleq_fwd_flat_sn/
  85 qed-.
  86
  87 lemma lsx_fwd_flat_dx: ∀h,g,I,G,L,V,T,d. G ⊢ ⋕⬊*[h, g, ⓕ{I}V.T, d] L →
  88                        G ⊢ ⋕⬊*[h, g, T, d] L.
  89 #h #g #I #G #L #V #T #d #H @(lsx_ind … H) -L
  90 #L1 #_ #IHL1 @lsx_intro
  91 #L2 #HL12 #HV @IHL1 /3 width=3 by lleq_fwd_flat_dx/
  92 qed-.
  93
  94 lemma lsx_fwd_pair_sn: ∀h,g,I,G,L,V,T,d. G ⊢ ⋕⬊*[h, g, ②{I}V.T, d] L →
  95                        G ⊢ ⋕⬊*[h, g, V, d] L.
  96 #h #g * /2 width=4 by lsx_fwd_bind_sn, lsx_fwd_flat_sn/
  97 qed-.
  98
  99 (* Basic inversion lemmas ***************************************************)
 100
 101 lemma lsx_inv_flat: ∀h,g,I,G,L,V,T,d. G ⊢ ⋕⬊*[h, g, ⓕ{I}V.T, d] L →
 102                     G ⊢ ⋕⬊*[h, g, V, d] L ∧ G ⊢ ⋕⬊*[h, g, T, d] L.
 103 /3 width=3 by lsx_fwd_flat_sn, lsx_fwd_flat_dx, conj/ qed-.