matita/matita/contribs/lambdadelta/basic_2/computation/lsx_alt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/snalt_6.ma".
  16 include "basic_2/multiple/lleq_lleq.ma".
  17 include "basic_2/computation/lpxs_lleq.ma".
  18 include "basic_2/computation/lsx.ma".
  19
  20 (* SN EXTENDED STRONGLY NORMALIZING LOCAL ENVIRONMENTS **********************)
  21
  22 (* alternative definition of lsx *)
  23 definition lsxa: ∀h. sd h → relation4 ynat term genv lenv ≝
  24                  λh,g,d,T,G. SN … (lpxs h g G) (lleq d T).
  25
  26 interpretation
  27    "extended strong normalization (local environment) alternative"
  28    'SNAlt h g d T G L = (lsxa h g T d G L).
  29
  30 (* Basic eliminators ********************************************************)
  31
  32 lemma lsxa_ind: ∀h,g,G,T,d. ∀R:predicate lenv.
  33                 (∀L1. G ⊢ ⬊⬊*[h, g, T, d] L1 →
  34                       (∀L2. ⦃G, L1⦄ ⊢ ➡*[h, g] L2 → (L1 ≡[T, d] L2 → ⊥) → R L2) →
  35                       R L1
  36                 ) →
  37                 ∀L. G ⊢ ⬊⬊*[h, g, T, d] L → R L.
  38 #h #g #G #T #d #R #H0 #L1 #H elim H -L1
  39 /5 width=1 by lleq_sym, SN_intro/
  40 qed-.
  41
  42 (* Basic properties *********************************************************)
  43
  44 lemma lsxa_intro: ∀h,g,G,L1,T,d.
  45                   (∀L2. ⦃G, L1⦄ ⊢ ➡*[h, g] L2 → (L1 ≡[T, d] L2 → ⊥) → G ⊢ ⬊⬊*[h, g, T, d] L2) →
  46                   G ⊢ ⬊⬊*[h, g, T, d] L1.
  47 /5 width=1 by lleq_sym, SN_intro/ qed.
  48
  49 fact lsxa_intro_aux: ∀h,g,G,L1,T,d.
  50                      (∀L,L2. ⦃G, L⦄ ⊢ ➡*[h, g] L2 → L1 ≡[T, d] L → (L1 ≡[T, d] L2 → ⊥) → G ⊢ ⬊⬊*[h, g, T, d] L2) →
  51                      G ⊢ ⬊⬊*[h, g, T, d] L1.
  52 /4 width=3 by lsxa_intro/ qed-.
  53
  54 lemma lsxa_lleq_trans: ∀h,g,T,G,L1,d. G ⊢ ⬊⬊*[h, g, T, d] L1 →
  55                        ∀L2. L1 ≡[T, d] L2 → G ⊢ ⬊⬊*[h, g, T, d] L2.
  56 #h #g #T #G #L1 #d #H @(lsxa_ind … H) -L1
  57 #L1 #_ #IHL1 #L2 #HL12 @lsxa_intro
  58 #K2 #HLK2 #HnLK2 elim (lleq_lpxs_trans … HLK2 … HL12) -HLK2
  59 /5 width=4 by lleq_canc_sn, lleq_trans/
  60 qed-.
  61
  62 lemma lsxa_lpxs_trans: ∀h,g,T,G,L1,d. G ⊢ ⬊⬊*[h, g, T, d] L1 →
  63                        ∀L2. ⦃G, L1⦄ ⊢ ➡*[h, g] L2 → G ⊢ ⬊⬊*[h, g, T, d] L2.
  64 #h #g #T #G #L1 #d #H @(lsxa_ind … H) -L1 #L1 #HL1 #IHL1 #L2 #HL12
  65 elim (lleq_dec T L1 L2 d) /3 width=4 by lsxa_lleq_trans/
  66 qed-.
  67
  68 lemma lsxa_intro_lpx: ∀h,g,G,L1,T,d.
  69                       (∀L2. ⦃G, L1⦄ ⊢ ➡[h, g] L2 → (L1 ≡[T, d] L2 → ⊥) → G ⊢ ⬊⬊*[h, g, T, d] L2) →
  70                       G ⊢ ⬊⬊*[h, g, T, d] L1.
  71 #h #g #G #L1 #T #d #IH @lsxa_intro_aux
  72 #L #L2 #H @(lpxs_ind_dx … H) -L
  73 [ #H destruct #H elim H //
  74 | #L0 #L elim (lleq_dec T L1 L d) /3 width=1 by/
  75   #HnT #HL0 #HL2 #_ #HT #_ elim (lleq_lpx_trans … HL0 … HT) -L0
  76   #L0 #HL10 #HL0 @(lsxa_lpxs_trans … HL2) -HL2
  77   /5 width=3 by lsxa_lleq_trans, lleq_trans/
  78 ]
  79 qed-.
  80
  81 (* Main properties **********************************************************)
  82
  83 theorem lsx_lsxa: ∀h,g,G,L,T,d. G ⊢ ⬊*[h, g, T, d] L → G ⊢ ⬊⬊*[h, g, T, d] L.
  84 #h #g #G #L #T #d #H @(lsx_ind … H) -L
  85 /4 width=1 by lsxa_intro_lpx/
  86 qed.
  87
  88 (* Main inversion lemmas ****************************************************)
  89
  90 theorem lsxa_inv_lsx: ∀h,g,G,L,T,d. G ⊢ ⬊⬊*[h, g, T, d] L → G ⊢ ⬊*[h, g, T, d] L.
  91 #h #g #G #L #T #d #H @(lsxa_ind … H) -L
  92 /4 width=1 by lsx_intro, lpx_lpxs/
  93 qed-.
  94
  95 (* Advanced properties ******************************************************)
  96
  97 lemma lsx_intro_alt: ∀h,g,G,L1,T,d.
  98                      (∀L2. ⦃G, L1⦄ ⊢ ➡*[h, g] L2 → (L1 ≡[T, d] L2 → ⊥) → G ⊢ ⬊*[h, g, T, d] L2) →
  99                      G ⊢ ⬊*[h, g, T, d] L1.
 100 /6 width=1 by lsxa_inv_lsx, lsx_lsxa, lsxa_intro/ qed.
 101
 102 lemma lsx_lpxs_trans: ∀h,g,G,L1,T,d. G ⊢ ⬊*[h, g, T, d] L1 →
 103                       ∀L2. ⦃G, L1⦄ ⊢ ➡*[h, g] L2 → G ⊢ ⬊*[h, g, T, d] L2.
 104 /4 width=3 by lsxa_inv_lsx, lsx_lsxa, lsxa_lpxs_trans/ qed-.
 105
 106 (* Advanced eliminators *****************************************************)
 107
 108 lemma lsx_ind_alt: ∀h,g,G,T,d. ∀R:predicate lenv.
 109                    (∀L1. G ⊢ ⬊*[h, g, T, d] L1 →
 110                          (∀L2. ⦃G, L1⦄ ⊢ ➡*[h, g] L2 → (L1 ≡[T, d] L2 → ⊥) → R L2) →
 111                          R L1
 112                    ) →
 113                    ∀L. G ⊢ ⬊*[h, g, T, d] L → R L.
 114 #h #g #G #T #d #R #IH #L #H @(lsxa_ind h g G T d … L)
 115 /4 width=1 by lsxa_inv_lsx, lsx_lsxa/
 116 qed-.