matita/matita/contribs/lambdadelta/basic_2/computation/ltprs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/reducibility/ltpr.ma".
  16 include "basic_2/computation/tprs.ma".
  17
  18 (* CONTEXT-FREE PARALLEL COMPUTATION ON LOCAL ENVIRONMENTS ******************)
  19
  20 definition ltprs: relation lenv ≝ TC … ltpr.
  21
  22 interpretation
  23   "context-free parallel computation (environment)"
  24   'PRedStar L1 L2 = (ltprs L1 L2).
  25
  26 (* Basic eliminators ********************************************************)
  27
  28 lemma ltprs_ind: ∀L1. ∀R:predicate lenv. R L1 →
  29                  (∀L,L2. L1 ➡* L → L ➡ L2 → R L → R L2) →
  30                  ∀L2. L1 ➡* L2 → R L2.
  31 #L1 #R #HL1 #IHL1 #L2 #HL12
  32 @(TC_star_ind … HL1 IHL1 … HL12) //
  33 qed-.
  34
  35 lemma ltprs_ind_dx: ∀L2. ∀R:predicate lenv. R L2 →
  36                     (∀L1,L. L1 ➡ L → L ➡* L2 → R L → R L1) →
  37                     ∀L1. L1 ➡* L2 → R L1.
  38 #L2 #R #HL2 #IHL2 #L1 #HL12
  39 @(TC_star_ind_dx … HL2 IHL2 … HL12) //
  40 qed-.
  41
  42 (* Basic properties *********************************************************)
  43
  44 lemma ltprs_refl: reflexive … ltprs.
  45 /2 width=1/ qed.
  46
  47 (* Basic inversion lemmas ***************************************************)
  48
  49 lemma ltprs_inv_atom1: ∀L2. ⋆ ➡* L2 → L2 = ⋆.
  50 #L2 #H @(ltprs_ind … H) -L2 //
  51 #L #L2 #_ #HL2 #IHL1 destruct
  52 >(ltpr_inv_atom1 … HL2) -L2 //
  53 qed-.
  54
  55 lemma ltprs_inv_pair1: ∀I,K1,L2,V1. K1. ⓑ{I} V1 ➡* L2 →
  56                        ∃∃K2,V2. K1 ➡* K2 & V1 ➡* V2 & L2 = K2. ⓑ{I} V2.
  57 #I #K1 #L2 #V1 #H @(ltprs_ind … H) -L2 /2 width=5/
  58 #L #L2 #_ #HL2 * #K #V #HK1 #HV1 #H destruct
  59 elim (ltpr_inv_pair1 … HL2) -HL2 #K2 #V2 #HK2 #HV2 #H destruct /3 width=5/
  60 qed-.
  61
  62 lemma ltprs_inv_atom2: ∀L1. L1 ➡* ⋆ → L1 = ⋆.
  63 #L1 #H @(ltprs_ind_dx … H) -L1 //
  64 #L1 #L #HL1 #_ #IHL2 destruct
  65 >(ltpr_inv_atom2 … HL1) -L1 //
  66 qed-.
  67
  68 lemma ltprs_inv_pair2: ∀I,L1,K2,V2. L1 ➡* K2. ⓑ{I} V2 →
  69                        ∃∃K1,V1. K1 ➡* K2 & V1 ➡* V2 & L1 = K1. ⓑ{I} V1.
  70 #I #L1 #K2 #V2 #H @(ltprs_ind_dx … H) -L1 /2 width=5/
  71 #L1 #L #HL1 #_ * #K #V #HK2 #HV2 #H destruct
  72 elim (ltpr_inv_pair2 … HL1) -HL1 #K1 #V1 #HK1 #HV1 #H destruct /3 width=5/
  73 qed-.
  74
  75 (* Basic forward lemmas *****************************************************)
  76
  77 lemma ltprs_fwd_length: ∀L1,L2. L1 ➡* L2 → |L1| = |L2|.
  78 #L1 #L2 #H @(ltprs_ind … H) -L2 //
  79 #L #L2 #_ #HL2 #IHL1
  80 >IHL1 -L1 >(ltpr_fwd_length … HL2) -HL2 //
  81 qed-.