matita/matita/contribs/lambdadelta/basic_2/computation/xprs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/static/lsubss.ma".
  16 include "basic_2/reducibility/xpr.ma".
  17 (*
  18 include "basic_2/reducibility/cnf.ma".
  19 *)
  20 (* EXTENDED PARALLEL COMPUTATION ON TERMS ***********************************)
  21
  22 definition xprs: ∀h. sd h → lenv → relation term ≝
  23                  λh,g,L. TC … (xpr h g L).
  24
  25 interpretation "extended parallel computation (term)"
  26    'XPRedStar h g L T1 T2 = (xprs h g L T1 T2).
  27
  28 (* Basic eliminators ********************************************************)
  29
  30 lemma xprs_ind: ∀h,g,L,T1. ∀R:predicate term. R T1 →
  31                 (∀T,T2. ⦃h, L⦄ ⊢ T1 •➡*[g] T → ⦃h, L⦄ ⊢ T •➡[g] T2 → R T → R T2) →
  32                 ∀T2. ⦃h, L⦄ ⊢ T1 •➡*[g] T2 → R T2.
  33 #h #g #L #T1 #R #HT1 #IHT1 #T2 #HT12
  34 @(TC_star_ind … HT1 IHT1 … HT12) //
  35 qed-.
  36
  37 lemma xprs_ind_dx: ∀h,g,L,T2. ∀R:predicate term. R T2 →
  38                    (∀T1,T. ⦃h, L⦄ ⊢ T1 •➡[g] T → ⦃h, L⦄ ⊢ T •➡*[g] T2 → R T → R T1) →
  39                    ∀T1. ⦃h, L⦄ ⊢ T1 •➡*[g] T2 → R T1.
  40 #h #g #L #T2 #R #HT2 #IHT2 #T1 #HT12
  41 @(TC_star_ind_dx … HT2 IHT2 … HT12) //
  42 qed-.
  43
  44 (* Basic properties *********************************************************)
  45
  46 lemma xprs_refl: ∀h,g,L. reflexive … (xprs h g L).
  47 /2 width=1/ qed.
  48
  49 lemma xprs_strap1: ∀h,g,L,T1,T,T2.
  50                    ⦃h, L⦄ ⊢ T1 •➡*[g] T → ⦃h, L⦄ ⊢ T •➡[g] T2 → ⦃h, L⦄ ⊢ T1 •➡*[g] T2.
  51 /2 width=3/ qed.
  52
  53 lemma xprs_strap2: ∀h,g,L,T1,T,T2.
  54                    ⦃h, L⦄ ⊢ T1 •➡[g] T → ⦃h, L⦄ ⊢ T •➡*[g] T2 → ⦃h, L⦄ ⊢ T1 •➡*[g] T2.
  55 /2 width=3/ qed.
  56
  57 (* Basic inversion lemmas ***************************************************)
  58 (*
  59 axiom xprs_inv_cnf1: ∀L,T,U. L ⊢ T ➡* U → L ⊢ 𝐍⦃T⦄ → T = U.
  60 #L #T #U #H @(xprs_ind_dx … H) -T //
  61 #T0 #T #H1T0 #_ #IHT #H2T0
  62 lapply (H2T0 … H1T0) -H1T0 #H destruct /2 width=1/
  63 qed-.
  64 *)