matita/matita/contribs/lambdadelta/basic_2/computation/yprs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unwind/sstas.ma".
  16 include "basic_2/reducibility/ypr.ma".
  17 include "basic_2/computation/ltprs.ma".
  18 include "basic_2/computation/cprs.ma".
  19
  20 (* "BIG TREE" PARALLEL COMPUTATION FOR CLOSURES *****************************)
  21
  22 definition yprs: ∀h. sd h → bi_relation lenv term ≝
  23                  λh,g. bi_TC … (ypr h g).
  24
  25 interpretation "'big tree' parallel computation (closure)"
  26    'BTPRedStar h g L1 T1 L2 T2 = (yprs h g L1 T1 L2 T2).
  27
  28 (* Basic eliminators ********************************************************)
  29
  30 lemma yprs_ind: ∀h,g,L1,T1. ∀R:relation2 lenv term. R L1 T1 →
  31                 (∀L,L2,T,T2. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L, T⦄ → h ⊢ ⦃L, T⦄ ≽[g] ⦃L2, T2⦄ → R L T → R L2 T2) →
  32                 ∀L2,T2. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄ → R L2 T2.
  33 /3 width=7 by bi_TC_star_ind/ qed-.
  34
  35 lemma yprs_ind_dx: ∀h,g,L2,T2. ∀R:relation2 lenv term. R L2 T2 →
  36                    (∀L1,L,T1,T. h ⊢ ⦃L1, T1⦄ ≽[g] ⦃L, T⦄ → h ⊢ ⦃L, T⦄ ≥[g] ⦃L2, T2⦄ → R L T → R L1 T1) →
  37                    ∀L1,T1. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄ → R L1 T1.
  38 /3 width=7 by bi_TC_star_ind_dx/ qed-.
  39
  40 (* Basic properties *********************************************************)
  41
  42 lemma yprs_refl: ∀h,g. bi_reflexive … (yprs h g).
  43 /2 width=1/ qed.
  44
  45 lemma ypr_yprs: ∀h,g,L1,L2,T1,T2. h ⊢ ⦃L1, T1⦄ ≽[g] ⦃L2, T2⦄ →
  46                 h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  47 /2 width=1/ qed.
  48
  49 lemma yprs_strap1: ∀h,g,L1,L,L2,T1,T,T2. h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L, T⦄ →
  50                    h ⊢ ⦃L, T⦄ ≽[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  51 /2 width=4/ qed-.
  52
  53 lemma yprs_strap2: ∀h,g,L1,L,L2,T1,T,T2. h ⊢ ⦃L1, T1⦄ ≽[g] ⦃L, T⦄ →
  54                    h ⊢ ⦃L, T⦄ ≥[g] ⦃L2, T2⦄ → h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  55 /2 width=4/ qed-.
  56
  57 lemma fw_yprs: ∀h,g,L1,L2,T1,T2. ♯{L2, T2} < ♯{L1, T1} →
  58                h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  59 /3 width=1/ qed.
  60
  61 lemma cprs_yprs: ∀h,g,L,T1,T2. L ⊢ T1 ➡* T2 → h ⊢ ⦃L, T1⦄ ≥[g] ⦃L, T2⦄.
  62 #h #g #L #T1 #T2 #H @(cprs_ind … H) -T2 // /3 width=4 by ypr_cpr, yprs_strap1/
  63 qed.
  64
  65 lemma ltprs_yprs: ∀h,g,L1,L2,T. L1 ➡* L2 → h ⊢ ⦃L1, T⦄ ≥[g] ⦃L2, T⦄.
  66 #h #g #L1 #L2 #T #H @(ltprs_ind … H) -L2 // /3 width=4 by ypr_ltpr, yprs_strap1/
  67 qed.
  68
  69 lemma sstas_yprs: ∀h,g,L,T1,T2. ⦃h, L⦄ ⊢ T1 •*[g] T2 →
  70                   h ⊢ ⦃L, T1⦄ ≥[g] ⦃L, T2⦄.
  71 #h #g #L #T1 #T2 #H @(sstas_ind … H) -T2 // /3 width=4 by ypr_ssta, yprs_strap1/
  72 qed.
  73
  74 lemma ltpr_cprs_yprs: ∀h,g,L1,L2,T1,T2. L1 ➡ L2 → L2 ⊢ T1 ➡* T2 →
  75                       h ⊢ ⦃L1, T1⦄ ≥[g] ⦃L2, T2⦄.
  76 /3 width=4 by yprs_strap2, ypr_ltpr, cprs_yprs/
  77 qed.