matita/matita/contribs/lambdadelta/basic_2/dynamic/cnv.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/ynat/ynat_lt.ma".
  16 include "basic_2/notation/relations/exclaim_5.ma".
  17 include "basic_2/notation/relations/exclaim_4.ma".
  18 include "basic_2/notation/relations/exclaimstar_4.ma".
  19 include "basic_2/rt_computation/cpms.ma".
  20
  21 (* CONTEXT-SENSITIVE NATIVE VALIDITY FOR TERMS ******************************)
  22
  23 (* activate genv *)
  24 (* Basic_2A1: uses: snv *)
  25 inductive cnv (a:ynat) (h): relation3 genv lenv term ≝
  26 | cnv_sort: ∀G,L,s. cnv a h G L (⋆s)
  27 | cnv_zero: ∀I,G,K,V. cnv a h G K V → cnv a h G (K.ⓑ{I}V) (#0)
  28 | cnv_lref: ∀I,G,K,i. cnv a h G K (#i) → cnv a h G (K.ⓘ{I}) (#↑i)
  29 | cnv_bind: ∀p,I,G,L,V,T. cnv a h G L V → cnv a h G (L.ⓑ{I}V) T → cnv a h G L (ⓑ{p,I}V.T)
  30 | cnv_appl: ∀n,p,G,L,V,W0,T,U0. yinj n < a → cnv a h G L V → cnv a h G L T →
  31             ⦃G,L⦄ ⊢ V ➡*[1,h] W0 → ⦃G,L⦄ ⊢ T ➡*[n,h] ⓛ{p}W0.U0 → cnv a h G L (ⓐV.T)
  32 | cnv_cast: ∀G,L,U,T,U0. cnv a h G L U → cnv a h G L T →
  33             ⦃G,L⦄ ⊢ U ➡*[h] U0 → ⦃G,L⦄ ⊢ T ➡*[1,h] U0 → cnv a h G L (ⓝU.T)
  34 .
  35
  36 interpretation "context-sensitive native validity (term)"
  37    'Exclaim a h G L T = (cnv a h G L T).
  38
  39 interpretation "context-sensitive restricted native validity (term)"
  40    'Exclaim h G L T = (cnv (yinj (S (S O))) h G L T).
  41
  42 interpretation "context-sensitive extended native validity (term)"
  43    'ExclaimStar h G L T = (cnv Y h G L T).
  44
  45 (* Basic inversion lemmas ***************************************************)
  46
  47 fact cnv_inv_zero_aux (a) (h): ∀G,L,X. ⦃G,L⦄ ⊢ X ![a,h] → X = #0 →
  48                                ∃∃I,K,V. ⦃G,K⦄ ⊢ V ![a,h] & L = K.ⓑ{I}V.
  49 #a #h #G #L #X * -G -L -X
  50 [ #G #L #s #H destruct
  51 | #I #G #K #V #HV #_ /2 width=5 by ex2_3_intro/
  52 | #I #G #K #i #_ #H destruct
  53 | #p #I #G #L #V #T #_ #_ #H destruct
  54 | #n #p #G #L #V #W0 #T #U0 #_ #_ #_ #_ #_ #H destruct
  55 | #G #L #U #T #U0 #_ #_ #_ #_ #H destruct
  56 ]
  57 qed-.
  58
  59 lemma cnv_inv_zero (a) (h): ∀G,L. ⦃G,L⦄ ⊢ #0 ![a,h] →
  60                             ∃∃I,K,V. ⦃G,K⦄ ⊢ V ![a,h] & L = K.ⓑ{I}V.
  61 /2 width=3 by cnv_inv_zero_aux/ qed-.
  62
  63 fact cnv_inv_lref_aux (a) (h): ∀G,L,X. ⦃G,L⦄ ⊢ X ![a,h] → ∀i. X = #(↑i) →
  64                               ∃∃I,K. ⦃G,K⦄ ⊢ #i ![a,h] & L = K.ⓘ{I}.
  65 #a #h #G #L #X * -G -L -X
  66 [ #G #L #s #j #H destruct
  67 | #I #G #K #V #_ #j #H destruct
  68 | #I #G #L #i #Hi #j #H destruct /2 width=4 by ex2_2_intro/
  69 | #p #I #G #L #V #T #_ #_ #j #H destruct
  70 | #n #p #G #L #V #W0 #T #U0 #_ #_ #_ #_ #_ #j #H destruct
  71 | #G #L #U #T #U0 #_ #_ #_ #_ #j #H destruct
  72 ]
  73 qed-.
  74
  75 lemma cnv_inv_lref (a) (h): ∀G,L,i. ⦃G,L⦄ ⊢ #↑i ![a,h] →
  76                             ∃∃I,K. ⦃G,K⦄ ⊢ #i ![a,h] & L = K.ⓘ{I}.
  77 /2 width=3 by cnv_inv_lref_aux/ qed-.
  78
  79 fact cnv_inv_gref_aux (a) (h): ∀G,L,X. ⦃G,L⦄ ⊢ X ![a,h] → ∀l. X = §l → ⊥.
  80 #a #h #G #L #X * -G -L -X
  81 [ #G #L #s #l #H destruct
  82 | #I #G #K #V #_ #l #H destruct
  83 | #I #G #K #i #_ #l #H destruct
  84 | #p #I #G #L #V #T #_ #_ #l #H destruct
  85 | #n #p #G #L #V #W0 #T #U0 #_ #_ #_ #_ #_ #l #H destruct
  86 | #G #L #U #T #U0 #_ #_ #_ #_ #l #H destruct
  87 ]
  88 qed-.
  89
  90 (* Basic_2A1: uses: snv_inv_gref *)
  91 lemma cnv_inv_gref (a) (h): ∀G,L,l. ⦃G,L⦄ ⊢ §l ![a,h] → ⊥.
  92 /2 width=8 by cnv_inv_gref_aux/ qed-.
  93
  94 fact cnv_inv_bind_aux (a) (h): ∀G,L,X. ⦃G,L⦄ ⊢ X ![a,h] →
  95                                ∀p,I,V,T. X = ⓑ{p,I}V.T →
  96                                ∧∧ ⦃G,L⦄ ⊢ V ![a,h]
  97                                 & ⦃G,L.ⓑ{I}V⦄ ⊢ T ![a,h].
  98 #a #h #G #L #X * -G -L -X
  99 [ #G #L #s #q #Z #X1 #X2 #H destruct
 100 | #I #G #K #V #_ #q #Z #X1 #X2 #H destruct
 101 | #I #G #K #i #_ #q #Z #X1 #X2 #H destruct
 102 | #p #I #G #L #V #T #HV #HT #q #Z #X1 #X2 #H destruct /2 width=1 by conj/
 103 | #n #p #G #L #V #W0 #T #U0 #_ #_ #_ #_ #_ #q #Z #X1 #X2 #H destruct
 104 | #G #L #U #T #U0 #_ #_ #_ #_ #q #Z #X1 #X2 #H destruct
 105 ]
 106 qed-.
 107
 108 (* Basic_2A1: uses: snv_inv_bind *)
 109 lemma cnv_inv_bind (a) (h): ∀p,I,G,L,V,T. ⦃G,L⦄ ⊢ ⓑ{p,I}V.T ![a,h] →
 110                             ∧∧ ⦃G,L⦄ ⊢ V ![a,h]
 111                              & ⦃G,L.ⓑ{I}V⦄ ⊢ T ![a,h].
 112 /2 width=4 by cnv_inv_bind_aux/ qed-.
 113
 114 fact cnv_inv_appl_aux (a) (h): ∀G,L,X. ⦃G,L⦄ ⊢ X ![a,h] → ∀V,T. X = ⓐV.T →
 115                                ∃∃n,p,W0,U0. yinj n < a & ⦃G,L⦄ ⊢ V ![a,h] & ⦃G,L⦄ ⊢ T ![a,h] &
 116                                             ⦃G,L⦄ ⊢ V ➡*[1,h] W0 & ⦃G,L⦄ ⊢ T ➡*[n,h] ⓛ{p}W0.U0.
 117 #a #h #G #L #X * -L -X
 118 [ #G #L #s #X1 #X2 #H destruct
 119 | #I #G #K #V #_ #X1 #X2 #H destruct
 120 | #I #G #K #i #_ #X1 #X2 #H destruct
 121 | #p #I #G #L #V #T #_ #_ #X1 #X2 #H destruct
 122 | #n #p #G #L #V #W0 #T #U0 #Ha #HV #HT #HVW0 #HTU0 #X1 #X2 #H destruct /3 width=7 by ex5_4_intro/
 123 | #G #L #U #T #U0 #_ #_ #_ #_ #X1 #X2 #H destruct
 124 ]
 125 qed-.
 126
 127 (* Basic_2A1: uses: snv_inv_appl *)
 128 lemma cnv_inv_appl (a) (h): ∀G,L,V,T. ⦃G,L⦄ ⊢ ⓐV.T ![a,h] →
 129                             ∃∃n,p,W0,U0. yinj n < a & ⦃G,L⦄ ⊢ V ![a,h] & ⦃G,L⦄ ⊢ T ![a,h] &
 130                                          ⦃G,L⦄ ⊢ V ➡*[1,h] W0 & ⦃G,L⦄ ⊢ T ➡*[n,h] ⓛ{p}W0.U0.
 131 /2 width=3 by cnv_inv_appl_aux/ qed-.
 132
 133 fact cnv_inv_cast_aux (a) (h): ∀G,L,X. ⦃G,L⦄ ⊢ X ![a,h] → ∀U,T. X = ⓝU.T →
 134                                ∃∃U0. ⦃G,L⦄ ⊢ U ![a,h] & ⦃G,L⦄ ⊢ T ![a,h] &
 135                                      ⦃G,L⦄ ⊢ U ➡*[h] U0 & ⦃G,L⦄ ⊢ T ➡*[1,h] U0.
 136 #a #h #G #L #X * -G -L -X
 137 [ #G #L #s #X1 #X2 #H destruct
 138 | #I #G #K #V #_ #X1 #X2 #H destruct
 139 | #I #G #K #i #_ #X1 #X2 #H destruct
 140 | #p #I #G #L #V #T #_ #_ #X1 #X2 #H destruct
 141 | #n #p #G #L #V #W0 #T #U0 #_ #_ #_ #_ #_ #X1 #X2 #H destruct
 142 | #G #L #U #T #U0 #HV #HT #HU0 #HTU0 #X1 #X2 #H destruct /2 width=3 by ex4_intro/
 143 ]
 144 qed-.
 145
 146 (* Basic_2A1: uses: snv_inv_appl *)
 147 lemma cnv_inv_cast (a) (h): ∀G,L,U,T. ⦃G,L⦄ ⊢ ⓝU.T ![a,h] →
 148                             ∃∃U0. ⦃G,L⦄ ⊢ U ![a,h] & ⦃G,L⦄ ⊢ T ![a,h] &
 149                                   ⦃G,L⦄ ⊢ U ➡*[h] U0 & ⦃G,L⦄ ⊢ T ➡*[1,h] U0.
 150 /2 width=3 by cnv_inv_cast_aux/ qed-.
 151
 152 (* Basic forward lemmas *****************************************************)
 153
 154 lemma cnv_fwd_flat (a) (h) (I) (G) (L):
 155                    ∀V,T. ⦃G,L⦄ ⊢ ⓕ{I}V.T ![a,h] →
 156                    ∧∧ ⦃G,L⦄ ⊢ V ![a,h] & ⦃G,L⦄ ⊢ T ![a,h].
 157 #a #h * #G #L #V #T #H
 158 [ elim (cnv_inv_appl … H) #n #p #W #U #_ #HV #HT #_ #_
 159 | elim (cnv_inv_cast … H) #U #HV #HT #_ #_
 160 ] -H /2 width=1 by conj/
 161 qed-.
 162
 163 lemma cnv_fwd_pair_sn (a) (h) (I) (G) (L):
 164       ∀V,T. ⦃G,L⦄ ⊢ ②{I}V.T ![a,h] → ⦃G,L⦄ ⊢ V ![a,h].
 165 #a #h * [ #p ] #I #G #L #V #T #H
 166 [ elim (cnv_inv_bind … H) -H #HV #_
 167 | elim (cnv_fwd_flat … H) -H #HV #_
 168 ] //
 169 qed-.
 170
 171 (* Basic_2A1: removed theorems 3:
 172               shnv_cast shnv_inv_cast snv_shnv_cast
 173 *)