matita/matita/contribs/lambdadelta/basic_2/dynamic/cnv.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/exclaim_5.ma".
  16 include "basic_2/notation/relations/exclaim_4.ma".
  17 include "basic_2/notation/relations/exclaimstar_4.ma".
  18 include "basic_2/rt_computation/cpms.ma".
  19
  20 (* CONTEXT-SENSITIVE NATIVE VALIDITY FOR TERMS ******************************)
  21
  22 (* activate genv *)
  23 (* Basic_2A1: uses: snv *)
  24 inductive cnv (a) (h): relation3 genv lenv term ≝
  25 | cnv_sort: ∀G,L,s. cnv a h G L (⋆s)
  26 | cnv_zero: ∀I,G,K,V. cnv a h G K V → cnv a h G (K.ⓑ{I}V) (#0)
  27 | cnv_lref: ∀I,G,K,i. cnv a h G K (#i) → cnv a h G (K.ⓘ{I}) (#↑i)
  28 | cnv_bind: ∀p,I,G,L,V,T. cnv a h G L V → cnv a h G (L.ⓑ{I}V) T → cnv a h G L (ⓑ{p,I}V.T)
  29 | cnv_appl: ∀n,p,G,L,V,W0,T,U0. (a = Ⓣ → n ≤ 1) → cnv a h G L V → cnv a h G L T →
  30             ⦃G, L⦄ ⊢ V ➡*[1, h] W0 → ⦃G, L⦄ ⊢ T ➡*[n, h] ⓛ{p}W0.U0 → cnv a h G L (ⓐV.T)
  31 | cnv_cast: ∀G,L,U,T,U0. cnv a h G L U → cnv a h G L T →
  32             ⦃G, L⦄ ⊢ U ➡*[h] U0 → ⦃G, L⦄ ⊢ T ➡*[1, h] U0 → cnv a h G L (ⓝU.T)
  33 .
  34
  35 interpretation "context-sensitive native validity (term)"
  36    'Exclaim a h G L T = (cnv a h G L T).
  37
  38 interpretation "context-sensitive restricted native validity (term)"
  39    'Exclaim h G L T = (cnv true h G L T).
  40
  41 interpretation "context-sensitive extended native validity (term)"
  42    'ExclaimStar h G L T = (cnv false h G L T).
  43
  44 (* Basic inversion lemmas ***************************************************)
  45
  46 fact cnv_inv_zero_aux (a) (h): ∀G,L,X. ⦃G, L⦄ ⊢ X ![a, h] → X = #0 →
  47                                ∃∃I,K,V. ⦃G, K⦄ ⊢ V ![a, h] & L = K.ⓑ{I}V.
  48 #a #h #G #L #X * -G -L -X
  49 [ #G #L #s #H destruct
  50 | #I #G #K #V #HV #_ /2 width=5 by ex2_3_intro/
  51 | #I #G #K #i #_ #H destruct
  52 | #p #I #G #L #V #T #_ #_ #H destruct
  53 | #n #p #G #L #V #W0 #T #U0 #_ #_ #_ #_ #_ #H destruct
  54 | #G #L #U #T #U0 #_ #_ #_ #_ #H destruct
  55 ]
  56 qed-.
  57
  58 lemma cnv_inv_zero (a) (h): ∀G,L. ⦃G, L⦄ ⊢ #0 ![a, h] →
  59                             ∃∃I,K,V. ⦃G, K⦄ ⊢ V ![a, h] & L = K.ⓑ{I}V.
  60 /2 width=3 by cnv_inv_zero_aux/ qed-.
  61
  62 fact cnv_inv_lref_aux (a) (h): ∀G,L,X. ⦃G, L⦄ ⊢ X ![a, h] → ∀i. X = #(↑i) →
  63                               ∃∃I,K. ⦃G, K⦄ ⊢ #i ![a, h] & L = K.ⓘ{I}.
  64 #a #h #G #L #X * -G -L -X
  65 [ #G #L #s #j #H destruct
  66 | #I #G #K #V #_ #j #H destruct
  67 | #I #G #L #i #Hi #j #H destruct /2 width=4 by ex2_2_intro/
  68 | #p #I #G #L #V #T #_ #_ #j #H destruct
  69 | #n #p #G #L #V #W0 #T #U0 #_ #_ #_ #_ #_ #j #H destruct
  70 | #G #L #U #T #U0 #_ #_ #_ #_ #j #H destruct
  71 ]
  72 qed-.
  73
  74 lemma cnv_inv_lref (a) (h): ∀G,L,i. ⦃G, L⦄ ⊢ #↑i ![a, h] →
  75                             ∃∃I,K. ⦃G, K⦄ ⊢ #i ![a, h] & L = K.ⓘ{I}.
  76 /2 width=3 by cnv_inv_lref_aux/ qed-.
  77
  78 fact cnv_inv_gref_aux (a) (h): ∀G,L,X. ⦃G, L⦄ ⊢ X ![a, h] → ∀l. X = §l → ⊥.
  79 #a #h #G #L #X * -G -L -X
  80 [ #G #L #s #l #H destruct
  81 | #I #G #K #V #_ #l #H destruct
  82 | #I #G #K #i #_ #l #H destruct
  83 | #p #I #G #L #V #T #_ #_ #l #H destruct
  84 | #n #p #G #L #V #W0 #T #U0 #_ #_ #_ #_ #_ #l #H destruct
  85 | #G #L #U #T #U0 #_ #_ #_ #_ #l #H destruct
  86 ]
  87 qed-.
  88
  89 (* Basic_2A1: uses: snv_inv_gref *)
  90 lemma cnv_inv_gref (a) (h): ∀G,L,l. ⦃G, L⦄ ⊢ §l ![a, h] → ⊥.
  91 /2 width=8 by cnv_inv_gref_aux/ qed-.
  92
  93 fact cnv_inv_bind_aux (a) (h): ∀G,L,X. ⦃G, L⦄ ⊢ X ![a, h] →
  94                                ∀p,I,V,T. X = ⓑ{p,I}V.T →
  95                                ∧∧ ⦃G, L⦄ ⊢ V ![a, h]
  96                                 & ⦃G, L.ⓑ{I}V⦄ ⊢ T ![a, h].
  97 #a #h #G #L #X * -G -L -X
  98 [ #G #L #s #q #Z #X1 #X2 #H destruct
  99 | #I #G #K #V #_ #q #Z #X1 #X2 #H destruct
 100 | #I #G #K #i #_ #q #Z #X1 #X2 #H destruct
 101 | #p #I #G #L #V #T #HV #HT #q #Z #X1 #X2 #H destruct /2 width=1 by conj/
 102 | #n #p #G #L #V #W0 #T #U0 #_ #_ #_ #_ #_ #q #Z #X1 #X2 #H destruct
 103 | #G #L #U #T #U0 #_ #_ #_ #_ #q #Z #X1 #X2 #H destruct
 104 ]
 105 qed-.
 106
 107 (* Basic_2A1: uses: snv_inv_bind *)
 108 lemma cnv_inv_bind (a) (h): ∀p,I,G,L,V,T. ⦃G, L⦄ ⊢ ⓑ{p,I}V.T ![a, h] →
 109                             ∧∧ ⦃G, L⦄ ⊢ V ![a, h]
 110                              & ⦃G, L.ⓑ{I}V⦄ ⊢ T ![a, h].
 111 /2 width=4 by cnv_inv_bind_aux/ qed-.
 112
 113 fact cnv_inv_appl_aux (a) (h): ∀G,L,X. ⦃G, L⦄ ⊢ X ![a, h] → ∀V,T. X = ⓐV.T →
 114                                ∃∃n,p,W0,U0. a = Ⓣ → n ≤ 1 & ⦃G, L⦄ ⊢ V ![a, h] & ⦃G, L⦄ ⊢ T ![a, h] &
 115                                             ⦃G, L⦄ ⊢ V ➡*[1, h] W0 & ⦃G, L⦄ ⊢ T ➡*[n, h] ⓛ{p}W0.U0.
 116 #a #h #G #L #X * -L -X
 117 [ #G #L #s #X1 #X2 #H destruct
 118 | #I #G #K #V #_ #X1 #X2 #H destruct
 119 | #I #G #K #i #_ #X1 #X2 #H destruct
 120 | #p #I #G #L #V #T #_ #_ #X1 #X2 #H destruct
 121 | #n #p #G #L #V #W0 #T #U0 #Ha #HV #HT #HVW0 #HTU0 #X1 #X2 #H destruct /3 width=7 by ex5_4_intro/
 122 | #G #L #U #T #U0 #_ #_ #_ #_ #X1 #X2 #H destruct
 123 ]
 124 qed-.
 125
 126 (* Basic_2A1: uses: snv_inv_appl *)
 127 lemma cnv_inv_appl (a) (h): ∀G,L,V,T. ⦃G, L⦄ ⊢ ⓐV.T ![a, h] →
 128                             ∃∃n,p,W0,U0. a = Ⓣ → n ≤ 1 & ⦃G, L⦄ ⊢ V ![a, h] & ⦃G, L⦄ ⊢ T ![a, h] &
 129                                          ⦃G, L⦄ ⊢ V ➡*[1, h] W0 & ⦃G, L⦄ ⊢ T ➡*[n, h] ⓛ{p}W0.U0.
 130 /2 width=3 by cnv_inv_appl_aux/ qed-.
 131
 132 fact cnv_inv_cast_aux (a) (h): ∀G,L,X. ⦃G, L⦄ ⊢ X ![a, h] → ∀U,T. X = ⓝU.T →
 133                                ∃∃U0. ⦃G, L⦄ ⊢ U ![a, h] & ⦃G, L⦄ ⊢ T ![a, h] &
 134                                      ⦃G, L⦄ ⊢ U ➡*[h] U0 & ⦃G, L⦄ ⊢ T ➡*[1, h] U0.
 135 #a #h #G #L #X * -G -L -X
 136 [ #G #L #s #X1 #X2 #H destruct
 137 | #I #G #K #V #_ #X1 #X2 #H destruct
 138 | #I #G #K #i #_ #X1 #X2 #H destruct
 139 | #p #I #G #L #V #T #_ #_ #X1 #X2 #H destruct
 140 | #n #p #G #L #V #W0 #T #U0 #_ #_ #_ #_ #_ #X1 #X2 #H destruct
 141 | #G #L #U #T #U0 #HV #HT #HU0 #HTU0 #X1 #X2 #H destruct /2 width=3 by ex4_intro/
 142 ]
 143 qed-.
 144
 145 (* Basic_2A1: uses: snv_inv_appl *)
 146 lemma cnv_inv_cast (a) (h): ∀G,L,U,T. ⦃G, L⦄ ⊢ ⓝU.T ![a, h] →
 147                             ∃∃U0. ⦃G, L⦄ ⊢ U ![a, h] & ⦃G, L⦄ ⊢ T ![a, h] &
 148                                   ⦃G, L⦄ ⊢ U ➡*[h] U0 & ⦃G, L⦄ ⊢ T ➡*[1, h] U0.
 149 /2 width=3 by cnv_inv_cast_aux/ qed-.
 150
 151 (* Basic forward lemmas *****************************************************)
 152
 153 lemma cnv_fwd_flat (a) (h) (I) (G) (L):
 154                    ∀V,T. ⦃G, L⦄ ⊢ ⓕ{I}V.T ![a,h] →
 155                    ∧∧ ⦃G, L⦄ ⊢ V ![a,h] & ⦃G, L⦄ ⊢ T ![a,h].
 156 #a #h * #G #L #V #T #H
 157 [ elim (cnv_inv_appl … H) #n #p #W #U #_ #HV #HT #_ #_
 158 | elim (cnv_inv_cast … H) #U #HV #HT #_ #_
 159 ] -H /2 width=1 by conj/
 160 qed-.
 161
 162 (* Basic_2A1: removed theorems 3:
 163               shnv_cast shnv_inv_cast snv_shnv_cast
 164 *)