matita/matita/contribs/lambdadelta/basic_2/dynamic/cnv.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/syntax/ac.ma".
  16 include "basic_2/notation/relations/exclaim_5.ma".
  17 include "basic_2/notation/relations/exclaim_4.ma".
  18 include "basic_2/notation/relations/exclaimstar_4.ma".
  19 include "basic_2/rt_computation/cpms.ma".
  20
  21 (* CONTEXT-SENSITIVE NATIVE VALIDITY FOR TERMS ******************************)
  22
  23 (* activate genv *)
  24 (* Basic_2A1: uses: snv *)
  25 inductive cnv (a) (h): relation3 genv lenv term ≝
  26 | cnv_sort: ∀G,L,s. cnv a h G L (⋆s)
  27 | cnv_zero: ∀I,G,K,V. cnv a h G K V → cnv a h G (K.ⓑ{I}V) (#0)
  28 | cnv_lref: ∀I,G,K,i. cnv a h G K (#i) → cnv a h G (K.ⓘ{I}) (#↑i)
  29 | cnv_bind: ∀p,I,G,L,V,T. cnv a h G L V → cnv a h G (L.ⓑ{I}V) T → cnv a h G L (ⓑ{p,I}V.T)
  30 | cnv_appl: ∀n,p,G,L,V,W0,T,U0. appl a n → cnv a h G L V → cnv a h G L T →
  31             ⦃G,L⦄ ⊢ V ➡*[1,h] W0 → ⦃G,L⦄ ⊢ T ➡*[n,h] ⓛ{p}W0.U0 → cnv a h G L (ⓐV.T)
  32 | cnv_cast: ∀G,L,U,T,U0. cnv a h G L U → cnv a h G L T →
  33             ⦃G,L⦄ ⊢ U ➡*[h] U0 → ⦃G,L⦄ ⊢ T ➡*[1,h] U0 → cnv a h G L (ⓝU.T)
  34 .
  35
  36 interpretation "context-sensitive native validity (term)"
  37    'Exclaim a h G L T = (cnv a h G L T).
  38
  39 interpretation "context-sensitive restricted native validity (term)"
  40    'Exclaim h G L T = (cnv (ac_eq (S O)) h G L T).
  41
  42 interpretation "context-sensitive extended native validity (term)"
  43    'ExclaimStar h G L T = (cnv ac_top h G L T).
  44
  45 (* Basic inversion lemmas ***************************************************)
  46
  47 fact cnv_inv_zero_aux (a) (h):
  48      ∀G,L,X. ⦃G,L⦄ ⊢ X ![a,h] → X = #0 →
  49      ∃∃I,K,V. ⦃G,K⦄ ⊢ V ![a,h] & L = K.ⓑ{I}V.
  50 #a #h #G #L #X * -G -L -X
  51 [ #G #L #s #H destruct
  52 | #I #G #K #V #HV #_ /2 width=5 by ex2_3_intro/
  53 | #I #G #K #i #_ #H destruct
  54 | #p #I #G #L #V #T #_ #_ #H destruct
  55 | #n #p #G #L #V #W0 #T #U0 #_ #_ #_ #_ #_ #H destruct
  56 | #G #L #U #T #U0 #_ #_ #_ #_ #H destruct
  57 ]
  58 qed-.
  59
  60 lemma cnv_inv_zero (a) (h):
  61       ∀G,L. ⦃G,L⦄ ⊢ #0 ![a,h] →
  62       ∃∃I,K,V. ⦃G,K⦄ ⊢ V ![a,h] & L = K.ⓑ{I}V.
  63 /2 width=3 by cnv_inv_zero_aux/ qed-.
  64
  65 fact cnv_inv_lref_aux (a) (h):
  66      ∀G,L,X. ⦃G,L⦄ ⊢ X ![a,h] → ∀i. X = #(↑i) →
  67      ∃∃I,K. ⦃G,K⦄ ⊢ #i ![a,h] & L = K.ⓘ{I}.
  68 #a #h #G #L #X * -G -L -X
  69 [ #G #L #s #j #H destruct
  70 | #I #G #K #V #_ #j #H destruct
  71 | #I #G #L #i #Hi #j #H destruct /2 width=4 by ex2_2_intro/
  72 | #p #I #G #L #V #T #_ #_ #j #H destruct
  73 | #n #p #G #L #V #W0 #T #U0 #_ #_ #_ #_ #_ #j #H destruct
  74 | #G #L #U #T #U0 #_ #_ #_ #_ #j #H destruct
  75 ]
  76 qed-.
  77
  78 lemma cnv_inv_lref (a) (h):
  79       ∀G,L,i. ⦃G,L⦄ ⊢ #↑i ![a,h] →
  80       ∃∃I,K. ⦃G,K⦄ ⊢ #i ![a,h] & L = K.ⓘ{I}.
  81 /2 width=3 by cnv_inv_lref_aux/ qed-.
  82
  83 fact cnv_inv_gref_aux (a) (h): ∀G,L,X. ⦃G,L⦄ ⊢ X ![a,h] → ∀l. X = §l → ⊥.
  84 #a #h #G #L #X * -G -L -X
  85 [ #G #L #s #l #H destruct
  86 | #I #G #K #V #_ #l #H destruct
  87 | #I #G #K #i #_ #l #H destruct
  88 | #p #I #G #L #V #T #_ #_ #l #H destruct
  89 | #n #p #G #L #V #W0 #T #U0 #_ #_ #_ #_ #_ #l #H destruct
  90 | #G #L #U #T #U0 #_ #_ #_ #_ #l #H destruct
  91 ]
  92 qed-.
  93
  94 (* Basic_2A1: uses: snv_inv_gref *)
  95 lemma cnv_inv_gref (a) (h): ∀G,L,l. ⦃G,L⦄ ⊢ §l ![a,h] → ⊥.
  96 /2 width=8 by cnv_inv_gref_aux/ qed-.
  97
  98 fact cnv_inv_bind_aux (a) (h):
  99      ∀G,L,X. ⦃G,L⦄ ⊢ X ![a,h] →
 100      ∀p,I,V,T. X = ⓑ{p,I}V.T →
 101      ∧∧ ⦃G,L⦄ ⊢ V ![a,h] & ⦃G,L.ⓑ{I}V⦄ ⊢ T ![a,h].
 102 #a #h #G #L #X * -G -L -X
 103 [ #G #L #s #q #Z #X1 #X2 #H destruct
 104 | #I #G #K #V #_ #q #Z #X1 #X2 #H destruct
 105 | #I #G #K #i #_ #q #Z #X1 #X2 #H destruct
 106 | #p #I #G #L #V #T #HV #HT #q #Z #X1 #X2 #H destruct /2 width=1 by conj/
 107 | #n #p #G #L #V #W0 #T #U0 #_ #_ #_ #_ #_ #q #Z #X1 #X2 #H destruct
 108 | #G #L #U #T #U0 #_ #_ #_ #_ #q #Z #X1 #X2 #H destruct
 109 ]
 110 qed-.
 111
 112 (* Basic_2A1: uses: snv_inv_bind *)
 113 lemma cnv_inv_bind (a) (h):
 114       ∀p,I,G,L,V,T. ⦃G,L⦄ ⊢ ⓑ{p,I}V.T ![a,h] →
 115       ∧∧ ⦃G,L⦄ ⊢ V ![a,h] & ⦃G,L.ⓑ{I}V⦄ ⊢ T ![a,h].
 116 /2 width=4 by cnv_inv_bind_aux/ qed-.
 117
 118 fact cnv_inv_appl_aux (a) (h):
 119      ∀G,L,X. ⦃G,L⦄ ⊢ X ![a,h] → ∀V,T. X = ⓐV.T →
 120      ∃∃n,p,W0,U0. appl a n & ⦃G,L⦄ ⊢ V ![a,h] & ⦃G,L⦄ ⊢ T ![a,h] &
 121                   ⦃G,L⦄ ⊢ V ➡*[1,h] W0 & ⦃G,L⦄ ⊢ T ➡*[n,h] ⓛ{p}W0.U0.
 122 #a #h #G #L #X * -L -X
 123 [ #G #L #s #X1 #X2 #H destruct
 124 | #I #G #K #V #_ #X1 #X2 #H destruct
 125 | #I #G #K #i #_ #X1 #X2 #H destruct
 126 | #p #I #G #L #V #T #_ #_ #X1 #X2 #H destruct
 127 | #n #p #G #L #V #W0 #T #U0 #Ha #HV #HT #HVW0 #HTU0 #X1 #X2 #H destruct /3 width=7 by ex5_4_intro/
 128 | #G #L #U #T #U0 #_ #_ #_ #_ #X1 #X2 #H destruct
 129 ]
 130 qed-.
 131
 132 (* Basic_2A1: uses: snv_inv_appl *)
 133 lemma cnv_inv_appl (a) (h):
 134       ∀G,L,V,T. ⦃G,L⦄ ⊢ ⓐV.T ![a,h] →
 135       ∃∃n,p,W0,U0. appl a n & ⦃G,L⦄ ⊢ V ![a,h] & ⦃G,L⦄ ⊢ T ![a,h] &
 136                    ⦃G,L⦄ ⊢ V ➡*[1,h] W0 & ⦃G,L⦄ ⊢ T ➡*[n,h] ⓛ{p}W0.U0.
 137 /2 width=3 by cnv_inv_appl_aux/ qed-.
 138
 139 fact cnv_inv_cast_aux (a) (h):
 140      ∀G,L,X. ⦃G,L⦄ ⊢ X ![a,h] → ∀U,T. X = ⓝU.T →
 141      ∃∃U0. ⦃G,L⦄ ⊢ U ![a,h] & ⦃G,L⦄ ⊢ T ![a,h] &
 142            ⦃G,L⦄ ⊢ U ➡*[h] U0 & ⦃G,L⦄ ⊢ T ➡*[1,h] U0.
 143 #a #h #G #L #X * -G -L -X
 144 [ #G #L #s #X1 #X2 #H destruct
 145 | #I #G #K #V #_ #X1 #X2 #H destruct
 146 | #I #G #K #i #_ #X1 #X2 #H destruct
 147 | #p #I #G #L #V #T #_ #_ #X1 #X2 #H destruct
 148 | #n #p #G #L #V #W0 #T #U0 #_ #_ #_ #_ #_ #X1 #X2 #H destruct
 149 | #G #L #U #T #U0 #HV #HT #HU0 #HTU0 #X1 #X2 #H destruct /2 width=3 by ex4_intro/
 150 ]
 151 qed-.
 152
 153 (* Basic_2A1: uses: snv_inv_cast *)
 154 lemma cnv_inv_cast (a) (h):
 155       ∀G,L,U,T. ⦃G,L⦄ ⊢ ⓝU.T ![a,h] →
 156       ∃∃U0. ⦃G,L⦄ ⊢ U ![a,h] & ⦃G,L⦄ ⊢ T ![a,h] &
 157             ⦃G,L⦄ ⊢ U ➡*[h] U0 & ⦃G,L⦄ ⊢ T ➡*[1,h] U0.
 158 /2 width=3 by cnv_inv_cast_aux/ qed-.
 159
 160 (* Basic forward lemmas *****************************************************)
 161
 162 lemma cnv_fwd_flat (a) (h) (I) (G) (L):
 163       ∀V,T. ⦃G,L⦄ ⊢ ⓕ{I}V.T ![a,h] →
 164       ∧∧ ⦃G,L⦄ ⊢ V ![a,h] & ⦃G,L⦄ ⊢ T ![a,h].
 165 #a #h * #G #L #V #T #H
 166 [ elim (cnv_inv_appl … H) #n #p #W #U #_ #HV #HT #_ #_
 167 | elim (cnv_inv_cast … H) #U #HV #HT #_ #_
 168 ] -H /2 width=1 by conj/
 169 qed-.
 170
 171 lemma cnv_fwd_pair_sn (a) (h) (I) (G) (L):
 172       ∀V,T. ⦃G,L⦄ ⊢ ②{I}V.T ![a,h] → ⦃G,L⦄ ⊢ V ![a,h].
 173 #a #h * [ #p ] #I #G #L #V #T #H
 174 [ elim (cnv_inv_bind … H) -H #HV #_
 175 | elim (cnv_fwd_flat … H) -H #HV #_
 176 ] //
 177 qed-.
 178
 179 (* Basic_2A1: removed theorems 3:
 180               shnv_cast shnv_inv_cast snv_shnv_cast
 181 *)