matita/matita/contribs/lambdadelta/basic_2/dynamic/cnv_cpce.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/cpue_csx.ma".
  16 include "basic_2/rt_conversion/cpce_drops.ma".
  17 include "basic_2/dynamic/cnv_cpue.ma".
  18
  19 (* CONTEXT-SENSITIVE NATIVE VALIDITY FOR TERMS ******************************)
  20
  21 (* Properties with context-sensitive parallel eta-conversion for terms ******)
  22
  23 lemma cpce_total_cnv (a) (h) (G) (L):
  24       ∀T1. ⦃G,L⦄ ⊢ T1 ![a,h] → ∃T2. ⦃G,L⦄ ⊢ T1 ⬌η[h] T2.
  25 #a #h #G #L #T1 #HT1
  26 lapply (cnv_fwd_csx … HT1) #H
  27 generalize in match HT1; -HT1
  28 @(csx_ind_fpbg … H) -G -L -T1
  29 #G #L * *
  30 [ #s #_ #_ /2 width=2 by cpce_sort, ex_intro/
  31 | #i #H1i #IH #H2i
  32   elim (drops_ldec_dec L i) [ * #K #W #HLK | -H1i -IH #HnX ]
  33   [ lapply (cnv_inv_lref_pair … H2i … HLK) -H2i #H2W
  34     lapply (csx_inv_lref_pair … HLK H1i) -H1i #H1W
  35     elim (cpue_total_csx … H1W) -H1W #X
  36     elim (abst_dec X) [ * | -IH ]
  37     [ #p #V1 #U #H destruct * #n #HWU #_
  38       elim (IH G K V1) -IH
  39       [ #V2 #HV12
  40         elim (lifts_total V2 (𝐔❴↑i❵)) #W2 #HVW2
  41         /3 width=12 by cpce_eta_drops, ex_intro/
  42       | /3 width=6 by  cnv_cpms_trans, cnv_fwd_pair_sn/
  43       | /4 width=6 by fqup_cpms_fwd_fpbg, fpbg_fqu_trans, fqup_lref/
  44       ]
  45     | #HnX #HWX
  46       @(ex_intro … (#i))
  47       @cpce_zero_drops #n0 #p #K0 #W0 #V0 #U0 #HLK0 #HWU0
  48       lapply (drops_mono … HLK0 … HLK) -i -L #H destruct
  49       elim (cnv_cpue_cpms_conf … H2W … HWU0 … HWX) -n0 -W #X0 * #n0 #HUX0 #_ #HX0
  50       elim (cpms_inv_abst_sn … HUX0) -HUX0 #V1 #U1 #_ #_ #H destruct -n0 -K -V0 -U0
  51       elim (tueq_inv_bind2 … HX0) -HX0 #U0 #_ #H destruct -U1
  52       /2 width=4 by/
  53     ]
  54   | /5 width=3 by cpce_zero_drops, ex1_2_intro, ex_intro/
  55   ]
  56 | #l #_ #_ /2 width=2 by cpce_gref, ex_intro/
  57 | #p #I #V1 #T1 #_ #IH #H
  58   elim (cnv_inv_bind … H) -H #HV1 #HT1
  59   elim (IH … HV1) [| /3 width=1 by fpb_fpbg, fpb_fqu, fqu_pair_sn/ ] #V2 #HV12
  60   elim (IH … HT1) [| /4 width=1 by fpb_fpbg, fpb_fqu, fqu_bind_dx/ ] #T2 #HT12
  61   /3 width=2 by cpce_bind, ex_intro/
  62 | #I #V1 #T1 #_ #IH #H
  63   elim (cnv_fwd_flat … H) -H #HV1 #HT1
  64   elim (IH … HV1) [| /3 width=1 by fpb_fpbg, fpb_fqu, fqu_pair_sn/ ] #V2 #HV12
  65   elim (IH … HT1) [| /3 width=1 by fpb_fpbg, fpb_fqu, fqu_flat_dx/ ] #T2 #HT12
  66   /3 width=2 by cpce_flat, ex_intro/
  67 ]
  68 qed-.