matita/matita/contribs/lambdadelta/basic_2/dynamic/cnv_cpm_tdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/xoa/ex_5_1.ma".
  16 include "ground_2/xoa/ex_9_3.ma".
  17 include "basic_2/rt_transition/cpm_tdeq.ma".
  18 include "basic_2/rt_transition/cpr.ma".
  19 include "basic_2/rt_computation/fpbg_fqup.ma".
  20 include "basic_2/dynamic/cnv_fsb.ma".
  21
  22 (* CONTEXT-SENSITIVE NATIVE VALIDITY FOR TERMS ******************************)
  23
  24 (* Inversion lemmas with restricted rt-transition for terms *****************)
  25
  26 lemma cnv_cpr_tdeq_fwd_refl (a) (h) (o) (G) (L):
  27                             ∀T1,T2. ⦃G, L⦄ ⊢ T1 ➡[h] T2 → T1 ≛[h,o] T2 →
  28                             ⦃G, L⦄ ⊢ T1 ![a,h] → T1 = T2.
  29 #a #h #o #G #L #T1 #T2 #H @(cpr_ind … H) -G -L -T1 -T2
  30 [ //
  31 | #G #K #V1 #V2 #X2 #_ #_ #_ #H1 #_ -a -G -K -V1 -V2
  32   lapply (tdeq_inv_lref1 … H1) -H1 #H destruct //
  33 | #I #G #K #T2 #X2 #i #_ #_ #_ #H1 #_ -a -I -G -K -T2
  34   lapply (tdeq_inv_lref1 … H1) -H1 #H destruct //
  35 | #p #I #G #L #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #H1 #H2
  36   elim (tdeq_inv_pair1 … H1) -H1 #V0 #T0 #HV0 #HT0 #H destruct
  37   elim (cnv_inv_bind … H2) -H2 #HV1 #HT1
  38   /3 width=3 by eq_f2/
  39 | #I #G #L #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #H1 #H2
  40   elim (tdeq_inv_pair1 … H1) -H1 #V0 #T0 #HV0 #HT0 #H destruct
  41   elim (cnv_fwd_flat … H2) -H2 #HV1 #HT1
  42   /3 width=3 by eq_f2/
  43 | #G #K #V #T1 #X1 #X2 #HXT1 #HX12 #_ #H1 #H2
  44   elim (cnv_fpbg_refl_false … o … H2) -a
  45   @(fpbg_tdeq_div … H1) -H1
  46   /3 width=9 by cpm_tdneq_cpm_fpbg, cpm_zeta, tdeq_lifts_inv_pair_sn/
  47 | #G #L #U #T1 #T2 #HT12 #_ #H1 #H2
  48   elim (cnv_fpbg_refl_false … o … H2) -a
  49   @(fpbg_tdeq_div … H1) -H1
  50   /3 width=6 by cpm_tdneq_cpm_fpbg, cpm_eps, tdeq_inv_pair_xy_y/
  51 | #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #_ #H1 #_
  52   elim (tdeq_inv_pair … H1) -H1 #H #_ #_ destruct
  53 | #p #G #L #V1 #V2 #X2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #_ #_ #H1 #_
  54   elim (tdeq_inv_pair … H1) -H1 #H #_ #_ destruct
  55 ]
  56 qed-.
  57
  58 lemma cpm_tdeq_inv_bind_sn (a) (h) (o) (n) (p) (I) (G) (L):
  59                            ∀V,T1. ⦃G, L⦄ ⊢ ⓑ{p,I}V.T1 ![a,h] →
  60                            ∀X. ⦃G, L⦄ ⊢ ⓑ{p,I}V.T1 ➡[n,h] X → ⓑ{p,I}V.T1 ≛[h,o] X →
  61                            ∃∃T2. ⦃G,L⦄ ⊢ V ![a,h] & ⦃G, L.ⓑ{I}V⦄ ⊢ T1 ![a,h] & ⦃G, L.ⓑ{I}V⦄ ⊢ T1 ➡[n,h] T2 & T1 ≛[h,o] T2 & X = ⓑ{p,I}V.T2.
  62 #a #h #o #n #p #I #G #L #V #T1 #H0 #X #H1 #H2
  63 elim (cpm_inv_bind1 … H1) -H1 *
  64 [ #XV #T2 #HXV #HT12 #H destruct
  65   elim (tdeq_inv_pair … H2) -H2 #_ #H2XV #H2T12
  66   elim (cnv_inv_bind … H0) -H0 #HV #HT
  67   lapply (cnv_cpr_tdeq_fwd_refl … HXV H2XV HV) #H destruct -HXV -H2XV
  68   /2 width=4 by ex5_intro/
  69 | #X1 #HXT1 #HX1 #H1 #H destruct
  70   elim (cnv_fpbg_refl_false … o … H0) -a
  71   @(fpbg_tdeq_div … H2) -H2
  72   /3 width=9 by cpm_tdneq_cpm_fpbg, cpm_zeta, tdeq_lifts_inv_pair_sn/
  73 ]
  74 qed-.
  75
  76 lemma cpm_tdeq_inv_appl_sn (a) (h) (o) (n) (G) (L):
  77                            ∀V,T1. ⦃G,L⦄ ⊢ ⓐV.T1 ![a,h] →
  78                            ∀X. ⦃G,L⦄ ⊢ ⓐV.T1 ➡[n,h] X → ⓐV.T1 ≛[h,o] X →
  79                            ∃∃m,q,W,U1,T2. a = Ⓣ → m ≤ 1 & ⦃G,L⦄ ⊢ V ![a,h] & ⦃G, L⦄ ⊢ V ➡*[1,h] W & ⦃G, L⦄ ⊢ T1 ➡*[m,h] ⓛ{q}W.U1
  80                                         & ⦃G,L⦄⊢ T1 ![a,h] & ⦃G, L⦄ ⊢ T1 ➡[n,h] T2 & T1 ≛[h,o] T2 & X = ⓐV.T2.
  81 #a #h #o #n #G #L #V #T1 #H0 #X #H1 #H2
  82 elim (cpm_inv_appl1 … H1) -H1 *
  83 [ #XV #T2 #HXV #HT12 #H destruct
  84   elim (tdeq_inv_pair … H2) -H2 #_ #H2XV #H2T12
  85   elim (cnv_inv_appl … H0) -H0 #m #q #W #U1 #Hm #HV #HT #HVW #HTU1
  86   lapply (cnv_cpr_tdeq_fwd_refl … HXV H2XV HV) #H destruct -HXV -H2XV
  87   /3 width=7 by ex8_5_intro/
  88 | #q #V2 #W1 #W2 #XT #T2 #_ #_ #_ #H1 #H destruct -H0
  89   elim (tdeq_inv_pair … H2) -H2 #H #_ #_ destruct
  90 | #q #V2 #XV #W1 #W2 #XT #T2 #_ #_ #_ #_ #H1 #H destruct -H0
  91   elim (tdeq_inv_pair … H2) -H2 #H #_ #_ destruct
  92 ]
  93 qed-.
  94
  95 lemma cpm_tdeq_inv_cast_sn (a) (h) (o) (n) (G) (L):
  96                            ∀U1,T1. ⦃G, L⦄ ⊢ ⓝU1.T1 ![a,h] →
  97                            ∀X. ⦃G, L⦄ ⊢ ⓝU1.T1 ➡[n,h] X → ⓝU1.T1 ≛[h,o] X →
  98                            ∃∃U0,U2,T2. ⦃G,L⦄ ⊢ U1 ➡*[h] U0 & ⦃G,L⦄ ⊢ T1 ➡*[1,h] U0
  99                                      & ⦃G, L⦄ ⊢ U1 ![a,h] & ⦃G, L⦄ ⊢ U1 ➡[n,h] U2 & U1 ≛[h,o] U2
 100                                      & ⦃G, L⦄ ⊢ T1 ![a,h] & ⦃G, L⦄ ⊢ T1 ➡[n,h] T2 & T1 ≛[h,o] T2 & X = ⓝU2.T2.
 101 #a #h #o #n #G #L #U1 #T1 #H0 #X #H1 #H2
 102 elim (cpm_inv_cast1 … H1) -H1 [ * || * ]
 103 [ #U2 #T2 #HU12 #HT12 #H destruct
 104   elim (tdeq_inv_pair … H2) -H2 #_ #H2U12 #H2T12
 105   elim (cnv_inv_cast … H0) -H0 #U0 #HU1 #HT1 #HU10 #HT1U0
 106   /2 width=7 by ex9_3_intro/
 107 | #HT1X
 108   elim (cnv_fpbg_refl_false … o … H0) -a
 109   @(fpbg_tdeq_div … H2) -H2
 110   /3 width=6 by cpm_tdneq_cpm_fpbg, cpm_eps, tdeq_inv_pair_xy_y/
 111 | #m #HU1X #H destruct
 112   elim (cnv_fpbg_refl_false … o … H0) -a
 113   @(fpbg_tdeq_div … H2) -H2
 114   /3 width=6 by cpm_tdneq_cpm_fpbg, cpm_ee, tdeq_inv_pair_xy_x/
 115 ]
 116 qed-.
 117
 118 (* Eliminators with restricted rt-transition for terms **********************)
 119
 120 lemma cpm_tdeq_ind (a) (h) (o) (n) (G) (Q:relation3 …):
 121                    (∀I,L. n = 0 → Q L (⓪{I}) (⓪{I})) →
 122                    (∀L,s. n = 1 → deg h o s 0 → Q L (⋆s) (⋆(next h s))) →
 123                    (∀p,I,L,V,T1. ⦃G,L⦄⊢ V![a,h] → ⦃G,L.ⓑ{I}V⦄⊢T1![a,h] →
 124                     ∀T2. ⦃G,L.ⓑ{I}V⦄ ⊢ T1 ➡[n,h] T2 → T1 ≛[h,o] T2 →
 125                     Q (L.ⓑ{I}V) T1 T2 → Q L (ⓑ{p,I}V.T1) (ⓑ{p,I}V.T2)
 126                    ) →
 127                    (∀m. (a = Ⓣ → m ≤ 1) →
 128                     ∀L,V. ⦃G,L⦄ ⊢ V ![a,h] → ∀W. ⦃G, L⦄ ⊢ V ➡*[1,h] W →
 129                     ∀p,T1,U1. ⦃G, L⦄ ⊢ T1 ➡*[m,h] ⓛ{p}W.U1 → ⦃G,L⦄⊢ T1 ![a,h] →
 130                     ∀T2. ⦃G, L⦄ ⊢ T1 ➡[n,h] T2 → T1 ≛[h,o] T2 →
 131                     Q L T1 T2 → Q L (ⓐV.T1) (ⓐV.T2)
 132                    ) →
 133                    (∀L,U0,U1,T1. ⦃G,L⦄ ⊢ U1 ➡*[h] U0 → ⦃G,L⦄ ⊢ T1 ➡*[1,h] U0 →
 134                     ∀U2. ⦃G, L⦄ ⊢ U1 ![a,h] → ⦃G, L⦄ ⊢ U1 ➡[n,h] U2 → U1 ≛[h,o] U2 →
 135                     ∀T2. ⦃G, L⦄ ⊢ T1 ![a,h] → ⦃G, L⦄ ⊢ T1 ➡[n,h] T2 → T1 ≛[h,o] T2 →
 136                     Q L U1 U2 → Q L T1 T2 → Q L (ⓝU1.T1) (ⓝU2.T2)
 137                    ) →
 138                    ∀L,T1. ⦃G,L⦄ ⊢ T1 ![a,h] →
 139                    ∀T2. ⦃G,L⦄ ⊢ T1 ➡[n,h] T2 → T1 ≛[h,o] T2 → Q L T1 T2.
 140 #a #h #o #n #G #Q #IH1 #IH2 #IH3 #IH4 #IH5 #L #T1
 141 @(insert_eq_0 … G) #F
 142 @(fqup_wf_ind_eq (Ⓣ) … F L T1) -L -T1 -F
 143 #G0 #L0 #T0 #IH #F #L * [| * [| * ]]
 144 [ #I #_ #_ #_ #_ #HF #X #H1X #H2X destruct -G0 -L0 -T0
 145   elim (cpm_tdeq_inv_atom_sn … H1X H2X) -H1X -H2X *
 146   [ #H1 #H2 destruct /2 width=1 by/
 147   | #s #H1 #H2 #H3 #Hs destruct /2 width=1 by/
 148   ]
 149 | #p #I #V #T1 #HG #HL #HT #H0 #HF #X #H1X #H2X destruct
 150   elim (cpm_tdeq_inv_bind_sn … H0 … H1X H2X) -H0 -H1X -H2X #T2 #HV #HT1 #H1T12 #H2T12 #H destruct
 151   /3 width=5 by/
 152 | #V #T1 #HG #HL #HT #H0 #HF #X #H1X #H2X destruct
 153   elim (cpm_tdeq_inv_appl_sn … H0 … H1X H2X) -H0 -H1X -H2X #m #q #W #U1 #T2 #Hm #HV #HVW #HTU1 #HT1 #H1T12 #H2T12 #H destruct
 154   /3 width=7 by/
 155 | #U1 #T1 #HG #HL #HT #H0 #HF #X #H1X #H2X destruct
 156   elim (cpm_tdeq_inv_cast_sn … H0 … H1X H2X) -H0 -H1X -H2X #U0 #U2 #T2 #HU10 #HT1U0 #HU1 #H1U12 #H2U12 #HT1 #H1T12 #H2T12 #H destruct
 157   /3 width=5 by/
 158 ]
 159 qed-.
 160
 161 (* Advanced properties with restricted rt-transition for terms **************)
 162
 163 lemma cpm_tdeq_free (a) (h) (o) (n) (G) (L):
 164                     ∀T1. ⦃G, L⦄ ⊢ T1 ![a,h] →
 165                     ∀T2. ⦃G, L⦄ ⊢ T1 ➡[n,h] T2 → T1 ≛[h,o] T2 →
 166                     ∀F,K. ⦃F, K⦄ ⊢ T1 ➡[n,h] T2.
 167 #a #h #o #n #G #L #T1 #H0 #T2 #H1 #H2
 168 @(cpm_tdeq_ind … H0 … H1 H2) -L -T1 -T2
 169 [ #I #L #H #F #K destruct //
 170 | #L #s #H #_ #F #K destruct //
 171 | #p #I #L #V #T1 #_ #_ #T2 #_ #_ #IH #F #K
 172   /2 width=1 by cpm_bind/
 173 | #m #_ #L #V #_ #W #_ #q #T1 #U1 #_ #_ #T2 #_ #_ #IH #F #K
 174   /2 width=1 by cpm_appl/
 175 | #L #U0 #U1 #T1 #_ #_ #U2 #_ #_ #_ #T2 #_ #_ #_ #IHU #IHT #F #K
 176   /2 width=1 by cpm_cast/
 177 ]
 178 qed-.
 179
 180 (* Advanced inversion lemmas with restricted rt-transition for terms ********)
 181
 182 lemma cpm_tdeq_inv_bind_sn_void (a) (h) (o) (n) (p) (I) (G) (L):
 183                                 ∀V,T1. ⦃G, L⦄ ⊢ ⓑ{p,I}V.T1 ![a,h] →
 184                                 ∀X. ⦃G, L⦄ ⊢ ⓑ{p,I}V.T1 ➡[n,h] X → ⓑ{p,I}V.T1 ≛[h,o] X →
 185                                 ∃∃T2. ⦃G,L⦄ ⊢ V ![a,h] & ⦃G, L.ⓑ{I}V⦄ ⊢ T1 ![a,h] & ⦃G, L.ⓧ⦄ ⊢ T1 ➡[n,h] T2 & T1 ≛[h,o] T2 & X = ⓑ{p,I}V.T2.
 186 #a #h #o #n #p #I #G #L #V #T1 #H0 #X #H1 #H2
 187 elim (cpm_tdeq_inv_bind_sn … H0 … H1 H2) -H0 -H1 -H2 #T2 #HV #HT1 #H1T12 #H2T12 #H
 188 /3 width=5 by ex5_intro, cpm_tdeq_free/
 189 qed-.