matita/matita/contribs/lambdadelta/basic_2/dynamic/cnv_cpm_tdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/cpr.ma".
  16 include "basic_2/rt_computation/fpbg_fqup.ma".
  17 include "basic_2/dynamic/cnv_fsb.ma".
  18
  19 (* T-BOUND CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS ***************)
  20
  21 (* Inversion lemmas with degree-based equivalence for terms *****************)
  22
  23 lemma cnv_cpr_tdeq_fwd_refl (a) (h) (o) (G) (L):
  24                             ∀T1,T2. ⦃G, L⦄ ⊢ T1 ➡[h] T2 → T1 ≛[h,o] T2 →
  25                             ⦃G, L⦄ ⊢ T1 ![a,h] → T1 = T2.
  26 #a #h #o #G #L #T1 #T2 #H @(cpr_ind … H) -G -L -T1 -T2
  27 [ //
  28 | #G #K #V1 #V2 #X2 #_ #_ #_ #H1 #_ -a -G -K -V1 -V2
  29   lapply (tdeq_inv_lref1 … H1) -H1 #H destruct //
  30 | #I #G #K #T2 #X2 #i #_ #_ #_ #H1 #_ -a -I -G -K -T2
  31   lapply (tdeq_inv_lref1 … H1) -H1 #H destruct //
  32 | #p #I #G #L #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #H1 #H2
  33   elim (tdeq_inv_pair1 … H1) -H1 #V0 #T0 #HV0 #HT0 #H destruct
  34   elim (cnv_inv_bind … H2) -H2 #HV1 #HT1
  35   /3 width=3 by eq_f2/
  36 | #I #G #L #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #H1 #H2
  37   elim (tdeq_inv_pair1 … H1) -H1 #V0 #T0 #HV0 #HT0 #H destruct
  38   elim (cnv_fwd_flat … H2) -H2 #HV1 #HT1
  39   /3 width=3 by eq_f2/
  40 | #G #K #V #T1 #X1 #X2 #HXT1 #HX12 #_ #H1 #H2
  41   elim (cnv_fpbg_refl_false … o … H2) -a
  42   @(fpbg_tdeq_div … H1) -H1
  43   /3 width=9 by cpm_tdneq_cpm_fpbg, cpm_zeta, tdeq_lifts_inv_pair_sn/
  44 | #G #L #U #T1 #T2 #HT12 #_ #H1 #H2
  45   elim (cnv_fpbg_refl_false … o … H2) -a
  46   @(fpbg_tdeq_div … H1) -H1
  47   /3 width=6 by cpm_tdneq_cpm_fpbg, cpm_eps, tdeq_inv_pair_xy_y/
  48 | #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #_ #H1 #_
  49   elim (tdeq_inv_pair … H1) -H1 #H #_ #_ destruct
  50 | #p #G #L #V1 #V2 #X2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #_ #_ #H1 #_
  51   elim (tdeq_inv_pair … H1) -H1 #H #_ #_ destruct
  52 ]
  53 qed-.
  54
  55 lemma cpm_tdeq_inv_bind (a) (h) (o) (n) (p) (I) (G) (L):
  56                         ∀V,T1. ⦃G, L⦄ ⊢ ⓑ{p,I}V.T1 ![a,h] →
  57                         ∀X. ⦃G, L⦄ ⊢ ⓑ{p,I}V.T1 ➡[n,h] X → ⓑ{p,I}V.T1 ≛[h,o] X →
  58                         ∃∃T2. ⦃G, L.ⓑ{I}V⦄ ⊢ T1 ➡[n,h] T2 & T1 ≛[h,o] T2 & X = ⓑ{p,I}V.T2.
  59 #a #h #o #n #p #I #G #L #V #T1 #H0 #X #H1 #H2
  60 elim (cpm_inv_bind1 … H1) -H1 *
  61 [ #XV #T2 #HXV #HT12 #H destruct
  62   elim (tdeq_inv_pair … H2) -H2 #_ #H2XV #H2T12
  63   elim (cnv_inv_bind … H0) -H0 #HV #_
  64   lapply (cnv_cpr_tdeq_fwd_refl … HXV H2XV HV) #H destruct -HXV -H2XV -HV
  65   /2 width=4 by ex3_intro/
  66 | #X1 #HXT1 #HX1 #H1 #H destruct
  67   elim (cnv_fpbg_refl_false … o … H0) -a
  68   @(fpbg_tdeq_div … H2) -H2
  69   /3 width=9 by cpm_tdneq_cpm_fpbg, cpm_zeta, tdeq_lifts_inv_pair_sn/
  70 ]
  71 qed-.
  72
  73 lemma cpm_tdeq_inv_appl (a) (h) (o) (n) (G) (L):
  74                         ∀V,T1. ⦃G, L⦄ ⊢ ⓐV.T1 ![a,h] →
  75                         ∀X. ⦃G, L⦄ ⊢ ⓐV.T1 ➡[n,h] X → ⓐV.T1 ≛[h,o] X →
  76                         ∃∃T2. ⦃G, L⦄ ⊢ T1 ➡[n,h] T2 & T1 ≛[h,o] T2 & X = ⓐV.T2.
  77 #a #h #o #n #G #L #V #T1 #H0 #X #H1 #H2
  78 elim (cpm_inv_appl1 … H1) -H1 *
  79 [ #XV #T2 #HXV #HT12 #H destruct
  80   elim (tdeq_inv_pair … H2) -H2 #_ #H2XV #H2T12
  81   elim (cnv_inv_appl … H0) -H0 #m #q #W #U #_ #HV #_ #_ #_ -m -q -W -U
  82   lapply (cnv_cpr_tdeq_fwd_refl … HXV H2XV HV) #H destruct -HXV -H2XV -HV
  83   /2 width=4 by ex3_intro/
  84 | #q #V2 #W1 #W2 #XT #T2 #_ #_ #_ #H1 #H destruct -H0
  85   elim (tdeq_inv_pair … H2) -H2 #H #_ #_ destruct
  86 | #q #V2 #XV #W1 #W2 #XT #T2 #_ #_ #_ #_ #H1 #H destruct -H0
  87   elim (tdeq_inv_pair … H2) -H2 #H #_ #_ destruct
  88 ]
  89 qed-.
  90
  91 lemma cpm_tdeq_inv_cast (a) (h) (o) (n) (G) (L):
  92                         ∀U1,T1. ⦃G, L⦄ ⊢ ⓝU1.T1 ![a,h] →
  93                         ∀X. ⦃G, L⦄ ⊢ ⓝU1.T1 ➡[n,h] X → ⓝU1.T1 ≛[h,o] X →
  94                         ∃∃U2,T2. ⦃G, L⦄ ⊢ U1 ➡[n,h] U2 & U1 ≛[h,o] U2 & ⦃G, L⦄ ⊢ T1 ➡[n,h] T2 & T1 ≛[h,o] T2 & X = ⓝU2.T2.
  95 #a #h #o #n #G #L #U1 #T1 #H0 #X #H1 #H2
  96 elim (cpm_inv_cast1 … H1) -H1 [ * || * ]
  97 [ #U2 #T2 #HU12 #HT12 #H destruct -H0
  98   elim (tdeq_inv_pair … H2) -H2 #_ #H2U12 #H2T12
  99   /2 width=7 by ex5_2_intro/
 100 | #HT1X
 101   elim (cnv_fpbg_refl_false … o … H0) -a
 102   @(fpbg_tdeq_div … H2) -H2
 103   /3 width=6 by cpm_tdneq_cpm_fpbg, cpm_eps, tdeq_inv_pair_xy_y/
 104 | #m #HU1X #H destruct
 105   elim (cnv_fpbg_refl_false … o … H0) -a
 106   @(fpbg_tdeq_div … H2) -H2
 107   /3 width=6 by cpm_tdneq_cpm_fpbg, cpm_ee, tdeq_inv_pair_xy_x/
 108 ]
 109 qed-.