matita/matita/contribs/lambdadelta/basic_2/dynamic/cnv_cpm_teqx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_5_1.ma".
  16 include "ground/xoa/ex_8_5.ma".
  17 include "ground/xoa/ex_9_3.ma".
  18 include "basic_2/rt_transition/cpm_teqx.ma".
  19 include "basic_2/rt_computation/fpbg_fqup.ma".
  20 include "basic_2/dynamic/cnv_fsb.ma".
  21
  22 (* CONTEXT-SENSITIVE NATIVE VALIDITY FOR TERMS ******************************)
  23
  24 (* Inversion lemmas with restricted rt-transition for terms *****************)
  25
  26 lemma cnv_cpr_teqx_fwd_refl (h) (a) (G) (L):
  27       ∀T1,T2. ❪G,L❫ ⊢ T1 ➡[h,0] T2 → T1 ≛ T2 → ❪G,L❫ ⊢ T1 ![h,a] → T1 = T2.
  28 #h #a #G #L #T1 #T2 #H @(cpr_ind … H) -G -L -T1 -T2
  29 [ //
  30 | #G #K #V1 #V2 #X2 #_ #_ #_ #H1 #_ -a -G -K -V1 -V2
  31   lapply (teqx_inv_lref1 … H1) -H1 #H destruct //
  32 | #I #G #K #T2 #X2 #i #_ #_ #_ #H1 #_ -a -I -G -K -T2
  33   lapply (teqx_inv_lref1 … H1) -H1 #H destruct //
  34 | #p #I #G #L #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #H1 #H2
  35   elim (teqx_inv_pair1 … H1) -H1 #V0 #T0 #HV0 #HT0 #H destruct
  36   elim (cnv_inv_bind … H2) -H2 #HV1 #HT1
  37   /3 width=3 by eq_f2/
  38 | #I #G #L #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #H1 #H2
  39   elim (teqx_inv_pair1 … H1) -H1 #V0 #T0 #HV0 #HT0 #H destruct
  40   elim (cnv_fwd_flat … H2) -H2 #HV1 #HT1
  41   /3 width=3 by eq_f2/
  42 | #G #K #V #T1 #X1 #X2 #HXT1 #HX12 #_ #H1 #H2
  43   elim (cnv_fpbg_refl_false … H2) -a
  44   @(fpbg_teqx_div … H1) -H1
  45   /3 width=9 by cpm_tneqx_cpm_fpbg, cpm_zeta, teqx_lifts_inv_pair_sn/
  46 | #G #L #U #T1 #T2 #HT12 #_ #H1 #H2
  47   elim (cnv_fpbg_refl_false … H2) -a
  48   @(fpbg_teqx_div … H1) -H1
  49   /3 width=7 by cpm_tneqx_cpm_fpbg, cpm_eps, teqx_inv_pair_xy_y/
  50 | #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #_ #H1 #_
  51   elim (teqx_inv_pair … H1) -H1 #H #_ #_ destruct
  52 | #p #G #L #V1 #V2 #X2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #_ #_ #H1 #_
  53   elim (teqx_inv_pair … H1) -H1 #H #_ #_ destruct
  54 ]
  55 qed-.
  56
  57 lemma cpm_teqx_inv_bind_sn (h) (a) (n) (p) (I) (G) (L):
  58       ∀V,T1. ❪G,L❫ ⊢ ⓑ[p,I]V.T1 ![h,a] →
  59       ∀X. ❪G,L❫ ⊢ ⓑ[p,I]V.T1 ➡[h,n] X → ⓑ[p,I]V.T1 ≛ X →
  60       ∃∃T2. ❪G,L❫ ⊢ V ![h,a] & ❪G,L.ⓑ[I]V❫ ⊢ T1 ![h,a] & ❪G,L.ⓑ[I]V❫ ⊢ T1 ➡[h,n] T2 & T1 ≛ T2 & X = ⓑ[p,I]V.T2.
  61 #h #a #n #p #I #G #L #V #T1 #H0 #X #H1 #H2
  62 elim (cpm_inv_bind1 … H1) -H1 *
  63 [ #XV #T2 #HXV #HT12 #H destruct
  64   elim (teqx_inv_pair … H2) -H2 #_ #H2XV #H2T12
  65   elim (cnv_inv_bind … H0) -H0 #HV #HT
  66   lapply (cnv_cpr_teqx_fwd_refl … HXV H2XV HV) #H destruct -HXV -H2XV
  67   /2 width=4 by ex5_intro/
  68 | #X1 #HXT1 #HX1 #H1 #H destruct
  69   elim (cnv_fpbg_refl_false … H0) -a
  70   @(fpbg_teqx_div … H2) -H2
  71   /3 width=9 by cpm_tneqx_cpm_fpbg, cpm_zeta, teqx_lifts_inv_pair_sn/
  72 ]
  73 qed-.
  74
  75 lemma cpm_teqx_inv_appl_sn (h) (a) (n) (G) (L):
  76       ∀V,T1. ❪G,L❫ ⊢ ⓐV.T1 ![h,a] →
  77       ∀X. ❪G,L❫ ⊢ ⓐV.T1 ➡[h,n] X → ⓐV.T1 ≛ X →
  78       ∃∃m,q,W,U1,T2. ad a m & ❪G,L❫ ⊢ V ![h,a] & ❪G,L❫ ⊢ V ➡*[h,1] W & ❪G,L❫ ⊢ T1 ➡*[h,m] ⓛ[q]W.U1
  79                    & ❪G,L❫⊢ T1 ![h,a] & ❪G,L❫ ⊢ T1 ➡[h,n] T2 & T1 ≛ T2 & X = ⓐV.T2.
  80 #h #a #n #G #L #V #T1 #H0 #X #H1 #H2
  81 elim (cpm_inv_appl1 … H1) -H1 *
  82 [ #XV #T2 #HXV #HT12 #H destruct
  83   elim (teqx_inv_pair … H2) -H2 #_ #H2XV #H2T12
  84   elim (cnv_inv_appl … H0) -H0 #m #q #W #U1 #Hm #HV #HT #HVW #HTU1
  85   lapply (cnv_cpr_teqx_fwd_refl … HXV H2XV HV) #H destruct -HXV -H2XV
  86   /3 width=7 by ex8_5_intro/
  87 | #q #V2 #W1 #W2 #XT #T2 #_ #_ #_ #H1 #H destruct -H0
  88   elim (teqx_inv_pair … H2) -H2 #H #_ #_ destruct
  89 | #q #V2 #XV #W1 #W2 #XT #T2 #_ #_ #_ #_ #H1 #H destruct -H0
  90   elim (teqx_inv_pair … H2) -H2 #H #_ #_ destruct
  91 ]
  92 qed-.
  93
  94 lemma cpm_teqx_inv_cast_sn (h) (a) (n) (G) (L):
  95       ∀U1,T1. ❪G,L❫ ⊢ ⓝU1.T1 ![h,a] →
  96       ∀X. ❪G,L❫ ⊢ ⓝU1.T1 ➡[h,n] X → ⓝU1.T1 ≛ X →
  97       ∃∃U0,U2,T2. ❪G,L❫ ⊢ U1 ➡*[h,0] U0 & ❪G,L❫ ⊢ T1 ➡*[h,1] U0
  98                 & ❪G,L❫ ⊢ U1 ![h,a] & ❪G,L❫ ⊢ U1 ➡[h,n] U2 & U1 ≛ U2
  99                 & ❪G,L❫ ⊢ T1 ![h,a] & ❪G,L❫ ⊢ T1 ➡[h,n] T2 & T1 ≛ T2 & X = ⓝU2.T2.
 100 #h #a #n #G #L #U1 #T1 #H0 #X #H1 #H2
 101 elim (cpm_inv_cast1 … H1) -H1 [ * || * ]
 102 [ #U2 #T2 #HU12 #HT12 #H destruct
 103   elim (teqx_inv_pair … H2) -H2 #_ #H2U12 #H2T12
 104   elim (cnv_inv_cast … H0) -H0 #U0 #HU1 #HT1 #HU10 #HT1U0
 105   /2 width=7 by ex9_3_intro/
 106 | #HT1X
 107   elim (cnv_fpbg_refl_false … H0) -a
 108   @(fpbg_teqx_div … H2) -H2
 109   /3 width=7 by cpm_tneqx_cpm_fpbg, cpm_eps, teqx_inv_pair_xy_y/
 110 | #m #HU1X #H destruct
 111   elim (cnv_fpbg_refl_false … H0) -a
 112   @(fpbg_teqx_div … H2) -H2
 113   /3 width=7 by cpm_tneqx_cpm_fpbg, cpm_ee, teqx_inv_pair_xy_x/
 114 ]
 115 qed-.
 116
 117 lemma cpm_teqx_inv_bind_dx (h) (a) (n) (p) (I) (G) (L):
 118       ∀X. ❪G,L❫ ⊢ X ![h,a] →
 119       ∀V,T2. ❪G,L❫ ⊢ X ➡[h,n] ⓑ[p,I]V.T2 → X ≛ ⓑ[p,I]V.T2 →
 120       ∃∃T1. ❪G,L❫ ⊢ V ![h,a] & ❪G,L.ⓑ[I]V❫ ⊢ T1 ![h,a] & ❪G,L.ⓑ[I]V❫ ⊢ T1 ➡[h,n] T2 & T1 ≛ T2 & X = ⓑ[p,I]V.T1.
 121 #h #a #n #p #I #G #L #X #H0 #V #T2 #H1 #H2
 122 elim (teqx_inv_pair2 … H2) #V0 #T1 #_ #_ #H destruct
 123 elim (cpm_teqx_inv_bind_sn … H0 … H1 H2) -H0 -H1 -H2 #T0 #HV #HT1 #H1T12 #H2T12 #H destruct
 124 /2 width=5 by ex5_intro/
 125 qed-.
 126
 127 (* Eliminators with restricted rt-transition for terms **********************)
 128
 129 lemma cpm_teqx_ind (h) (a) (n) (G) (Q:relation3 …):
 130       (∀I,L. n = 0 → Q L (⓪[I]) (⓪[I])) →
 131       (∀L,s. n = 1 → Q L (⋆s) (⋆(⫯[h]s))) →
 132       (∀p,I,L,V,T1. ❪G,L❫⊢ V![h,a] → ❪G,L.ⓑ[I]V❫⊢T1![h,a] →
 133         ∀T2. ❪G,L.ⓑ[I]V❫ ⊢ T1 ➡[h,n] T2 → T1 ≛ T2 →
 134         Q (L.ⓑ[I]V) T1 T2 → Q L (ⓑ[p,I]V.T1) (ⓑ[p,I]V.T2)
 135       ) →
 136       (∀m. ad a m →
 137         ∀L,V. ❪G,L❫ ⊢ V ![h,a] → ∀W. ❪G,L❫ ⊢ V ➡*[h,1] W →
 138         ∀p,T1,U1. ❪G,L❫ ⊢ T1 ➡*[h,m] ⓛ[p]W.U1 → ❪G,L❫⊢ T1 ![h,a] →
 139         ∀T2. ❪G,L❫ ⊢ T1 ➡[h,n] T2 → T1 ≛ T2 →
 140         Q L T1 T2 → Q L (ⓐV.T1) (ⓐV.T2)
 141       ) →
 142       (∀L,U0,U1,T1. ❪G,L❫ ⊢ U1 ➡*[h,0] U0 → ❪G,L❫ ⊢ T1 ➡*[h,1] U0 →
 143         ∀U2. ❪G,L❫ ⊢ U1 ![h,a] → ❪G,L❫ ⊢ U1 ➡[h,n] U2 → U1 ≛ U2 →
 144         ∀T2. ❪G,L❫ ⊢ T1 ![h,a] → ❪G,L❫ ⊢ T1 ➡[h,n] T2 → T1 ≛ T2 →
 145         Q L U1 U2 → Q L T1 T2 → Q L (ⓝU1.T1) (ⓝU2.T2)
 146       ) →
 147       ∀L,T1. ❪G,L❫ ⊢ T1 ![h,a] →
 148       ∀T2. ❪G,L❫ ⊢ T1 ➡[h,n] T2 → T1 ≛ T2 → Q L T1 T2.
 149 #h #a #n #G #Q #IH1 #IH2 #IH3 #IH4 #IH5 #L #T1
 150 @(insert_eq_0 … G) #F
 151 @(fqup_wf_ind_eq (Ⓣ) … F L T1) -L -T1 -F
 152 #G0 #L0 #T0 #IH #F #L * [| * [| * ]]
 153 [ #I #_ #_ #_ #_ #HF #X #H1X #H2X destruct -G0 -L0 -T0
 154   elim (cpm_teqx_inv_atom_sn … H1X H2X) -H1X -H2X *
 155   [ #H1 #H2 destruct /2 width=1 by/
 156   | #s #H1 #H2 #H3 destruct /2 width=1 by/
 157   ]
 158 | #p #I #V #T1 #HG #HL #HT #H0 #HF #X #H1X #H2X destruct
 159   elim (cpm_teqx_inv_bind_sn … H0 … H1X H2X) -H0 -H1X -H2X #T2 #HV #HT1 #H1T12 #H2T12 #H destruct
 160   /3 width=5 by/
 161 | #V #T1 #HG #HL #HT #H0 #HF #X #H1X #H2X destruct
 162   elim (cpm_teqx_inv_appl_sn … H0 … H1X H2X) -H0 -H1X -H2X #m #q #W #U1 #T2 #Hm #HV #HVW #HTU1 #HT1 #H1T12 #H2T12 #H destruct
 163   /3 width=7 by/
 164 | #U1 #T1 #HG #HL #HT #H0 #HF #X #H1X #H2X destruct
 165   elim (cpm_teqx_inv_cast_sn … H0 … H1X H2X) -H0 -H1X -H2X #U0 #U2 #T2 #HU10 #HT1U0 #HU1 #H1U12 #H2U12 #HT1 #H1T12 #H2T12 #H destruct
 166   /3 width=5 by/
 167 ]
 168 qed-.
 169
 170 (* Advanced properties with restricted rt-transition for terms **************)
 171
 172 lemma cpm_teqx_free (h) (a) (n) (G) (L):
 173       ∀T1. ❪G,L❫ ⊢ T1 ![h,a] →
 174       ∀T2. ❪G,L❫ ⊢ T1 ➡[h,n] T2 → T1 ≛ T2 →
 175       ∀F,K. ❪F,K❫ ⊢ T1 ➡[h,n] T2.
 176 #h #a #n #G #L #T1 #H0 #T2 #H1 #H2
 177 @(cpm_teqx_ind … H0 … H1 H2) -L -T1 -T2
 178 [ #I #L #H #F #K destruct //
 179 | #L #s #H #F #K destruct //
 180 | #p #I #L #V #T1 #_ #_ #T2 #_ #_ #IH #F #K
 181   /2 width=1 by cpm_bind/
 182 | #m #_ #L #V #_ #W #_ #q #T1 #U1 #_ #_ #T2 #_ #_ #IH #F #K
 183   /2 width=1 by cpm_appl/
 184 | #L #U0 #U1 #T1 #_ #_ #U2 #_ #_ #_ #T2 #_ #_ #_ #IHU #IHT #F #K
 185   /2 width=1 by cpm_cast/
 186 ]
 187 qed-.
 188
 189 (* Advanced inversion lemmas with restricted rt-transition for terms ********)
 190
 191 lemma cpm_teqx_inv_bind_sn_void (h) (a) (n) (p) (I) (G) (L):
 192       ∀V,T1. ❪G,L❫ ⊢ ⓑ[p,I]V.T1 ![h,a] →
 193       ∀X. ❪G,L❫ ⊢ ⓑ[p,I]V.T1 ➡[h,n] X → ⓑ[p,I]V.T1 ≛ X →
 194       ∃∃T2. ❪G,L❫ ⊢ V ![h,a] & ❪G,L.ⓑ[I]V❫ ⊢ T1 ![h,a] & ❪G,L.ⓧ❫ ⊢ T1 ➡[h,n] T2 & T1 ≛ T2 & X = ⓑ[p,I]V.T2.
 195 #h #a #n #p #I #G #L #V #T1 #H0 #X #H1 #H2
 196 elim (cpm_teqx_inv_bind_sn … H0 … H1 H2) -H0 -H1 -H2 #T2 #HV #HT1 #H1T12 #H2T12 #H
 197 /3 width=5 by ex5_intro, cpm_teqx_free/
 198 qed-.