matita/matita/contribs/lambdadelta/basic_2/dynamic/cnv_cpm_teqx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/xoa/ex_5_1.ma".
  16 include "ground_2/xoa/ex_9_3.ma".
  17 include "basic_2/rt_transition/cpm_teqx.ma".
  18 include "basic_2/rt_computation/fpbg_fqup.ma".
  19 include "basic_2/dynamic/cnv_fsb.ma".
  20
  21 (* CONTEXT-SENSITIVE NATIVE VALIDITY FOR TERMS ******************************)
  22
  23 (* Inversion lemmas with restricted rt-transition for terms *****************)
  24
  25 lemma cnv_cpr_teqx_fwd_refl (h) (a) (G) (L):
  26       ∀T1,T2. ⦃G,L⦄ ⊢ T1 ➡[h] T2 → T1 ≛ T2 → ⦃G,L⦄ ⊢ T1 ![h,a] → T1 = T2.
  27 #h #a #G #L #T1 #T2 #H @(cpr_ind … H) -G -L -T1 -T2
  28 [ //
  29 | #G #K #V1 #V2 #X2 #_ #_ #_ #H1 #_ -a -G -K -V1 -V2
  30   lapply (teqx_inv_lref1 … H1) -H1 #H destruct //
  31 | #I #G #K #T2 #X2 #i #_ #_ #_ #H1 #_ -a -I -G -K -T2
  32   lapply (teqx_inv_lref1 … H1) -H1 #H destruct //
  33 | #p #I #G #L #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #H1 #H2
  34   elim (teqx_inv_pair1 … H1) -H1 #V0 #T0 #HV0 #HT0 #H destruct
  35   elim (cnv_inv_bind … H2) -H2 #HV1 #HT1
  36   /3 width=3 by eq_f2/
  37 | #I #G #L #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #H1 #H2
  38   elim (teqx_inv_pair1 … H1) -H1 #V0 #T0 #HV0 #HT0 #H destruct
  39   elim (cnv_fwd_flat … H2) -H2 #HV1 #HT1
  40   /3 width=3 by eq_f2/
  41 | #G #K #V #T1 #X1 #X2 #HXT1 #HX12 #_ #H1 #H2
  42   elim (cnv_fpbg_refl_false … H2) -a
  43   @(fpbg_teqx_div … H1) -H1
  44   /3 width=9 by cpm_tneqx_cpm_fpbg, cpm_zeta, teqx_lifts_inv_pair_sn/
  45 | #G #L #U #T1 #T2 #HT12 #_ #H1 #H2
  46   elim (cnv_fpbg_refl_false … H2) -a
  47   @(fpbg_teqx_div … H1) -H1
  48   /3 width=6 by cpm_tneqx_cpm_fpbg, cpm_eps, teqx_inv_pair_xy_y/
  49 | #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #_ #H1 #_
  50   elim (teqx_inv_pair … H1) -H1 #H #_ #_ destruct
  51 | #p #G #L #V1 #V2 #X2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #_ #_ #H1 #_
  52   elim (teqx_inv_pair … H1) -H1 #H #_ #_ destruct
  53 ]
  54 qed-.
  55
  56 lemma cpm_teqx_inv_bind_sn (h) (a) (n) (p) (I) (G) (L):
  57       ∀V,T1. ⦃G,L⦄ ⊢ ⓑ{p,I}V.T1 ![h,a] →
  58       ∀X. ⦃G,L⦄ ⊢ ⓑ{p,I}V.T1 ➡[n,h] X → ⓑ{p,I}V.T1 ≛ X →
  59       ∃∃T2. ⦃G,L⦄ ⊢ V ![h,a] & ⦃G,L.ⓑ{I}V⦄ ⊢ T1 ![h,a] & ⦃G,L.ⓑ{I}V⦄ ⊢ T1 ➡[n,h] T2 & T1 ≛ T2 & X = ⓑ{p,I}V.T2.
  60 #h #a #n #p #I #G #L #V #T1 #H0 #X #H1 #H2
  61 elim (cpm_inv_bind1 … H1) -H1 *
  62 [ #XV #T2 #HXV #HT12 #H destruct
  63   elim (teqx_inv_pair … H2) -H2 #_ #H2XV #H2T12
  64   elim (cnv_inv_bind … H0) -H0 #HV #HT
  65   lapply (cnv_cpr_teqx_fwd_refl … HXV H2XV HV) #H destruct -HXV -H2XV
  66   /2 width=4 by ex5_intro/
  67 | #X1 #HXT1 #HX1 #H1 #H destruct
  68   elim (cnv_fpbg_refl_false … H0) -a
  69   @(fpbg_teqx_div … H2) -H2
  70   /3 width=9 by cpm_tneqx_cpm_fpbg, cpm_zeta, teqx_lifts_inv_pair_sn/
  71 ]
  72 qed-.
  73
  74 lemma cpm_teqx_inv_appl_sn (h) (a) (n) (G) (L):
  75       ∀V,T1. ⦃G,L⦄ ⊢ ⓐV.T1 ![h,a] →
  76       ∀X. ⦃G,L⦄ ⊢ ⓐV.T1 ➡[n,h] X → ⓐV.T1 ≛ X →
  77       ∃∃m,q,W,U1,T2. ad a m & ⦃G,L⦄ ⊢ V ![h,a] & ⦃G,L⦄ ⊢ V ➡*[1,h] W & ⦃G,L⦄ ⊢ T1 ➡*[m,h] ⓛ{q}W.U1
  78                    & ⦃G,L⦄⊢ T1 ![h,a] & ⦃G,L⦄ ⊢ T1 ➡[n,h] T2 & T1 ≛ T2 & X = ⓐV.T2.
  79 #h #a #n #G #L #V #T1 #H0 #X #H1 #H2
  80 elim (cpm_inv_appl1 … H1) -H1 *
  81 [ #XV #T2 #HXV #HT12 #H destruct
  82   elim (teqx_inv_pair … H2) -H2 #_ #H2XV #H2T12
  83   elim (cnv_inv_appl … H0) -H0 #m #q #W #U1 #Hm #HV #HT #HVW #HTU1
  84   lapply (cnv_cpr_teqx_fwd_refl … HXV H2XV HV) #H destruct -HXV -H2XV
  85   /3 width=7 by ex8_5_intro/
  86 | #q #V2 #W1 #W2 #XT #T2 #_ #_ #_ #H1 #H destruct -H0
  87   elim (teqx_inv_pair … H2) -H2 #H #_ #_ destruct
  88 | #q #V2 #XV #W1 #W2 #XT #T2 #_ #_ #_ #_ #H1 #H destruct -H0
  89   elim (teqx_inv_pair … H2) -H2 #H #_ #_ destruct
  90 ]
  91 qed-.
  92
  93 lemma cpm_teqx_inv_cast_sn (h) (a) (n) (G) (L):
  94       ∀U1,T1. ⦃G,L⦄ ⊢ ⓝU1.T1 ![h,a] →
  95       ∀X. ⦃G,L⦄ ⊢ ⓝU1.T1 ➡[n,h] X → ⓝU1.T1 ≛ X →
  96       ∃∃U0,U2,T2. ⦃G,L⦄ ⊢ U1 ➡*[h] U0 & ⦃G,L⦄ ⊢ T1 ➡*[1,h] U0
  97                 & ⦃G,L⦄ ⊢ U1 ![h,a] & ⦃G,L⦄ ⊢ U1 ➡[n,h] U2 & U1 ≛ U2
  98                 & ⦃G,L⦄ ⊢ T1 ![h,a] & ⦃G,L⦄ ⊢ T1 ➡[n,h] T2 & T1 ≛ T2 & X = ⓝU2.T2.
  99 #h #a #n #G #L #U1 #T1 #H0 #X #H1 #H2
 100 elim (cpm_inv_cast1 … H1) -H1 [ * || * ]
 101 [ #U2 #T2 #HU12 #HT12 #H destruct
 102   elim (teqx_inv_pair … H2) -H2 #_ #H2U12 #H2T12
 103   elim (cnv_inv_cast … H0) -H0 #U0 #HU1 #HT1 #HU10 #HT1U0
 104   /2 width=7 by ex9_3_intro/
 105 | #HT1X
 106   elim (cnv_fpbg_refl_false … H0) -a
 107   @(fpbg_teqx_div … H2) -H2
 108   /3 width=6 by cpm_tneqx_cpm_fpbg, cpm_eps, teqx_inv_pair_xy_y/
 109 | #m #HU1X #H destruct
 110   elim (cnv_fpbg_refl_false … H0) -a
 111   @(fpbg_teqx_div … H2) -H2
 112   /3 width=6 by cpm_tneqx_cpm_fpbg, cpm_ee, teqx_inv_pair_xy_x/
 113 ]
 114 qed-.
 115
 116 lemma cpm_teqx_inv_bind_dx (h) (a) (n) (p) (I) (G) (L):
 117       ∀X. ⦃G,L⦄ ⊢ X ![h,a] →
 118       ∀V,T2. ⦃G,L⦄ ⊢ X ➡[n,h] ⓑ{p,I}V.T2 → X ≛ ⓑ{p,I}V.T2 →
 119       ∃∃T1. ⦃G,L⦄ ⊢ V ![h,a] & ⦃G,L.ⓑ{I}V⦄ ⊢ T1 ![h,a] & ⦃G,L.ⓑ{I}V⦄ ⊢ T1 ➡[n,h] T2 & T1 ≛ T2 & X = ⓑ{p,I}V.T1.
 120 #h #a #n #p #I #G #L #X #H0 #V #T2 #H1 #H2
 121 elim (teqx_inv_pair2 … H2) #V0 #T1 #_ #_ #H destruct
 122 elim (cpm_teqx_inv_bind_sn … H0 … H1 H2) -H0 -H1 -H2 #T0 #HV #HT1 #H1T12 #H2T12 #H destruct
 123 /2 width=5 by ex5_intro/
 124 qed-.
 125
 126 (* Eliminators with restricted rt-transition for terms **********************)
 127
 128 lemma cpm_teqx_ind (h) (a) (n) (G) (Q:relation3 …):
 129       (∀I,L. n = 0 → Q L (⓪{I}) (⓪{I})) →
 130       (∀L,s. n = 1 → Q L (⋆s) (⋆(⫯[h]s))) →
 131       (∀p,I,L,V,T1. ⦃G,L⦄⊢ V![h,a] → ⦃G,L.ⓑ{I}V⦄⊢T1![h,a] →
 132         ∀T2. ⦃G,L.ⓑ{I}V⦄ ⊢ T1 ➡[n,h] T2 → T1 ≛ T2 →
 133         Q (L.ⓑ{I}V) T1 T2 → Q L (ⓑ{p,I}V.T1) (ⓑ{p,I}V.T2)
 134       ) →
 135       (∀m. ad a m →
 136         ∀L,V. ⦃G,L⦄ ⊢ V ![h,a] → ∀W. ⦃G,L⦄ ⊢ V ➡*[1,h] W →
 137         ∀p,T1,U1. ⦃G,L⦄ ⊢ T1 ➡*[m,h] ⓛ{p}W.U1 → ⦃G,L⦄⊢ T1 ![h,a] →
 138         ∀T2. ⦃G,L⦄ ⊢ T1 ➡[n,h] T2 → T1 ≛ T2 →
 139         Q L T1 T2 → Q L (ⓐV.T1) (ⓐV.T2)
 140       ) →
 141       (∀L,U0,U1,T1. ⦃G,L⦄ ⊢ U1 ➡*[h] U0 → ⦃G,L⦄ ⊢ T1 ➡*[1,h] U0 →
 142         ∀U2. ⦃G,L⦄ ⊢ U1 ![h,a] → ⦃G,L⦄ ⊢ U1 ➡[n,h] U2 → U1 ≛ U2 →
 143         ∀T2. ⦃G,L⦄ ⊢ T1 ![h,a] → ⦃G,L⦄ ⊢ T1 ➡[n,h] T2 → T1 ≛ T2 →
 144         Q L U1 U2 → Q L T1 T2 → Q L (ⓝU1.T1) (ⓝU2.T2)
 145       ) →
 146       ∀L,T1. ⦃G,L⦄ ⊢ T1 ![h,a] →
 147       ∀T2. ⦃G,L⦄ ⊢ T1 ➡[n,h] T2 → T1 ≛ T2 → Q L T1 T2.
 148 #h #a #n #G #Q #IH1 #IH2 #IH3 #IH4 #IH5 #L #T1
 149 @(insert_eq_0 … G) #F
 150 @(fqup_wf_ind_eq (Ⓣ) … F L T1) -L -T1 -F
 151 #G0 #L0 #T0 #IH #F #L * [| * [| * ]]
 152 [ #I #_ #_ #_ #_ #HF #X #H1X #H2X destruct -G0 -L0 -T0
 153   elim (cpm_teqx_inv_atom_sn … H1X H2X) -H1X -H2X *
 154   [ #H1 #H2 destruct /2 width=1 by/
 155   | #s #H1 #H2 #H3 destruct /2 width=1 by/
 156   ]
 157 | #p #I #V #T1 #HG #HL #HT #H0 #HF #X #H1X #H2X destruct
 158   elim (cpm_teqx_inv_bind_sn … H0 … H1X H2X) -H0 -H1X -H2X #T2 #HV #HT1 #H1T12 #H2T12 #H destruct
 159   /3 width=5 by/
 160 | #V #T1 #HG #HL #HT #H0 #HF #X #H1X #H2X destruct
 161   elim (cpm_teqx_inv_appl_sn … H0 … H1X H2X) -H0 -H1X -H2X #m #q #W #U1 #T2 #Hm #HV #HVW #HTU1 #HT1 #H1T12 #H2T12 #H destruct
 162   /3 width=7 by/
 163 | #U1 #T1 #HG #HL #HT #H0 #HF #X #H1X #H2X destruct
 164   elim (cpm_teqx_inv_cast_sn … H0 … H1X H2X) -H0 -H1X -H2X #U0 #U2 #T2 #HU10 #HT1U0 #HU1 #H1U12 #H2U12 #HT1 #H1T12 #H2T12 #H destruct
 165   /3 width=5 by/
 166 ]
 167 qed-.
 168
 169 (* Advanced properties with restricted rt-transition for terms **************)
 170
 171 lemma cpm_teqx_free (h) (a) (n) (G) (L):
 172       ∀T1. ⦃G,L⦄ ⊢ T1 ![h,a] →
 173       ∀T2. ⦃G,L⦄ ⊢ T1 ➡[n,h] T2 → T1 ≛ T2 →
 174       ∀F,K. ⦃F,K⦄ ⊢ T1 ➡[n,h] T2.
 175 #h #a #n #G #L #T1 #H0 #T2 #H1 #H2
 176 @(cpm_teqx_ind … H0 … H1 H2) -L -T1 -T2
 177 [ #I #L #H #F #K destruct //
 178 | #L #s #H #F #K destruct //
 179 | #p #I #L #V #T1 #_ #_ #T2 #_ #_ #IH #F #K
 180   /2 width=1 by cpm_bind/
 181 | #m #_ #L #V #_ #W #_ #q #T1 #U1 #_ #_ #T2 #_ #_ #IH #F #K
 182   /2 width=1 by cpm_appl/
 183 | #L #U0 #U1 #T1 #_ #_ #U2 #_ #_ #_ #T2 #_ #_ #_ #IHU #IHT #F #K
 184   /2 width=1 by cpm_cast/
 185 ]
 186 qed-.
 187
 188 (* Advanced inversion lemmas with restricted rt-transition for terms ********)
 189
 190 lemma cpm_teqx_inv_bind_sn_void (h) (a) (n) (p) (I) (G) (L):
 191       ∀V,T1. ⦃G,L⦄ ⊢ ⓑ{p,I}V.T1 ![h,a] →
 192       ∀X. ⦃G,L⦄ ⊢ ⓑ{p,I}V.T1 ➡[n,h] X → ⓑ{p,I}V.T1 ≛ X →
 193       ∃∃T2. ⦃G,L⦄ ⊢ V ![h,a] & ⦃G,L.ⓑ{I}V⦄ ⊢ T1 ![h,a] & ⦃G,L.ⓧ⦄ ⊢ T1 ➡[n,h] T2 & T1 ≛ T2 & X = ⓑ{p,I}V.T2.
 194 #h #a #n #p #I #G #L #V #T1 #H0 #X #H1 #H2
 195 elim (cpm_teqx_inv_bind_sn … H0 … H1 H2) -H0 -H1 -H2 #T2 #HV #HT1 #H1T12 #H2T12 #H
 196 /3 width=5 by ex5_intro, cpm_teqx_free/
 197 qed-.