matita/matita/contribs/lambdadelta/basic_2/dynamic/cnv_eval.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/cpmuwe_cpmuwe.ma".
  16 include "basic_2/rt_equivalence/cpes_cpes.ma".
  17 include "basic_2/dynamic/cnv_cpmuwe.ma". (**) (* should be included by the next *)
  18 include "basic_2/dynamic/cnv_cpmuwe_cpmre.ma".
  19 include "basic_2/dynamic/cnv_cpes.ma".
  20 include "basic_2/dynamic/cnv_preserve_cpes.ma".
  21
  22 (* CONTEXT-SENSITIVE NATIVE VALIDITY FOR TERMS ******************************)
  23
  24 (* main properties with evaluations for rt-transition on terms **************)
  25
  26 theorem cnv_dec (h) (a) (G) (L) (T): ac_props a →
  27         Decidable (❪G,L❫ ⊢ T ![h,a]).
  28 #h #a #G #L #T #Ha
  29 @(fqup_wf_ind_eq (Ⓣ) … G L T) -G -L -T #G0 #L0 #T0 #IH #G #L * * [|||| * ]
  30 [ #s #HG #HL #HT destruct -Ha -IH
  31   /2 width=1 by cnv_sort, or_introl/
  32 | #i #HG #HL #HT destruct -Ha
  33   elim (drops_F_uni L i) [| * * ]
  34   [ /3 width=8 by cnv_inv_lref_atom, or_intror/
  35   | /3 width=9 by cnv_inv_lref_unit, or_intror/
  36   | #I #V #K #HLK
  37     elim (IH G K V) -IH [3: /2 width=2 by fqup_lref/ ]
  38     [ /3 width=5 by cnv_lref_drops, or_introl/
  39     | /4 width=5 by cnv_inv_lref_pair, or_intror/
  40     ]
  41   ]
  42 | #l #HG #HL #HT destruct -Ha -IH
  43   /3 width=6 by cnv_inv_gref, or_intror/
  44 | #p #I #V #T #HG #HL #HT destruct -Ha
  45   elim (IH G L V) [| -IH | // ] #HV
  46   [ elim (IH G (L.ⓑ[I]V) T) -IH [3: // ] #HT
  47     [ /3 width=1 by cnv_bind, or_introl/ ]
  48   ]
  49   @or_intror #H
  50   elim (cnv_inv_bind … H) -H /2 width=1 by/
  51 | #V #T #HG #HL #HT destruct
  52   elim (IH G L V) [| -IH #HV | // ]
  53   [ elim (IH G L T) -IH [| #HT #HV | // ]
  54     [ #HT #HV
  55       elim (cnv_R_cpmuwe_total … HT) #n #Hn
  56       elim (dec_min (R_cpmuwe h G L T) … Hn) -Hn
  57       [| /2 width=2 by cnv_R_cpmuwe_dec/ ] #n0 #_ -n
  58       elim (ac_dec … Ha n0) -Ha
  59       [ * #n #Ha #Hn * #X0 #HX0 #_
  60         elim (abst_dec X0)
  61         [ * #p #W #U0 #H destruct
  62           elim (cnv_cpes_dec … 1 0 … HV W) [ #HVW | #HnVW ]
  63           [ lapply (cpmuwe_fwd_cpms … HX0) -HX0 #HTU0
  64             elim (cnv_fwd_cpms_abst_dx_le … HT … HTU0 … Hn) #U #HTU #_ -U0 -n0
  65             /3 width=7 by cnv_appl_cpes, or_introl/
  66 (* Note: argument type mismatch *)
  67           | @or_intror #H -n
  68             elim (cnv_inv_appl_cpes … H) -H #m0 #q #WX #UX #_ #_ #_ #HVWX #HTUX
  69             lapply (cpmuwe_abst … HTUX) -HTUX #HTUX
  70             elim (cnv_cpmuwe_mono … HT … HTUX … HX0) -a -T #H #_
  71             elim (cpes_fwd_abst_bi … H) -H #_ #HWX -n0 -m0 -p -q -UX -U0
  72             /3 width=3 by cpes_cpes_trans/
  73           | lapply (cnv_cpmuwe_trans … HT … HX0) -T #H
  74             elim (cnv_inv_bind … H) -H #HW #_ //
  75           ]
  76 (* Note: no expected type *)
  77         | #HnX0
  78           @or_intror #H
  79           elim (cnv_inv_appl_cpes … H) -H #m0 #q #W0 #U0 #_ #_ #_ #_ #HTU0
  80           lapply (cpmuwe_abst … HTU0) -HTU0 #HTU0
  81           elim (cnv_cpmuwe_mono … HT … HTU0 … HX0) -T #_ #H
  82           elim (tweq_inv_abst_sn … H) -W0 -U0 #W0 #U0 #H destruct
  83           /2 width=4 by/
  84         ]
  85 (* Note: failed applicability *)
  86       | #Hge #_ #Hlt
  87         @or_intror #H
  88         elim (cnv_inv_appl … H) -H #m0 #q #W0 #U0 #Hm0 #_ #_ #_ #HTU0
  89         elim (lt_or_ge m0 n0) #H0 [| /3 width=3 by ex2_intro/ ] -Hm0 -Hge
  90         /4 width=6 by cpmuwe_abst, ex_intro/
  91       ]
  92     ]
  93   ]
  94   @or_intror #H
  95   elim (cnv_inv_appl … H) -H /2 width=1 by/
  96 | #U #T #HG #HL #HT destruct
  97   elim (IH G L U) [| -IH | // ] #HU
  98   [ elim (IH G L T) -IH [3: // ] #HT
  99     [ elim (cnv_cpes_dec … 0 1 … HU … HT) #HUT
 100       [ /3 width=1 by cnv_cast_cpes, or_introl/ ]
 101     ]
 102   ]
 103   @or_intror #H
 104   elim (cnv_inv_cast_cpes … H) -H /2 width=1 by/
 105 ]
 106 qed-.