matita/matita/contribs/lambdadelta/basic_2/dynamic/lsubsv.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/lrsubeqv_5.ma".
  16 include "basic_2/dynamic/snv.ma".
  17
  18 (* LOCAL ENVIRONMENT REFINEMENT FOR STRATIFIED NATIVE VALIDITY **************)
  19
  20 (* Note: this is not transitive *)
  21 inductive lsubsv (h) (g) (G): relation lenv ≝
  22 | lsubsv_atom: lsubsv h g G (⋆) (⋆)
  23 | lsubsv_pair: ∀I,L1,L2,V. lsubsv h g G L1 L2 →
  24                lsubsv h g G (L1.ⓑ{I}V) (L2.ⓑ{I}V)
  25 | lsubsv_abbr: ∀L1,L2,W,V,l. ⦃G, L1⦄ ⊢ W ¡[h, g] → ⦃G, L1⦄ ⊢ V ¡[h, g] →
  26                scast h g l G L1 V W → ⦃G, L2⦄ ⊢ W ¡[h, g] →
  27                ⦃G, L1⦄ ⊢ V ▪[h, g] l+1 → ⦃G, L2⦄ ⊢ W ▪[h, g] l →
  28                lsubsv h g G L1 L2 → lsubsv h g G (L1.ⓓⓝW.V) (L2.ⓛW)
  29 .
  30
  31 interpretation
  32   "local environment refinement (stratified native validity)"
  33   'LRSubEqV h g G L1 L2 = (lsubsv h g G L1 L2).
  34
  35 (* Basic inversion lemmas ***************************************************)
  36
  37 fact lsubsv_inv_atom1_aux: ∀h,g,G,L1,L2. G ⊢ L1 ¡⫃[h, g] L2 → L1 = ⋆ → L2 = ⋆.
  38 #h #g #G #L1 #L2 * -L1 -L2
  39 [ //
  40 | #I #L1 #L2 #V #_ #H destruct
  41 | #L1 #L2 #W #V #l #_ #_ #_ #_ #_ #_ #_ #H destruct
  42 ]
  43 qed-.
  44
  45 lemma lsubsv_inv_atom1: ∀h,g,G,L2. G ⊢ ⋆ ¡⫃[h, g] L2 → L2 = ⋆.
  46 /2 width=6 by lsubsv_inv_atom1_aux/ qed-.
  47
  48 fact lsubsv_inv_pair1_aux: ∀h,g,G,L1,L2. G ⊢ L1 ¡⫃[h, g] L2 →
  49                            ∀I,K1,X. L1 = K1.ⓑ{I}X →
  50                            (∃∃K2. G ⊢ K1 ¡⫃[h, g] K2 & L2 = K2.ⓑ{I}X) ∨
  51                            ∃∃K2,W,V,l. ⦃G, K1⦄ ⊢ W ¡[h, g] & ⦃G, K1⦄ ⊢ V ¡[h, g] &
  52                                        scast h g l G K1 V W & ⦃G, K2⦄ ⊢ W ¡[h, g] &
  53                                        ⦃G, K1⦄ ⊢ V ▪[h, g] l+1 & ⦃G, K2⦄ ⊢ W ▪[h, g] l &
  54                                        G ⊢ K1 ¡⫃[h, g] K2 &
  55                                        I = Abbr & L2 = K2.ⓛW & X = ⓝW.V.
  56 #h #g #G #L1 #L2 * -L1 -L2
  57 [ #J #K1 #X #H destruct
  58 | #I #L1 #L2 #V #HL12 #J #K1 #X #H destruct /3 width=3/
  59 | #L1 #L2 #W #V #l #H1W #HV #HVW #H2W #H1l #H2l #HL12 #J #K1 #X #H destruct /3 width=13/
  60 ]
  61 qed-.
  62
  63 lemma lsubsv_inv_pair1: ∀h,g,I,G,K1,L2,X. G ⊢ K1.ⓑ{I}X ¡⫃[h, g] L2 →
  64                         (∃∃K2. G ⊢ K1 ¡⫃[h, g] K2 & L2 = K2.ⓑ{I}X) ∨
  65                         ∃∃K2,W,V,l. ⦃G, K1⦄ ⊢ W ¡[h, g] & ⦃G, K1⦄ ⊢ V ¡[h, g] &
  66                                     scast h g l G K1 V W & ⦃G, K2⦄ ⊢ W ¡[h, g] &
  67                                     ⦃G, K1⦄ ⊢ V ▪[h, g] l+1 & ⦃G, K2⦄ ⊢ W ▪[h, g] l &
  68                                     G ⊢ K1 ¡⫃[h, g] K2 &
  69                                     I = Abbr & L2 = K2.ⓛW & X = ⓝW.V.
  70 /2 width=3 by lsubsv_inv_pair1_aux/ qed-.
  71
  72 fact lsubsv_inv_atom2_aux: ∀h,g,G,L1,L2. G ⊢ L1 ¡⫃[h, g] L2 → L2 = ⋆ → L1 = ⋆.
  73 #h #g #G #L1 #L2 * -L1 -L2
  74 [ //
  75 | #I #L1 #L2 #V #_ #H destruct
  76 | #L1 #L2 #W #V #l #_ #_ #_ #_ #_ #_ #_ #H destruct
  77 ]
  78 qed-.
  79
  80 lemma lsubsv_inv_atom2: ∀h,g,G,L1. G ⊢ L1 ¡⫃[h, g] ⋆ → L1 = ⋆.
  81 /2 width=6 by lsubsv_inv_atom2_aux/ qed-.
  82
  83 fact lsubsv_inv_pair2_aux: ∀h,g,G,L1,L2. G ⊢ L1 ¡⫃[h, g] L2 →
  84                            ∀I,K2,W. L2 = K2.ⓑ{I}W →
  85                            (∃∃K1. G ⊢ K1 ¡⫃[h, g] K2 & L1 = K1.ⓑ{I}W) ∨
  86                            ∃∃K1,V,l. ⦃G, K1⦄ ⊢ W ¡[h, g] & ⦃G, K1⦄ ⊢ V ¡[h, g] &
  87                                      scast h g l G K1 V W & ⦃G, K2⦄ ⊢ W ¡[h, g] &
  88                                      ⦃G, K1⦄ ⊢ V ▪[h, g] l+1 & ⦃G, K2⦄ ⊢ W ▪[h, g] l &
  89                                      G ⊢ K1 ¡⫃[h, g] K2 & I = Abst & L1 = K1. ⓓⓝW.V.
  90 #h #g #G #L1 #L2 * -L1 -L2
  91 [ #J #K2 #U #H destruct
  92 | #I #L1 #L2 #V #HL12 #J #K2 #U #H destruct /3 width=3/
  93 | #L1 #L2 #W #V #l #H1W #HV #HVW #H2W #H1l #H2l #HL12 #J #K2 #U #H destruct /3 width=10/
  94 ]
  95 qed-.
  96
  97 lemma lsubsv_inv_pair2: ∀h,g,I,G,L1,K2,W. G ⊢ L1 ¡⫃[h, g] K2.ⓑ{I}W →
  98                         (∃∃K1. G ⊢ K1 ¡⫃[h, g] K2 & L1 = K1.ⓑ{I}W) ∨
  99                         ∃∃K1,V,l. ⦃G, K1⦄ ⊢ W ¡[h, g] & ⦃G, K1⦄ ⊢ V ¡[h, g] &
 100                                   scast h g l G K1 V W & ⦃G, K2⦄ ⊢ W ¡[h, g] &
 101                                   ⦃G, K1⦄ ⊢ V ▪[h, g] l+1 & ⦃G, K2⦄ ⊢ W ▪[h, g] l &
 102                                   G ⊢ K1 ¡⫃[h, g] K2 & I = Abst & L1 = K1. ⓓⓝW.V.
 103 /2 width=3 by lsubsv_inv_pair2_aux/ qed-.
 104
 105 (* Basic_forward lemmas *****************************************************)
 106
 107 lemma lsubsv_fwd_lsubr: ∀h,g,G,L1,L2. G ⊢ L1 ¡⫃[h, g] L2 → L1 ⫃ L2.
 108 #h #g #G #L1 #L2 #H elim H -L1 -L2 // /2 width=1/
 109 qed-.
 110
 111 (* Basic properties *********************************************************)
 112
 113 lemma lsubsv_refl: ∀h,g,G,L. G ⊢ L ¡⫃[h, g] L.
 114 #h #g #G #L elim L -L // /2 width=1/
 115 qed.
 116
 117 lemma lsubsv_cprs_trans: ∀h,g,G,L1,L2. G ⊢ L1 ¡⫃[h, g] L2 →
 118                          ∀T1,T2. ⦃G, L2⦄ ⊢ T1 ➡* T2 → ⦃G, L1⦄ ⊢ T1 ➡* T2.
 119 /3 width=6 by lsubsv_fwd_lsubr, lsubr_cprs_trans/
 120 qed-.
 121
 122 (* Note: the constant 0 cannot be generalized *)
 123 lemma lsubsv_ldrop_O1_conf: ∀h,g,G,L1,L2. G ⊢ L1 ¡⫃[h, g] L2 →
 124                             ∀K1,s,e. ⇩[s, 0, e] L1 ≡ K1 →
 125                             ∃∃K2. G ⊢ K1 ¡⫃[h, g] K2 & ⇩[s, 0, e] L2 ≡ K2.
 126 #h #g #G #L1 #L2 #H elim H -L1 -L2
 127 [ /2 width=3 by ex2_intro/
 128 | #I #L1 #L2 #V #_ #IHL12 #K1 #s #e #H
 129   elim (ldrop_inv_O1_pair1 … H) -H * #He #HLK1
 130   [ destruct
 131     elim (IHL12 L1 s 0) -IHL12 // #X #HL12 #H
 132     <(ldrop_inv_O2 … H) in HL12; -H /3 width=3 by lsubsv_pair, ldrop_pair, ex2_intro/
 133   | elim (IHL12 … HLK1) -L1 /3 width=3 by ldrop_drop_lt, ex2_intro/
 134   ]
 135 | #L1 #L2 #W #V #l #H1W #HV #HVW #H2W #H1l #H2l #_ #IHL12 #K1 #s #e #H
 136   elim (ldrop_inv_O1_pair1 … H) -H * #He #HLK1
 137   [ destruct
 138     elim (IHL12 L1 s 0) -IHL12 // #X #HL12 #H
 139     <(ldrop_inv_O2 … H) in HL12; -H /3 width=4 by lsubsv_abbr, ldrop_pair, ex2_intro/
 140   | elim (IHL12 … HLK1) -L1 /3 width=3 by ldrop_drop_lt, ex2_intro/
 141   ]
 142 ]
 143 qed-.
 144
 145 (* Note: the constant 0 cannot be generalized *)
 146 lemma lsubsv_ldrop_O1_trans: ∀h,g,G,L1,L2. G ⊢ L1 ¡⫃[h, g] L2 →
 147                              ∀K2,s, e. ⇩[s, 0, e] L2 ≡ K2 →
 148                              ∃∃K1. G ⊢ K1 ¡⫃[h, g] K2 & ⇩[s, 0, e] L1 ≡ K1.
 149 #h #g #G #L1 #L2 #H elim H -L1 -L2
 150 [ /2 width=3 by ex2_intro/
 151 | #I #L1 #L2 #V #_ #IHL12 #K2 #s #e #H
 152   elim (ldrop_inv_O1_pair1 … H) -H * #He #HLK2
 153   [ destruct
 154     elim (IHL12 L2 s 0) -IHL12 // #X #HL12 #H
 155     <(ldrop_inv_O2 … H) in HL12; -H /3 width=3 by lsubsv_pair, ldrop_pair, ex2_intro/
 156   | elim (IHL12 … HLK2) -L2 /3 width=3 by ldrop_drop_lt, ex2_intro/
 157   ]
 158 | #L1 #L2 #W #V #l #H1W #HV #HVW #H2W #H1l #H2l #_ #IHL12 #K2 #s #e #H
 159   elim (ldrop_inv_O1_pair1 … H) -H * #He #HLK2
 160   [ destruct
 161     elim (IHL12 L2 s 0) -IHL12 // #X #HL12 #H
 162     <(ldrop_inv_O2 … H) in HL12; -H /3 width=4 by lsubsv_abbr, ldrop_pair, ex2_intro/
 163   | elim (IHL12 … HLK2) -L2 /3 width=3 by ldrop_drop_lt, ex2_intro/
 164   ]
 165 ]
 166 qed-.